[RESOLVED] MSChart Zoom with mouse roller?

[Frabulator]

I have the standard zoom function with the mouse down, click and drag to zoom in that you can enable in the main chart settings. I was wondering, is there an easy way of adding in a function to where the chart zooms in by a certain percentage where the mouse is when the roller is activated?

I researched it a while back, and couldn't get it to work so I abandoned it. Thought I'd bring the question here to see what you all thought

Thanks!

Frab

[dday9]

If you already have the zoom working then what you'll need to do is generate the MouseWheel event for your control and then check if the Delta property greater than or less than 0:

Private Sub Chart1_MouseWheel(ByVal sender As Object,ByVal e As System.Windows.Forms.MouseEventArgs) Handles Chart1.MouseWheel
    If e.Delta > 0 Then
        'Zoom up
    Else
        'Zoom down
    End If
End Sub

[Frabulator]

If you already have the zoom working then what you'll need to do is generate the MouseWheel event for your control and then check if the Delta property greater than or less than 0:

Private Sub Chart1_MouseWheel(ByVal sender As Object,ByVal e As System.Windows.Forms.MouseEventArgs) Handles Chart1.MouseWheel
    If e.Delta > 0 Then
        'Zoom up
    Else
        'Zoom down
    End If
End Sub

Thank you for the reply

I have already gotten that far, however my zoom function I didnt code. It was the default zoom that mscharts automatically comes with.
I have been trying to break it down and see (by trial and error) if I can get it working. So far the only thing that I have came up with is the following code

Private Sub Chart1_MouseWheel(sender As Object, e As MouseEventArgs) Handles Chart1.MouseWheel
 
            zoomamount = TextBox28.Text
 
 
 
        Dim x As Int32 = e.Location.X
        Dim y As Int32 = e.Location.Y
 
        Dim chartStarty As Int32 = Chart1.Location.Y
        Dim chartstartx As Int32 = Chart1.Location.X
 
        Dim chartsizey As Int32 = Chart1.Size.Height
        Dim chartsizex As Int32 = Chart1.Size.Width
 
        Dim currentSIZEx As Int32 = Chart1.ChartAreas(0).AxisX.Maximum
        Dim currentSIZEy As Int32 = Chart1.ChartAreas(0).AxisY.Maximum
 
 
 
        If e.Delta > 0 Then
           ' Chart1.ChartAreas(0).CursorY.SelectionStart = (y / (zoomamount))
           ' Chart1.ChartAreas(0).CursorX.SelectionStart = (x / zoomamount))
 
           ' Chart1.ChartAreas(0).CursorY.SelectionEnd = ((chartsizey - y) / (zoomamount))
          '  Chart1.ChartAreas(0).CursorX.SelectionEnd = ((chartsizex - x) / (zoomamount))
 
            Chart1.ChartAreas(0).AxisY.Maximum = (currentSIZEy - (25))
            Chart1.ChartAreas(0).AxisX.Maximum = (currentSIZEx - (25))
        Else
            Chart1.ChartAreas(0).AxisY.Maximum = (currentSIZEy + (25))
            Chart1.ChartAreas(0).AxisX.Maximum = (currentSIZEx + (25))
 
        End If
    End Sub

however this just changes the max and min of the chart. Not really a zoom, and with no scroll bars.

[dday9]

I'm sorry, I must have misunderstood. I thought you had the zoom function already worked up. I'm unsure as to how to zoom in and out on a Chart because I've never used a Chart control before, so I'll have to bow out. Good luck though!

[Frabulator]

I'll have to bow out. Good luck though!

No sweat, and thanks

[Frabulator]

as an update, i have figured out part of the code.

If e.Delta < 0 Then
            Chart1.ChartAreas(0).AxisX.ScaleView.ZoomReset()
            Chart1.ChartAreas(0).AxisY.ScaleView.ZoomReset()
            amountofrolls = 0
        Else
 
            Dim xMin As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMinimum
            Dim xMax As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMaximum
            Dim yMin As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMinimum
            Dim yMax As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMaximum
            Dim amm As Double = 4
 
         
 
            Dim posXStart As Double = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X) - (xMax - xMin) / amm
 
            Dim posXFinish As Double = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X) + (xMax - xMin) / amm
 
            Dim posYStart As Double = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y) - (yMax - yMin) / amm
 
            Dim posYFinish As Double = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y) + (yMax - yMin) / amm
 
 
 
 
            Chart1.ChartAreas(0).AxisX.ScaleView.Zoom(posXStart, posXFinish)
            Chart1.ChartAreas(0).AxisY.ScaleView.Zoom(posYStart, posYFinish)
        End If

the AxisX.ScaleView.Zoom(Double, Double) is the actual zoom function itself. Now I need to figure out the right math formula to get it to work properly. Any help on this would be greatly appreciated.

Rigth now, it kinda zooms right, but not 100%. Its a bit hard for me to explain. It zooms in, but only if the mouse is not in the center of the chart.

[Frabulator]

bump

[Inferrd]

This is not quite 100%. Not sure why, but:

Dim scale As Double = 2   '   or what ever

Dim xMin As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMinimum
Dim xMax As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMaximum
Dim yMin As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMinimum
Dim yMax As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMaximum


Dim xValue As Double = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X)
Dim yValue As Double = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y)

Dim posXStart As Double = xValue - (xValue - xMin) / scale
Dim posXFinish As Double = posXStart + (xMax - xMin) / scale

Dim posYStart As Double = yValue - (yValue - yMin) / scale
Dim posYFinish As Double = posYStart + (yMax - yMin) / scale


Chart1.ChartAreas(0).AxisX.ScaleView.Zoom(posXStart, posXFinish)
Chart1.ChartAreas(0).AxisY.ScaleView.Zoom(posYStart, posYFinish)

[Frabulator]

This is not quite 100%. Not sure why

Thank you so much!
You have put me on the right track. I was able to modify your code to get a close to perfect zoom in function. What I changed was made an area that said if the mouse was within a percentage of the zoom area then it would not zoom in on it. That way, if you are close to the edge you will stay on the edge.

If e.Delta < 0 Then
            Chart1.ChartAreas(0).AxisX.ScaleView.ZoomReset()
            Chart1.ChartAreas(0).AxisY.ScaleView.ZoomReset()
            amountofrolls = 0
        Else
            Dim scale As Double = 1.25   '   or what ever
 
            Dim xMin As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMinimum
            Dim xMax As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMaximum ' + Chart1.ChartAreas(0).AxisX.ScaleView.Position
            Dim yMin As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMinimum
            Dim yMax As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMaximum ' + Chart1.ChartAreas(0).AxisX.ScaleView.Position
 
 
            Dim xValue As Double = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X)
            Dim yValue As Double = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y)
 
 
            Dim posXFinish As Double
            Dim posXStart As Double
 
 
 
            'this code checks to see if you are within a certain percentage of the starting point
            ' and if you are it will not zoom in
            '
            'check zoom  for x Start
            If (xValue - (xValue - xMin) / scale) >= xValue Then
                posXStart = xValue - (xValue - xMin)
            Else
                posXStart = xValue - (xValue - xMin) / scale
            End If
 
            '
            'check zoom  for x finish
            If xValue >= (posXStart + (xMax - xMin) / scale) Then
                posXFinish = posXStart + (xMax - xMin)
            Else
                posXFinish = posXStart + (xMax - xMin) / scale
            End If
 
 
 
            Dim posYFinish As Double
            Dim posYStart As Double
 
 
            '
            'check zoom for Y start
            If (yValue - (yValue - yMin) / scale) >= yValue Then
                posYStart = yValue - (yValue - yMin)
            Else
                posYStart = yValue - (yValue - yMin) / scale
            End If
 
 
            '
            'check zoom for Y finish
            If yValue >= (posYStart + (yMax - yMin) / scale) Then
                posYFinish = posYStart + (yMax - yMin)
            Else
                posYFinish = posYStart + (yMax - yMin) / scale
            End If
 
 
 
            Chart1.ChartAreas(0).AxisX.ScaleView.Zoom(posXStart, posXFinish)
            Chart1.ChartAreas(0).AxisY.ScaleView.Zoom(posYStart, posYFinish)
 
 
 
 
 
 
        End If

Now I'll get cracking on the zoom out
Thanks!

[AlMoutaz_Billah]

Now this is Working very fine with me zooming in & out Thanks guys you inspired me...
شكرا لكم رفاقي ,هذا الكود لكم ولمن يريد أن يستخدمه صدقة لوجه الله

 Private Sub Chart1_MouseWheel(sender As Object, e As MouseEventArgs) Handles Chart1.MouseWheel
        Try
            Dim ZoomFactor As Double = 0.25   '0 to 1 Represent 0% to 100% Every Wheel Tick.

            Dim Current_xMin As Integer = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMinimum
            Dim Current_xMax As Integer = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMaximum
            Dim Current_yMin As Integer = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMinimum
            Dim Current_yMax As Integer = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMaximum

            Dim PointerPosOnChart_xAxis As Integer = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X)
            Dim PointerPosOnChart_yAxis As Integer = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y)

            Dim New_xMin As Integer
            Dim New_xMax As Integer
            Dim New_yMin As Integer
            Dim New_yMax As Integer

            If Current_xMin <= PointerPosOnChart_xAxis And PointerPosOnChart_xAxis <= Current_xMax And
                Current_yMin <= PointerPosOnChart_yAxis And PointerPosOnChart_yAxis <= Current_yMax Then

                If e.Delta > 0 Then 'Zoom in While Moving The Mouse Wheel Forward (Up)

                    New_xMin = Current_xMin + ((PointerPosOnChart_xAxis - Current_xMin) * ZoomFactor)
                    New_xMax = Current_xMax - ((Current_xMax - PointerPosOnChart_xAxis) * ZoomFactor)
                    New_yMin = Current_yMin + ((PointerPosOnChart_yAxis - Current_yMin) * ZoomFactor)
                    New_yMax = Current_yMax - ((Current_yMax - PointerPosOnChart_yAxis) * ZoomFactor)

                ElseIf e.Delta < 0 Then 'Zoom out While Moving The Mouse Wheel Backward (Down)

                    New_xMin = Current_xMin - ((PointerPosOnChart_xAxis - Current_xMin) * ZoomFactor)
                    New_xMax = Current_xMax + ((Current_xMax - PointerPosOnChart_xAxis) * ZoomFactor)
                    New_yMin = Current_yMin - ((PointerPosOnChart_yAxis - Current_yMin) * ZoomFactor)
                    New_yMax = Current_yMax + ((Current_yMax - PointerPosOnChart_yAxis) * ZoomFactor)

                End If

                Chart1.ChartAreas(0).AxisX.ScaleView.Zoom(New_xMin, New_xMax)
                Chart1.ChartAreas(0).AxisY.ScaleView.Zoom(New_yMin, New_yMax)

            End If
        Catch ex As System.Exception
            MsgBox(ex.Message)
        End Try
    End Sub

[Timeshell]

I have further improved this code by making zoom out work as well as zoom in.

 Private Sub Chart1_MouseWheel(sender As Object, e As MouseEventArgs) Handles Chart1.MouseWheel
    Try

        With Chart1

            Dim xMin As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMinimum
            Dim xMax As Double = Chart1.ChartAreas(0).AxisX.ScaleView.ViewMaximum ' + Chart1.ChartAreas(0).AxisX.ScaleView.Position
            Dim yMin As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMinimum
            Dim yMax As Double = Chart1.ChartAreas(0).AxisY.ScaleView.ViewMaximum ' + Chart1.ChartAreas(0).AxisX.ScaleView.Position

            Dim xValue As Double = Chart1.ChartAreas(0).AxisX.PixelPositionToValue(e.Location.X)
            Dim yValue As Double = Chart1.ChartAreas(0).AxisY.PixelPositionToValue(e.Location.Y)

            Dim posXFinish As Double
            Dim posXStart As Double

            Dim posYFinish As Double
            Dim posYStart As Double



            'this code checks to see if you are within a certain percentage of the starting point
            ' and if you are it will not zoom in

            If e.Delta > 0 Then
                'check zoom  for x Start
                If (xValue - (xValue - xMin) / scale) >= xValue Then
                    posXStart = xValue - (xValue - xMin)
                Else
                    posXStart = xValue - (xValue - xMin) / scale
                End If

                'check zoom  for x finish
                If xValue >= (posXStart + (xMax - xMin) / scale) Then
                    posXFinish = posXStart + (xMax - xMin)
                Else
                    posXFinish = posXStart + (xMax - xMin) / scale
                End If

                'check zoom for Y start
                If (yValue - (yValue - yMin) / scale) >= yValue Then
                    posYStart = yValue - (yValue - yMin)
                Else
                    posYStart = yValue - (yValue - yMin) / scale
                End If

                'check zoom for Y finish
                If yValue >= (posYStart + (yMax - yMin) / scale) Then
                    posYFinish = posYStart + (yMax - yMin)
                Else
                    posYFinish = posYStart + (yMax - yMin) / scale
                End If
            ElseIf e.Delta < 0 Then
                'check zoom  for x Start
                If (xValue - (xValue - xMin) * scale) <= xValue Then
                    posXStart = xValue - (xValue - xMin)
                Else
                    posXStart = xValue - (xValue - xMin) * scale
                End If

                'check zoom  for x finish
                If xValue <= (posXStart + (xMax - xMin) * scale) Then
                    posXFinish = posXStart + (xMax - xMin)
                Else
                    posXFinish = posXStart + (xMax - xMin) * scale
                End If

                'check zoom for Y start
                If (yValue - (yValue - yMin) * scale) >= yValue Then
                    posYStart = yValue - (yValue - yMin)
                Else
                    posYStart = yValue - (yValue - yMin) * scale
                End If

                'check zoom for Y finish
                If yValue >= (posYStart + (yMax - yMin) * scale) Then
                    posYFinish = posYStart + (yMax - yMin)
                Else
                    posYFinish = posYStart + (yMax - yMin) * scale
                End If

            End If

            Chart1.ChartAreas(0).AxisX.ScaleView.Zoom(posXStart, posXFinish)
            Chart1.ChartAreas(0).AxisY.ScaleView.Zoom(posYStart, posYFinish)


        End With


    Catch ex As System.Exception
        MsgBox(ex.Message)
    End Try
End Sub