[RESOLVED] Creating RegEx COM wrapper

[MikiSoft]

I have some application written in VB6 which uses obsolete VBScript Regular Expressions 5.5 library, and I need to use more advanced patterns which are not supported in that library. I have already asked for help in VB6 section, but I didn't get any answers, so I found this: https://msdn.microsoft.com/en-us/lib...b5000cl_topic3
I don't have any experience in VB.NET so only you can help me to solve this problem. Therefore, I need a COM DLL (its creation is explained on above link) which will have code equivalent to this (used for VB6):

Function RegExpr(myPattern As String, myString As String, Optional myReplace As String, Optional bytResults As Byte, Optional intStart As Integer, Optional intCount As Integer) As Variant
'Uses "Microsoft VBScript Regular Expressions 5.5" library.
On Error GoTo E
    Dim objRegExp As RegExp
    Set objRegExp = New RegExp
    objRegExp.Pattern = myPattern
    objRegExp.IgnoreCase = True
    objRegExp.Global = True
    If bytResults > 0 Then
        Dim colMatches As MatchCollection
        Set colMatches = objRegExp.Execute(myString)
        If intCount = 0 Then intCount = colMatches.Count - intStart
        Dim i As Integer
        For i = intStart To intStart + intCount - 1
            If myReplace = vbNullString Then RegExpr = RegExpr & colMatches.Item(i).Value & vbNewLine Else: RegExpr = RegExpr & objRegExp.Replace(colMatches.Item(i).Value, myReplace) & vbNewLine
            If i = colMatches.Count - 1 Or bytResults = 2 Then Exit For
        Next
        RegExpr = Left$(RegExpr, Len(RegExpr) - 2)
    Else: RegExpr = objRegExp.Test(myString)
    End If
E:
End Function

Thanks in advance!

[Niya]

That article is targeted to Visual Studio 2003 which is quite ancient.

Nonetheless, what you are asking can be done relatively easily. But before we get into that, did you at least try looking for a more modern COM/ActiveX based RegEx library ?

[MikiSoft]

Yes, I've looked on official RegEx site and for VB6 there is only VBScript's library mentioned. Also I have tried to search on Google for a COM DLL, and unfortunately I found nothing which is equivalent to it.

[Niya]

Ok, do you have any flavor of Visual Studio after Visual Studio 6 ? In other words, do you have VB.Net ?

[MikiSoft]

Nope, but if I need to then I'll download and install it. If you're thinking about how should I get the DLL, you can post code of the wrapper here, then compile it and send me via PM so I won't need to download the whole VS to use it only once.

[Niya]

Well if you trust that I'm not gonna give you a Trojan , I'll PM you a DLL that wraps the .Net Framework's RegEx.

You're gonna have to wait a while though. I have to write it first and I have to install VB6 on my PC to test since its been a while since I did any COM Interop stuff so I'll need to make sure I did it right.

[MikiSoft]

Then I've found the right person for this, thanks! I will patiently wait.
And of course that I trust you.

[Niya]

Ok, Here is the DLL. Its a OneDrive link to a Zip file that contains the DLL, RegAsm which is used to register it, and two batch files for registering and unregistering the DLL.

To use it, open the zip file and extract the folder inside. Run register.bat, which you would find inside the folder, and you will be able to use it from your VB6 application. Note this though: After registering the DLL, you must not move the folder since the COM entries in the Windows registry will be pointing to that folder. If you need to move the folder then you must unregister the DLL via
unregister.bat first. Then you can move the folder and re-register.

One other thing, make sure that you have the .Net Framework 3.5 or up installed on whatever PC you're using this DLL on.

When you want to use it from VB6, you can go to the references dialog and find DotNetComRegExLib:-


You can then use it from your VB6 application like this:-

'
    Dim r As New DotNetRegEx
    Dim matches() As String
    
    
    r.Pattern = "whatever pattern"
    matches = r.Execute("My input")

Now, I've never used regular expressions so I don't really know anything much about it. I just exposed what you seemed to want which was pattern matching but there are a quite a few other methods like Replace and such. Just let me know if you need any of those exposed too.

And finally, here is the .Net code for the DLL:-

Imports System.Text.RegularExpressions
Imports System.Runtime.InteropServices
 
 
<Guid("67d9031c-cb2b-40dc-99a9-f8d7bbdfa5c5")> _
Public Interface IDotNetRegEx
    Property Pattern As String
    Property IgnoreCase As Boolean
    Function Execute(ByVal input As String) As String()
    Function Replace(ByVal input As String, ByVal replacement As String) As String
    Function IsMatch(ByVal input As String) As Boolean
 
End Interface
 
 
<ComVisible(True)> _
<ClassInterface(Runtime.InteropServices.ClassInterfaceType.None)> _
<Guid("90e4bc58-b2c2-4cd5-9d31-5f4d64ba6ccb")> _
Public Class DotNetRegEx
    Implements IDotNetRegEx
 
    Public Sub New()
    End Sub
 
    Public Property Pattern As String Implements IDotNetRegEx.Pattern
 
    Public Property IgnoreCase As Boolean Implements IDotNetRegEx.IgnoreCase
 
    Public Function IsMatch(ByVal input As String) As Boolean Implements IDotNetRegEx.IsMatch
        Dim reg = GetNewRegex()
 
        Return reg.IsMatch(input)
    End Function
 
    Public Function Replace(ByVal input As String, ByVal replacement As String) As String Implements IDotNetRegEx.Replace
        Dim reg As Regex = GetNewRegex()
 
        Return reg.Replace(input, replacement)
    End Function
 
    Public Function Execute(ByVal input As String) As String() Implements IDotNetRegEx.Execute
 
        Dim reg As Regex = GetNewRegex()
 
        Dim matches As MatchCollection = reg.Matches(input)
 
        Return matches.Cast(Of Match).Select(Function(m) m.Value).ToArray
    End Function
 
    Private Function GetNewRegex() As Regex
        Dim options As RegexOptions
 
        If Me.IgnoreCase Then
            options = options Or RegexOptions.IgnoreCase
        End If
 
        Return New Regex(Me.Pattern, options)
    End Function
 
End Class

[UPDATE]

I updated the DLL. The DotNetRegEx class now has the Replace method, the IsMatch method and the IgnoreCase property.

I also updated the posted source code.

[MikiSoft]

Thank you very much for the effort! Yes, I need Replace and Test command like in my example from main post; optional properties should be: Count, and if they exist - IgnoreCase and Global if they're by default set to False. And then my function will kick in.
P.S. Can minimum requirement be lowered to .NET 2.0? RegEx class should be same for every version so it should be used on the first where it appeared.

[Niya]

Ok, I extended it. I updated the link in post 8 so it will download the updated version. I added the Replace but there is no Test method. I assume Test checks the input to see if there are any matches ? If so, I added the IsMatch method which does this. As for counting matches, I had the Execute method return a String array so you can use UBound against that to get a count of matches.

P.S. Can minimum requirement be lowered to .NET 2.0? RegEx class should be same for every version so it should be used on the first where it appeared.

I don't understand what you mean by this.

[MikiSoft]

Thanks again, now I can implement it!

I mean that if it can be compiled against .NET 2.0?

[Niya]

I mean that if it can be compiled against .NET 2.0?

Not in its current state. I used LINQ in the source code which is not available in .Net 2.0.

[MikiSoft]

Hm, OK then. I thought that it will be better compatible if it's compiled for .NET 2.0 because I personally have an old XP machine which has only .NET 2.0, and I think that it's not the only case when there are no new versions installed. Just don't get me wrong because I respect your work and I will definitely use this as replacement for the old RegEx library. And, have a nice day!

[Niya]

.Net 3.5 comes by default with Windows 7 and higher versions come with Windows 8 and presumably Windows 10 so you can just register and use the library right away on such PCs. No version of the .Net Framework comes with XP so you're gonna have to install it, might as well install the latest one. So you don't really gain anything by having the library target 2.0. It just gives me more work since without LINQ, I'd be writing a bit more code.

[MikiSoft]

You're right. I forgot to mark this thread as resolved, so here it is.

[Niya]

So I take it you already tested it and it worked the way you wanted it to ? If not, lemme know what the problems are, as long as it doesn't involve the regular expressions themselves since, as I said, I have a very limited understanding of regular expressions.

[MikiSoft]

Sorry for late response because I was hunting for and installing .Net 3.5. It's working as it should, thanks!

[loquat]

here has a entended regexp engine
deelx: http://www.regexlab.com/en/deelx/ c++ source code in it
and here is the compiled version for vb6
http://www.newxing.com/Tech/Program/...egExp_643.html

[softv]

So I take it you already tested it and it worked the way you wanted it to ? If not, lemme know what the problems are, as long as it doesn't involve the regular expressions themselves since, as I said, I have a very limited understanding of regular expressions.

First of all, Thanks a TON for the dll and the .net source code. I was very much looking forward for a DLL like this one.


Well, two questions:

1) If I use this in my app which has to be deployed at user-end, is it the same procedure for registering the tlb and/or dll during deployment too? If not and if a simpler procedure exists, I would be much grateful if you can let me know the exact steps for the same. In fact, will it be possible to use the tlb and dll without registering at user-end? If I am right, the tlb gets compiled along with my app's exe. Right?

2) I could not find a way to find the index of the matches. Will it be possible for you please to update your tlb and DLL to give a list of all the matches' indexes too.


Very kind regards.

[Niya]

1) If I use this in my app which has to be deployed at user-end, is it the same procedure for registering the tlb and/or dll during deployment too? If not and if a simpler procedure exists, I would be much grateful if you can let me know the exact steps for the same. In fact, will it be possible to use the tlb and dll without registering at user-end? If I am right, the tlb gets compiled along with my app's exe. Right?

Yes, the procedure is the same. Unfortunately at this time I don't know how to use type libraries without registering them. It's definitely possible, the VB6 guys do it all the time but I've just never got around to learning how to do it. It's quite a bit involved. It requires a bunch of settings in a manifest file and whatnot.

2) I could not find a way to find the index of the matches. Will it be possible for you please to update your tlb and DLL to give a list of all the matches' indexes too.

All I did with this project was expose .Net's Regex class through COM so VB6 applications can use it. I'm not very familiar with the Regex object itself so I don't even know if it can do that. Perhaps someone can fill me in on this. If it has a way, then this could also be exposed to VB6 for use.