Checkboxes behave as radio buttons

[henrikl]

Hi,

I am facing a problem which it seems I can’t find a solution to.

I have 4 checkboxes in a panel. One of the checkboxes is checked at load.
Now I would like the checkboxes to behave like radio buttons. Only one can be checked at a time.

I can’t use radio buttons because, my checkboxes are user controls with some extra features.

Thank you in advance.

[kaliman79912]

Loop through all the controls inside the panel, uncheck them all, and then check the current one.

To create the loop you do something like:

For Each myControl in myPanel.Controls

It would be a good idea to cast myControl to a checkBox so you have intellisense and all the early binding.

to uncheck all checkBoxes, put this inside the loop:

myControl.Checked = False

to check the current control:

sender.Checked = True

Also, good idea to cast the sender.

Remember to have that Sub as a handler for all checkBoxes CheckedChanged event. One important thing here is that you are changing the checked property of the boxes, so if you are not careful, this will be a recursive event that could overflow easily. Either do it with a control boolean variable, or disable and enable the event handlers.

[kleinma]

Loop through all the controls inside the panel, uncheck them all, and then check the current one.

To create the loop you do something like:

For Each myControl in myPanel.Controls

It would be a good idea to cast myControl to a checkBox so you have intellisense and all the early binding.

to uncheck all checkBoxes, put this inside the loop:

myControl.Checked = False

to check the current control:

sender.Checked = True

Also, good idea to cast the sender.

Remember to have that Sub as a handler for all checkBoxes CheckedChanged event.

To add to this, you can filter the controls to just the type you care about in the loop like this:

        For Each C As CheckBox In myPanel.Controls.OfType(Of CheckBox)()

        Next

[kaliman79912]

Here's the solution manipulating the eventHandlers

    Private Sub CheckBox1_CheckedChanged(sender As System.Object, e As System.EventArgs) Handles CheckBox1.CheckedChanged, CheckBox2.CheckedChanged, CheckBox3.CheckedChanged

        Dim mySender As CheckBox = DirectCast(sender, CheckBox)
        For Each myControl As CheckBox In Panel1.Controls
            RemoveHandler myControl.CheckedChanged, AddressOf CheckBox1_CheckedChanged
            If myControl.Name = mySender.Name Then
                myControl.Checked = True
            Else
                myControl.Checked = False

            End If
            AddHandler myControl.CheckedChanged, AddressOf CheckBox1_CheckedChanged
        Next

    End Sub

[TysonLPrice]

Old fashioned clunky control freak way.

	Private Sub CheckBox1_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox1.CheckedChanged
		If CheckBox1.Checked = True Then
			CheckBox2.Checked = False
			CheckBox3.Checked = False
			CheckBox4.Checked = False
		End If
	End Sub

	Private Sub CheckBox2_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox2.CheckedChanged
		If CheckBox2.Checked = True Then
			CheckBox1.Checked = False
			CheckBox3.Checked = False
			CheckBox4.Checked = False
		End If
	End Sub

	Private Sub CheckBox3_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox3.CheckedChanged
		If CheckBox3.Checked = True Then
			CheckBox1.Checked = False
			CheckBox2.Checked = False
			CheckBox4.Checked = False
		End If
	End Sub

	Private Sub CheckBox4_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox4.CheckedChanged
		If CheckBox4.Checked = True Then
			CheckBox1.Checked = False
			CheckBox2.Checked = False
			CheckBox3.Checked = False
		End If
	End Sub

[kleinma]

Why would it be necessary to remove and add event handlers for this?

[kaliman79912]

And using a status variable:

    Private Sub CheckBox1_CheckedChanged(sender As System.Object, e As System.EventArgs) Handles CheckBox1.CheckedChanged, CheckBox2.CheckedChanged, CheckBox3.CheckedChanged
        Static bolChanging As Boolean = False
        If Not bolChanging Then
            bolChanging = True
            Dim mySender As CheckBox = DirectCast(sender, CheckBox)
            For Each myControl As CheckBox In Panel1.Controls
                myControl.Checked = False
            Next
            mySender.Checked = True
            bolChanging = False
        End If
    End Sub

[kaliman79912]

Why would it be necessary to remove and add event handlers for this?

Because, if you change the checked property inside the CheckedChange event handler, that action will trigger the handler again, in an infinite recursive loop.

[Edgemeal]

i can’t use radio buttons because, my checkboxes are user controls with some extra features.

code remove!

[Vexslasher]

It works better if you do it from the click event instead of the checkchanged this is all you would need.

    Private Sub CheckBox1_Click(sender As Object, e As EventArgs) Handles CheckBox1.Click, CheckBox2.Click, CheckBox3.Click, CheckBox4.Click
        Dim mySender As CheckBox = DirectCast(sender, CheckBox)
        For Each Cb As CheckBox In Me.Controls.OfType(Of CheckBox)()
            Cb.Checked = False
        Next
        mySender.Checked = True
    End Sub

[kaliman79912]

how bout,

' User Control with a checkbox that acts like a radio button.

Public Class UC
    ' check box click,
    Private Sub CheckBox1_Click(sender As Object, e As System.EventArgs) Handles CheckBox1.Click
        ' get list of usercontrols of same type in the same parent/container.
        Dim ucs = Me.Parent.Controls.OfType(Of UC)()
        ' loop thru user controls
        For Each uc As UC In ucs
            ' if UC is NOT Me then,
            If uc.Name <> Me.Name Then
                ' get list of checkboxes in this uc,
                Dim checkBoxes = uc.Controls.OfType(Of CheckBox)()
                ' loop thru check box list,
                For Each chkBox As CheckBox In checkBoxes
                    ' if has same name as this checkbox then uncheck it!
                    If chkBox.Name = Me.CheckBox1.Name Then
                        chkBox.Checked = False
                    End If
                Next
            End If
        Next
    End Sub

End Class

For each uc As UC ?

This will have the infinite recursive problem also. Provided you add all Checkboxe's click events to the handles clause.

[kaliman79912]

It works better if you do it from the click event instead of the checkchanged this is all you would need.

    Private Sub CheckBox1_Click(sender As Object, e As EventArgs) Handles CheckBox1.Click, CheckBox2.Click, CheckBox3.Click, CheckBox4.Click
        Dim mySender As CheckBox = DirectCast(sender, CheckBox)
        For Each Cb As CheckBox In Me.Controls.OfType(Of CheckBox)()
            Cb.Checked = False
        Next
        mySender.Checked = True
    End Sub

Sort of, what if the user changes the status of the checked property with the keyboard?

[kaliman79912]

To add to this, you can filter the controls to just the type you care about in the loop like this:

        For Each C As CheckBox In myPanel.Controls.OfType(Of CheckBox)()

        Next

This is true, although I was assuming all controls inside the panel were CheckBoxes

[Vexslasher]

Sort of, what if the user changes the status of the checked property with the keyboard?

It still works perfectly you can use the keyboard or the mouse doesn't matter.

[Edgemeal]

For each uc As UC ?

This will have the infinite recursive problem also. Provided you add all Checkboxe's click events to the handles clause.

I think i got the wrong idea, I was going across multiple usercontrols, never mind LOL!

[kleinma]

Because, if you change the checked property inside the CheckedChange event handler, that action will trigger the handler again, in an infinite recursive loop.

Not if you cast the sender to checkbox and check to see if it is checked or not before taking action.

[kaliman79912]

It still works perfectly you can use the keyboard or the mouse doesn't matter.

The keyboard will not trigger the Click event

[kaliman79912]

Not if you cast the sender to checkbox and check to see if it is checked or not before taking action.

I may be off here, but lets say CB2 is checked (of course none others are), then the users checks CB1. At that moment the handler will be trigered and start the process. It iwll check to see if CB2 is checked and since it is, and it should not be, then it changes the status. This will trigger the CheckedChange event now for CB2 and start it all again. But now, the sender is CB2 so how can we diferentiate from the first recursion of the sub? how can we know now that the purpose of the handler is to leave the sender unchecked when on the first recursion it was the other way around?

[Vexslasher]

The keyboard will not trigger the Click event

It does I press space bar and that works..

[kaliman79912]

It does I press space bar and that works..

Sorry, you are right, The sub I created to test it had only one checkBox click event handled and was not doing it for the rest. duh!

[kleinma]

I may be off here, but lets say CB2 is checked (of course none others are), then the users checks CB1. At that moment the handler will be trigered and start the process. It iwll check to see if CB2 is checked and since it is, and it should not be, then it changes the status. This will trigger the CheckedChange event now for CB2 and start it all again. But now, the sender is CB2 so how can we diferentiate from the first recursion of the sub? how can we know now that the purpose of the handler is to leave the sender unchecked when on the first recursion it was the other way around?

So lets say you have 4 checkboxes on a form and you want them to act like radiobuttons. This is how I would code it, and it does not get stuck in recursion, and it does not require me to add and remove event handlers.

    Private Sub AnyCheckbox_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox1.CheckedChanged, CheckBox2.CheckedChanged, CheckBox3.CheckedChanged, CheckBox4.CheckedChanged

        'GET CHECKBOX THAT INITIATED EVENT FIRING
        Dim SenderCB As CheckBox = DirectCast(sender, CheckBox)
        'WE ONLY CARE TO DO SOMETHING WHEN A CHECKBOX GETS CHECKED (NOT UNCHECKED)
        'SO EXIT THE EVENT HANDLER IF OUR SENDER IS NOT CHECKED
        If Not SenderCB.Checked Then Return

        'LOOP ALL CHECKBOXES IN CONTAINER AND UNCHECK THEM IF THEY ARE CHECKED AND
        'ALSO IF THEY ARE NOT THE SENDER THAT INITIATED THIS EVENT
        For Each CB As CheckBox In Me.Controls.OfType(Of CheckBox)()
            If CB.Checked AndAlso CB IsNot sender Then
                CB.Checked = False
            End If
        Next

    End Sub

[passel]

It seems like the code in post 7 could be simplified.
You'll get the checkedChanged first on the one that is just checked.
So check to see if it is checked then reset the ones that are not it.

  Private Sub CheckBox1_CheckedChanged(sender As System.Object, e As System.EventArgs) Handles CheckBox1.CheckedChanged, CheckBox2.CheckedChanged, CheckBox3.CheckedChanged
    Dim mySender As CheckBox = DirectCast(sender, CheckBox)
    If mySender.Checked Then
      For Each myControl As CheckBox In Panel1.Controls
        If mySender IsNot myControl Then myControl.Checked = False
      Next
    End If
  End Sub

Edit: I guess I was a bit slow on getting that posted....

[kaliman79912]

Yes, you are correct, This approach is similar to the one using a boolean variable as a status, because the procedure is triggered, you just decide inside the code that nothing should be done in some cases. yours is better in the respect that it will only call the handler one more time as there is only one checkBox that can be checked in this scenario.

[Sitten Spynne]

If I had to pick one of these approaches, I'd use what #2 and #3 are suggesting. #5 is pretty horrid, and I don't even feel like evaluating #9 because it looks so complex I'd immediately look for another solution.

Here's what I'd do.

We have four choices, but only want one to be True at a given time. I'm thinking this is like we're choosing some toppings for some ice cream, but the store is cheap and only lets you pick one. I started imagining how I'd represent this as a type with 4 Boolean properties and setters that enforce only 1 is true, but I quickly ended up in the same kind of looping problem we're trying to avoid. Hm.

But then I realized we're selecting one thing, then updating a set of controls based on that one selection. That's far easier to deal with because we can ignore CheckedChanged when it's an "uncheck" event. For brevity, I'll use two checkboxes, and our toppings will be "Hot Fudge" and "Caramel".

Public Class Form1

    Private _selectedTopping As String

    Sub New()
        InitializeComponent()

        ' My 'Caramel' checkbox was the first.
        SelectTopping("Caramel")
    End Sub

    Private Sub SelectTopping(ByVal topping As String)
        _selectedTopping = topping

        chkCaramel.Checked = (_selectedTopping = "Caramel")
        chkHotFudge.Checked = (_selectedTopping = "Hot Fudge")
    End Sub

    Private Sub chkCaramel_CheckedChanged(sender As Object, e As EventArgs) Handles chkCaramel.CheckedChanged
        If chkCaramel.Checked Then
            SelectTopping("Caramel")
        End If
    End Sub

    Private Sub chkHotFudge_CheckedChanged(sender As Object, e As EventArgs) Handles chkHotFudge.CheckedChanged
        If chkHotFudge.Checked Then
            SelectTopping("Hot Fudge")
        End If
    End Sub

End Class

Now, this is a bit tedious for multiple checkboxes. If you opt to make the text of the checkbox the "name" of the selected topping, we can condense:

Public Class Form1

    Private _selectedTopping As String
    Private _toppings() As CheckBox

    Sub New()
        InitializeComponent()

        _toppings = {chkCaramel, chkHotFudge}
        For Each chkTopping In _toppings
            AddHandler chkTopping.CheckedChanged, AddressOf topping_CheckedChanged
        Next

        SelectTopping(_toppings(0).Text)
    End Sub

    Private Sub SelectTopping(ByVal topping As String)
        _selectedTopping = topping

        For Each chkTopping As CheckBox In _toppings
            chkTopping.Checked = (chkTopping.Text = _selectedTopping)
        Next
    End Sub

    Private Sub topping_CheckedChanged(sender As Object, e As EventArgs)
        Dim chkTopping = CType(sender, CheckBox)
        If chkTopping.Checked Then
            SelectTopping(chkTopping.Text)
        End If
    End Sub

End Class

I really wanted to show an approach that separated UI and logic, but it'd take more time than I think I have right now. I can see the solution in terms of WPF, but getting the same thing in terms of Windows Forms doesn't seem inherently easy. And it definitely looks silly in the isolated context of this example.

*edit*
I lied. Here you go, the enterprisey as heck way to do this. I still think there's a better way I haven't quite nailed down yet that doesn't have to rely on the text of the UI controls, but every time I lay out the 4-boolean version of the Controller I want to gag:

Imports System.ComponentModel
Imports System.Runtime.CompilerServices

Public Class Form1

    Private _controller As Form1Controller
    Private _toppingBoxes() As CheckBox

    Sub New()
        InitializeComponent()
        InitializeToppingBoxes()

        _controller = New Form1Controller()
        AddHandler _controller.PropertyChanged, AddressOf HandleControllerPropertyChanged

        _controller.SelectedTopping = "Caramel"
    End Sub

    Private Sub InitializeToppingBoxes()
        _toppingBoxes = {chkCaramel, chkHotFudge}
        For Each toppingBox In _toppingBoxes
            AddHandler toppingBox.CheckedChanged, GenerateCheckHandler(toppingBox)
        Next
    End Sub

    Private Sub UpdateToppings()
        For Each toppingBox In _toppingBoxes
            toppingBox.Checked = toppingBox.Name = _controller.SelectedTopping
        Next
    End Sub

    Private Function GenerateCheckHandler(ByVal checkBox As CheckBox) As EventHandler
        Return Sub(sender, e)
                   If checkBox.Checked Then
                       _controller.SelectedTopping = checkBox.Name
                   End If
               End Sub
    End Function

    Private Sub HandleControllerPropertyChanged(sender As Object, e As PropertyChangedEventArgs)
        Select Case e.PropertyName
            Case "SelectedTopping"
                UpdateToppings()
        End Select
    End Sub

End Class

Public Class Form1Controller
    Implements INotifyPropertyChanged

    Private _selectedTopping As String
    Public Property SelectedTopping As String
        Get
            Return _selectedTopping
        End Get
        Set(value As String)
            If _selectedTopping <> value Then
                _selectedTopping = value
                RaisePropertyChanged()
            End If
        End Set
    End Property

    Protected Sub RaisePropertyChanged(<CallerMemberName> Optional ByVal propertyName As String = "")
        RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
    End Sub

    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged

End Class

[henrikl]

Thank you all.

I have read all posts with interest.

Kaliman79912
You are right about the infinite recursive loop. That was my problem from the beginning.

Kleinma
Whit your solution I must click twice to get a checkbox checked. That was also a problem I was facing with my own code.

Passel
Your solution works perfect and is very short.

Thank you again,
Henrik

Here is what I ended up with

    Private Sub frmMain_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        For Each Nchk As Control In NpanSettings.Controls.OfType(Of PicCheckBox)()
            AddHandler DirectCast(Nchk, PicCheckBox).CheckedChanged, AddressOf NchkCheckChanged
        Next
    End Sub

    Private Sub NchkCheckChanged(ByVal sender As Object, ByVal e As EventArgs)
        If Initializing Then Return
        Dim SenderCB As PicCheckBox = DirectCast(sender, PicCheckBox)
        If SenderCB.Checked Then
            For Each chk As PicCheckBox In NpanSettings.Controls.OfType(Of PicCheckBox)()
                If SenderCB IsNot chk Then chk.Checked = False
            Next
        End If
    End Sub