[RESOLVED] Repeat loop until word is not found again.

[Grags]

Hey Shmee again.

This is a sub from my program...

   Public Sub Highlight(ByVal r As RichTextBox)
        Try
            r.SelectAll()
            r.SelectionColor = Color.White
            r.DeselectAll()

            For Each strWord As String In RoomNames
                Dim startIndex As Integer = 0
                Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
                For Each wMatch As Match In wordMatchers.Matches(r.Text)
                    With r
                        .Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                        .SelectionColor = Color.Cyan
                        .SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                        startIndex = .SelectionStart
                    End With
                Next
            Next
            r.Select(r.TextLength, 0)
            r.ScrollToCaret()
        Catch
        End Try
    End Sub

When ran this is the output..



FYI RoomNames is a List of String that holds each and every Room Name in my game.

The problem. As you can see in the picture "The Babies Bedroom" is colored Cyan once and then ignored the second time.

I tried copying and pasting the whole For Each strWord... and pasting it underneath and that worked perfectly. But It's bad coding as it can run into the same problem later on if the Room Name is mentioned more than twice.


EDIT: Please ignore the green text.

EDIT2: Just incase you're incapable of ignoring the green text this is the complete sub :P

   Public Sub Highlight(ByVal r As RichTextBox)
        Try
            r.SelectAll()
            r.SelectionColor = Color.White
            r.DeselectAll()

            For Each strWord As String In ObjectList
                Dim startIndex As Integer = 0
                Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
                For Each wMatch As Match In wordMatchers.Matches(r.Text)
                    With r
                        .Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                        .SelectionColor = Color.Lime
                        .SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                        startIndex = .SelectionStart
                    End With
                Next
            Next
            For Each strWord As String In ItemList
                Dim startIndex As Integer = 0
                Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
                For Each wMatch As Match In wordMatchers.Matches(r.Text)
                    With r
                        .Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                        .SelectionColor = Color.Yellow
                        .SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                        startIndex = .SelectionStart
                    End With
                Next
            Next
            For Each strWord As String In RoomNames
                Dim startIndex As Integer = 0
                Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
                For Each wMatch As Match In wordMatchers.Matches(r.Text)
                    With r
                        .Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                        .SelectionColor = Color.Cyan
                        .SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                        startIndex = .SelectionStart
                    End With
                Next
            Next
            r.Select(r.TextLength, 0)
            r.ScrollToCaret()
        Catch
        End Try
    End Sub

[.paul.]

Instead of .Find, use .SelectionStart with [Match].Index and .SelectionLength with [Match].Value.Length

[Grags]

Instead of .Find, use .SelectionStart with [Match].Index and .SelectionLength with [Match].Value.Length

Would you elaborate please?

[Bulldog]

Here's an example of doing it a better way (and taking on board what Paul said too).

Public Sub Highlight(ByVal r As RichTextBox, ByVal MyList As List(Of String), ByVal MyColor As Color)
    'r.SelectAll()
    'r.SelectionColor = Color.White
    'r.DeselectAll()
    For Each strWord As String In MyList
        'Dim startIndex As Integer = 0
        Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
        For Each wMatch As Match In wordMatchers.Matches(r.Text)
            With r
                '.Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                .SelectionStart = wMatch.Index
                .SelectionLength = wMatch.Value.Length
                .SelectionColor = MyColor
                '.SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                'startIndex = .SelectionStart
            End With
        Next
    Next
    r.Select(r.TextLength, 0)
    r.ScrollToCaret()
End Sub
 
Private Sub Button11_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button11.Click
 
    RichTextBox2.Text = "a adhsj s abc adjhu abc defh opq cde xyz cde"
 
    Dim RoomNames As New List(Of String)()
    RoomNames.Add("abc")
    RoomNames.Add("cde")
 
    Dim OtherStrings As New List(Of String)()
    OtherStrings.Add("xyz")
    OtherStrings.Add("opq")
 
    ' Clear any existing selections first
    RichTextBox2.SelectAll()
    RichTextBox2.SelectionColor = Color.Black
    RichTextBox2.DeselectAll()
 
    Highlight(RichTextBox2, RoomNames, Color.Blue)
    Highlight(RichTextBox2, OtherStrings, Color.Red)
 
End Sub

[.paul.]

Public Sub Highlight(ByVal r As RichTextBox)
    
    r.SelectAll()
    r.SelectionColor = Color.White
    r.DeselectAll()

    For Each strWord As String In RoomNames
        Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
        For Each wMatch As Match In wordMatchers.Matches(r.Text)
            With r
                .SelectionStart = wMatch.Index
                .SelectionLength = wMatch.Length
                .SelectionColor = Color.Cyan
                .SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
            End With
        Next
    Next
    r.Select(r.TextLength, 0)
    r.ScrollToCaret()
End Sub

[Grags]

Here's an example of doing it a better way (and taking on board what Paul said too).

Public Sub Highlight(ByVal r As RichTextBox, ByVal MyList As List(Of String), ByVal MyColor As Color)
    'r.SelectAll()
    'r.SelectionColor = Color.White
    'r.DeselectAll()
    For Each strWord As String In MyList
        'Dim startIndex As Integer = 0
        Dim wordMatchers As New Regex(String.Format("\b{0}(\b\S|\b)", strWord))
        For Each wMatch As Match In wordMatchers.Matches(r.Text)
            With r
                '.Find(wMatch.Value, startIndex, RichTextBoxFinds.WholeWord)
                .SelectionStart = wMatch.Index
                .SelectionLength = wMatch.Value.Length
                .SelectionColor = MyColor
                '.SelectedText = StrConv(.SelectedText, VbStrConv.ProperCase)
                'startIndex = .SelectionStart
            End With
        Next
    Next
    r.Select(r.TextLength, 0)
    r.ScrollToCaret()
End Sub
 
Private Sub Button11_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button11.Click
 
    RichTextBox2.Text = "a adhsj s abc adjhu abc defh opq cde xyz cde"
 
    Dim RoomNames As New List(Of String)()
    RoomNames.Add("abc")
    RoomNames.Add("cde")
 
    Dim OtherStrings As New List(Of String)()
    OtherStrings.Add("xyz")
    OtherStrings.Add("opq")
 
    ' Clear any existing selections first
    RichTextBox2.SelectAll()
    RichTextBox2.SelectionColor = Color.Black
    RichTextBox2.DeselectAll()
 
    Highlight(RichTextBox2, RoomNames, Color.Blue)
    Highlight(RichTextBox2, OtherStrings, Color.Red)
 
End Sub

Awesome! Thanks a lot. Sorry for the late reply, but I've been busy working etc. But I've finally managed to find some time. And this is perfect. Thanks again.

Thanks .Paul.

+Rep to both.

EDIT: Sorry the system won't allow me to rep either of you. Such a shame, as your work deserves some kind of reward. I will owe you one. Many thanks to both.