Datagrid

[Jagjit]

Hi

I have command button & i want when clicked another form should open in which Data is displayed & when user double clicks on Datagrid row it should return values to parent form.

Thanks

[gibra]

Sorry, but you are not clear (to me at least) ...

[Zvoni]

Sorry, but you are not clear (to me at least) ...

He doesn't know, how to make the communication between parent-form and child-form
Parent-Form has a commandbutton, and probably some labels or textboxes.
He hits the command-button, another form opens up, which has a datagrid (whichever).
He doubleclicks a row in that datagrid, and ... presto: the selected data from the datagrid is in the lables/textboxes on the parent form

[SamOscarBrown]

When you double-click on your datagrid, you can opt to assign values from that grid to global variables (set in a module), or you can assign those values directly to controls on your main form, like:

Dim myGridValue as String
myGridValue = (whatever cell(s) you want, assign it(them) here)
myMainForm.Text1.Text = myGridValue

or more simply:
myMainForm.Text1.Text = (whatever cell(s) you want, assign it(them) here)

[techgnome]

If I might offer a slightly different approach. I'd create a property or properties (or functions, or something) on the child form, and have the calling form get the values that way. I wouldn't have the child form force the data into the parent. While Sam's solution is simple and should work... it has a high risk of breaking down the road. It also relies heavily on default instances of forms... which in VB6 probably isn't a huge deal, but could still be a problem.

-tg

[SamOscarBrown]

Sam's solutions are usually simple, because that is all I understand! :-) I leave the complicated stuff to the experts!

[DataMiser]

I have never saw any issues from using default form instances in VB6.

Another option would be to use a public recordset or pass an instance of the recordset between forms.

[techgnome]

It's never a problem as long as that's all you use...

but if the form is a created instance, then using this:
myMainForm.Text1.Text = myGridValue

will cause the data to be sent to the default instance rather than the specific instance. That's all. I'm used to working with multiple instances of forms, as well as child forms that are used in more than one place, so I've always used the properties method.


-tg

[DataMiser]

I use default instances and created instances as needed. Some projects have a mixture of the two. This does not cause any problems unless of course I have some errors in my code but if that is the case then I can't blame the form instances for that.

[Schmidt]

He doesn't know, how to make the communication between parent-form and child-form
Parent-Form has a commandbutton, and probably some labels or textboxes.
He hits the command-button, another form opens up, which has a datagrid (whichever).
He doubleclicks a row in that datagrid, and ... presto: the selected data from the datagrid is in the lables/textboxes on the parent form

Well, in this case using an ADO-Recordset is the simplest solution.
(DataMiser already hinted at that).

This ADO-Rs could be hosted (declared) in a cModel-Class - or in the
ParentForm directly (as a Private Variable).

In the following short Demo-Project-Setup, I choose hosting of the Rs in the ParentForm.

Requirements to run the example:
- ensure a new, empty StdExe-Project
- ensure two normal Forms in it (Form1 as our Parent-Form, Form2 will be our Grid-Form)
- add an ADO 2.5 reference to the Project (over the References Dialogue)
- add a "Microsoft DatGrid" to the Project (over the Components Dialogue)
- place a DataGrid-instance on Form2 (with its defaultname DataGrid1)

The above preparations will take only one minute...

Now place the following code within our parent-form (Form1):

Option Explicit

Private Rs As New ADODB.Recordset
Private WithEvents cmdShowGridForm As CommandButton
Private txtID As TextBox, txtName As TextBox, cmbGender As ComboBox

Private Sub Form_Load()
  Rs.Fields.Append "ID", vbLong
  Rs.Fields.Append "Name", vbString
  Rs.Fields.Append "Gender", vbString
  Rs.Open
  Rs.AddNew Array(0, 1, 2), Array(1, "Peter", "male")
  Rs.AddNew Array(0, 1, 2), Array(2, "Paul", "male")
  Rs.AddNew Array(0, 1, 2), Array(3, "Mary", "female")
  
  Set cmdShowGridForm = Controls.Add("VB.CommandButton", "cmdShowGridForm")
      cmdShowGridForm.Visible = True
      cmdShowGridForm.Caption = "Show Grid"
  
  ScaleMode = vbPixels
  Set txtID = AddAndBind("txtID", "VB.TextBox", "ID", 10, 40, 150, 23)
  Set txtName = AddAndBind("txtName", "VB.TextBox", "Name", 10, 70, 150, 23)
  Set cmbGender = AddAndBind("cmbGender", "VB.ComboBox", "Gender", 10, 100, 150)
      cmbGender.AddItem "male"
      cmbGender.AddItem "female"
End Sub

Private Function AddAndBind(Key, ProgID, DataField, x, y, dx, Optional dy)
  Set AddAndBind = Controls.Add(ProgID, Key)
      AddAndBind.DataField = DataField
  Set AddAndBind.DataSource = Rs
      AddAndBind.Visible = True
  If IsMissing(dy) Then AddAndBind.Move x, y, dx Else AddAndBind.Move x, y, dx, dy
End Function

Private Sub cmdShowGridForm_Click()
  Form2.ShowAndBind Rs, Me
End Sub

And the following code in the grid-form (Form2)

Option Explicit

Public Sub ShowAndBind(Rs As ADODB.Recordset, ParentForm)
  Set DataGrid1.DataSource = Rs
  Show , ParentForm
End Sub

I think, that shows what's possible per ADO-DataBinding quite nicely.

Olaf

[dilettante]

DataGrid controls are more for entry/editing of data than displaying/picking data.

I'd choose a flexgrid or ListView or something else designed for the described usage.

[Schmidt]

DataGrid controls are more for entry/editing of data than displaying/picking data.

I'd choose a flexgrid or ListView or something else designed for the described usage.

Well, the Datagrid-Control is more lightweight than e.g. a FlexGrid (since it avoids
any DataCopying from the underlying, bound ADO-Recordset).

And to switch off its (per default enabled) CellEditing-behaviour and make it
show "Full-Row-Selects" instead, it is enough to enhance my small Routine -
ShowAndBind (in Form2) about two Lines:

   DataGrid1.AllowUpdate = False
   DataGrid1.MarqueeStyle = dbgHighlightRow

Olaf