Convert DataGridViewCell to Bitmap

[dday9]

I'm trying to get the bitmap of a DataGridViewCell. The best way to describe it is the DrawToBitmap method on most controls. Is there a built in method for this and if not has somebody already created a similar method?

[.paul.]

I'd probably calculate the size and (screen) coordinates and use Graphics.CopyFromScreen

[TnTinMN]

Give this a try:

Public Function GetDGVCellBitMap(ByVal dgv As DataGridView, ByVal row As Int32, ByVal col As Int32) As Bitmap
   Return GetDGVCellBitMap(dgv.Item(col, row))
End Function
 
Public Function GetDGVCellBitMap(ByVal cell As DataGridViewCell) As Bitmap
   Dim dgv As DataGridView = cell.DataGridView
   Dim firstDisplayedCell As DataGridViewCell = dgv.FirstDisplayedCell
   dgv.FirstDisplayedCell = cell
   Dim cellWasSelected As Boolean = cell.Selected
   cell.Selected = False
 
'     get DataGridView method: GetCellAdjustedDisplayRectangle
'     Friend Function GetCellAdjustedDisplayRectangle(ByVal columnIndex As Integer, ByVal rowIndex As Integer, ByVal cutOverflow As Boolean) As Rectangle
 
   Dim miGetCellAdjustedDisplayRectangle As Reflection.MethodInfo = GetType(DataGridView).GetMethod("GetCellAdjustedDisplayRectangle", Reflection.BindingFlags.Instance Or Reflection.BindingFlags.NonPublic)
 
   Dim cellBounds As Rectangle = CType(miGetCellAdjustedDisplayRectangle.Invoke(dgv, New Object() {cell.ColumnIndex, cell.RowIndex, False}), Rectangle)
   cellBounds.Location = New Point(cellBounds.X, 0) ' Point.Empty
 
 
'     get DataGridViewRow method: PaintCells
'     Protected Friend Overridable Sub PaintCells(ByVal graphics As Graphics, 
                                              'ByVal clipBounds As Rectangle, 
                                              'ByVal rowBounds As Rectangle, 
                                              'ByVal rowIndex As Integer, 
                                              'ByVal rowState As DataGridViewElementStates, 
                                              'ByVal isFirstDisplayedRow As Boolean, 
                                              'ByVal isLastVisibleRow As Boolean, 
                                              'ByVal paintParts As DataGridViewPaintParts)
 
   Dim rowBounds As Rectangle = dgv.GetRowDisplayRectangle(cell.RowIndex, False)
 
   'offset rowbounds x by cellbounds x
   rowBounds.Location = New Point(rowBounds.Location.X - cellBounds.Location.X, 0)
   Dim ret As New Bitmap(cellBounds.Width, cellBounds.Height)
 
   Dim miPaintCells As Reflection.MethodInfo = GetType(DataGridViewRow).GetMethod("PaintCells", Reflection.BindingFlags.Instance Or Reflection.BindingFlags.NonPublic)
   Using g As Graphics = Graphics.FromImage(ret)
      g.SmoothingMode = Drawing2D.SmoothingMode.AntiAlias
      g.TextRenderingHint = Drawing.Text.TextRenderingHint.AntiAlias
      Dim row As DataGridViewRow = dgv.Rows(cell.RowIndex)
      miPaintCells.Invoke(row, New Object() {g, _
                                             rowBounds, _
                                             rowBounds, _
                                             cell.RowIndex, _
                                             row.State, _
                                             False, _
                                             False, _
                                             DataGridViewPaintParts.All})
   End Using
 
   cell.Selected = cellWasSelected
   dgv.FirstDisplayedCell = firstDisplayedCell
   Return ret
End Function