Results 1 to 36 of 36

Thread: VB6-Extract Data from csv files in 3 different folder and update into 1 final folder.

  1. #1

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Question VB6-Extract Data from csv files in 3 different folder and update into 1 final folder.

    Hi Gurus,

    Need your help for this issue. I have 3 different folders with .csv files based on date (eg:LT_15102014.csv, CW_15102014.csv, RMP_15102014.csv) for each folder .
    I need to extract data based on the serial no (eg:0XV0SYU6) and copy to another folder with file name finaldata_15102014.csv.

    i have attached the pics how it looks like. any idea how to start off ? thanks a lot.
    Attached Images Attached Images   
    Last edited by crazydude80; Oct 15th, 2014 at 04:40 AM.

  2. #2
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Yes, read each .csv file by looping through each line and using instr() or split() functions, extract what you want, and then write it out to your new file. Easy.

    EDIT: I'm assuming the serial number can be found within the three .csv files.....

  3. #3

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hi Sam, i understand the concept but unsure about the code.
    reading from all folder then extract it and write. i did search for codes but not exactly what i want. thanks

  4. #4
    VB-aholic & Lovin' It LaVolpe's Avatar
    Join Date
    Oct 2007
    Location
    Beside Waldo
    Posts
    19,541

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    If you want to join all three in a single query of some sort, copy all 3 into the same folder. With CSVs, the folder acts as the database and the files act as the database tables. Otherwise, as Sam has suggested: Open each csv, extract what is needed & write/append to the new csv
    Insomnia is just a byproduct of, "It can't be done"

    Classics Enthusiast? Here's my 1969 Mustang Mach I Fastback. Her sister '67 Coupe has been adopted

    Newbie? Novice? Bored? Spend a few minutes browsing the FAQ section of the forum.
    Read the HitchHiker's Guide to Getting Help on the Forums.
    Here is the list of TAGs you can use to format your posts
    Here are VB6 Help Files online


    {Alpha Image Control} {Memory Leak FAQ} {Unicode Open/Save Dialog} {Resource Image Viewer/Extractor}
    {VB and DPI Tutorial} {Manifest Creator} {UserControl Button Template} {stdPicture Render Usage}

  5. #5
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Here is an example as I described briefly.
    (Has three four commandbuttons, 1 textbox (holding the search string), and one listbox.)
    (I did not use the commondialog, but instead, hardcoded directory paths---you should not do that)
    Code:
    Option Explicit
    Private Sub Command1_Click(Index As Integer)
        Dim intFile As Integer
        Dim myLine As String
        Dim stringFound As String
        intFile = FreeFile
        Dim x As Integer, y As Integer, z As Integer
        Select Case Index
            Case 0
                Open App.Path & "\dir1\csvOne.csv" For Input As intFile
            Case 1
                Open App.Path & "\dir2\csvTwo.csv" For Input As intFile
            Case 2
                Open App.Path & "\dir3\csvThree.csv" For Input As intFile
        End Select
            Do While Not EOF(1)
                Line Input #1, myLine      ' Read line of data.
                x = InStr(myLine, txtSNSearch.Text)
                If x > 0 Then
                    stringFound = Mid(myLine, x + 1)
                    y = InStr(1, stringFound, ")")
                    If y > 0 Then
                        stringFound = Mid(stringFound, 1, y)
                        List1.AddItem (stringFound)
                    End If
                End If
            Loop
    Close intFile
    End Sub
    Private Sub Command2_Click()
        Dim myText As String
        Dim x As Integer
        For x = 0 To List1.ListCount - 1
            List1.ListIndex = x
            myText = myText & "," & List1.Text
        Next x
        myText = Mid(myText, 2)
        Open App.Path & "\Dir4\csvFOUR.csv" For Output As #1
        Print #1, myText
        Close #1
        MsgBox "Done!"
    End Sub

  6. #6

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hi Sam, thanks for ur help. when i run in step mode F8, it stopped at hilited line (bad file name or numbers:runtime error "52"). anything that i missed out ?

    Code:
    Private Sub Command1_Click(Index As Integer)
        Dim intFile As Integer
        Dim myLine As String
        Dim stringFound As String
        intFile = FreeFile
        Dim x As Integer, y As Integer, z As Integer
        Select Case Index
            Case 0
                Open App.Path & "\DamperBoat\DMP_15102014.csv" For Input As intFile
            Case 1
                Open App.Path & "\CWBoat\CW_15102014.csv" For Input As intFile
            Case 2
                Open App.Path & "\RampBoat\RMP_15102014.csv" For Input As intFile
        End Select
        
        
            Do While Not EOF(1)
                Line Input #1, myLine      ' Read line of data.
                x = InStr(myLine, txtSNSearch.Text)
                If x > 0 Then
                    stringFound = Mid(myLine, x + 1)
                    y = InStr(1, stringFound, ")")
                    If y > 0 Then
                        stringFound = Mid(stringFound, 1, y)
                        List1.AddItem (stringFound)
                    End If
                End If
            Loop
    Close intFile

  7. #7
    VB-aholic & Lovin' It LaVolpe's Avatar
    Join Date
    Oct 2007
    Location
    Beside Waldo
    Posts
    19,541

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Don't hard code the file handle to the number 1. In your code, the file handle is intFile, not 1
    Insomnia is just a byproduct of, "It can't be done"

    Classics Enthusiast? Here's my 1969 Mustang Mach I Fastback. Her sister '67 Coupe has been adopted

    Newbie? Novice? Bored? Spend a few minutes browsing the FAQ section of the forum.
    Read the HitchHiker's Guide to Getting Help on the Forums.
    Here is the list of TAGs you can use to format your posts
    Here are VB6 Help Files online


    {Alpha Image Control} {Memory Leak FAQ} {Unicode Open/Save Dialog} {Resource Image Viewer/Extractor}
    {VB and DPI Tutorial} {Manifest Creator} {UserControl Button Template} {stdPicture Render Usage}

  8. #8
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by LaVolpe View Post
    Don't hard code the file handle to the number 1. In your code, the file handle is intFile, not 1
    Yeah....I know....got sloppy.

  9. #9

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by SamOscarBrown View Post
    Yeah....I know....got sloppy.

    So I just need to replace the 1 with intFile ?

    Sorry guys, I'm still studying. Once familiar will try not to hard code. Thanks

  10. #10

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by crazydude80 View Post
    So I just need to replace the 1 with intFile ?

    Sorry guys, I'm still studying. Once familiar will try not to hard code. Thanks
    Name:  query3.jpg
Views: 745
Size:  40.4 KB

    any idea y im getting 1 as return in the intFile ? thanks

  11. #11
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    That's because you have asked Freefile to give you a safe file handle number. That's what Freefile does, it inspects the system for a valid file handle (not in use) and returns an appropriate number. Normally, allocation is simple, Freefile will return 1 for the first file you open,2 for the second, etc, etc....

    The reason for using this is because you never know.... Suppose you have a routine in a timer in another module that decides to open 3 files and keep them open for a while. While this is happening, another piece of your code written as :

    Open filename for binary as 1

    will fail but

    filenum=Freefile
    Open filename for binary as filenum

    will work. Filenum will likely be 4 if you already have 3 other files opened, but you just don't care anyway. Freefile gave you a valid handle, you use it and then you are done.

  12. #12
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Disregard this post.....didn't read your issue correctly......
    Last edited by SamOscarBrown; Oct 16th, 2014 at 06:37 AM.

  13. #13

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by SamOscarBrown View Post
    PROBABLY, the "#1" was not your issue (I doubt you have other files open---but the Navion explanation is very good). What I think is that your paths to your directories are probably not correct. Are those three directories located under the directory in which you are running your project (known as app.Path), or are they under C:/.....somewhere?
    For YOU, you can HARD-CODE the whole path to the file(s) or better (once you understand), use variables to point to those directories.

    For example, instead of using app.Path (IF those dirs are not under the path of your project), you could hard code something like this:
    Code:
    Open "C:/users/crazydude80/DamperBoat/DMP_15102014.csv" For Input As intFile
    or

    Code:
    dim Dir1Path as String
    Dir1Path = "C:/users/crazydude80/DamperBoat/"
    open Dir1Path & "DMP_15102014.csv" For Input As intFile
    you guys are great. will try later and update again. thanks a lot

  14. #14
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    This is what it should look like:

    Code:
    Option Explicit
    Private Sub Command1_Click(Index As Integer)
        Dim intFile As Integer
        Dim myLine As String
        Dim stringFound As String
        intFile = FreeFile
        Dim x As Integer, y As Integer, z As Integer
        Select Case Index
            Case 0
                Open App.Path & "\dir1\csvOne.csv" For Input As intFile
            Case 1
                Open App.Path & "\dir2\csvTwo.csv" For Input As intFile
            Case 2
                Open App.Path & "\dir3\csvThree.csv" For Input As intFile
        End Select
        Do While Not EOF(intFile)
            Line Input #intFile, myLine      ' Read line of data.
            x = InStr(myLine, txtSNSearch.Text)
            If x > 0 Then
                stringFound = Mid(myLine, x + 1)
                y = InStr(1, stringFound, ")")
                If y > 0 Then
                    stringFound = Mid(stringFound, 1, y)
                    List1.AddItem (stringFound)
                End If
            End If
        Loop
    Close intFile
    End Sub
    Private Sub Command2_Click()
        Dim myText As String
        Dim x As Integer
        For x = 0 To List1.ListCount - 1
            List1.ListIndex = x
            myText = myText & "," & List1.Text
        Next x
        myText = Mid(myText, 2)
        Open App.Path & "\Dir4\csvFOUR.csv" For Output As #1
        Print #1, myText
        Close #1
        MsgBox "Done!"
    End Sub
    If you are still getting the error, then the issue probably lies in where your .csv files are located.
    Do you understand 'app.Path'?
    What are the full pathnames to where each of those .csv files are located?
    Without the proper path name, you will get the file not found error.
    YOu can either hard-code the paths, or use a variable for the directory structure leading to the paths.
    OR, better even yet, use a commondialog to open each of the files and use the commondialogs' properties to capture the whole path.

  15. #15

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hi, i tried with both Navion & sam method but still giving me the same error
    the path are correct. verified many times.


    Name:  query4.jpg
Views: 613
Size:  52.1 KB

  16. #16
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Do this:
    Click on the first button (Index of 0) and just before your line that throws the exception, put in:

    Code:
    Console.Write App.Path & "\Dir1\CSV1.csv"
    and see what the result is.,,,is your file with the name "CSV1.csv", included in the full/correct path?

    You know, this (my example) has HARDCODED paths under the path in which the application is being run, with names of DIR1, DIR2, and DIR3. Is that what YOU have? I kinda doubt it.

    Why don't you put a commonDialog on your form and open (browse to) the file(s) you want, using the commondialog to return the full pathname.

    Sam

  17. #17
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Here is what I mean: Using a commondialog on ONE button (Command1) to browse and find you file:
    Code:
    Option Explicit
    
    Private Sub Command1_Click()
        Dim intFile As Integer
        Dim myLine As String
        Dim stringFound As String
        intFile = FreeFile
        Dim x As Integer, y As Integer, z As Integer
        CommonDialog1.ShowOpen
        Dim myFile As String
        myFile = CommonDialog1.FileName
        Open myFile For Input As intFile
        Do While Not EOF(intFile)
            Line Input #intFile, myLine      ' Read line of data.
            x = InStr(myLine, txtSNSearch.Text)
            If x > 0 Then
                stringFound = Mid(myLine, x + 1)
                y = InStr(1, stringFound, ")")
                If y > 0 Then
                    stringFound = Mid(stringFound, 1, y)
                    List1.AddItem (stringFound)
                End If
            End If
        Loop
    Close intFile
    End Sub
    As

  18. #18
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    So where do you stand now? What is the current error you are encountering ?

    If you are not going where you want to go, i'll write you a little piece of code that will do the trick (from csv files).

  19. #19
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by Navion View Post
    If you are not going where you want to go, i'll write you a little piece of code that will do the trick (from csv files).
    ...and mine doesn't??????? :-)

  20. #20
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by SamOscarBrown View Post
    ...and mine doesn't??????? :-)
    Well I don't know... the OP still has problems it seems. At any rate , what I had in mind is much different from yours and not intended in a competitive fashion. Just here to help.

  21. #21
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    That's why the ":-)"......no absolutely, the more suggestions, the better chances for someone to learn.

  22. #22
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by SamOscarBrown View Post
    the more suggestions, the better chances for someone to learn.
    I agree. In computing, there is not one single way to do things, or a better one for that matter. At times, I am amazed by the varied coding styles posted to help resolve a case. ;

  23. #23

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    sorry for the late reply. was on long holiday. just back to office today.
    i dont see any error if i test by choosing 1 file only (as what Sam suggested using the commondialog to locate the file )
    the moment i switch back to all 3 then the problem comes again. im confused

  24. #24
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    I would like to help you with this, part of the reason is that I see you working real hard to get things working.

    But I don't exactly understand why you are formatting things the way you are.

    What I see is a very simple Parts look up system. The specifications are :

    - You have a WidgetA that has a model number say : 123456
    - For this widget, you want to find a part number for three different parts : TW, Ltorque and Ramp
    - The parts are contained in three different files, located in three different folders and also identified with a date stamp.

    Why three files?, Why three folders? Why the date stamp?

    Your system, if I understand it correctly could avoid all that....

    Also, a CSV file contains columns that are separated by commas. Although you work them in a spreadsheet, it is a database really. Since each element has its own column, you can parse the columns and go by index number. Instead, you read each line and you extract the information with Instr and mid. Although IT COULD work, this method is not very efficient and could lead to errors. Finally, you put the results into one single cell in the end. I don't think that is the best here.

    Now I hesitate between writing something entirely different.. or work out from your code.... but at the last minute, I decided to give you a piece of code based mostly on your last post, but working with comma delimited CSV files.

    The code contains enough checking and one error trap so that it should not stop and return the correct results if your CSV files are formatted properly. It also serves as an example you should study and understand all the elements. For example, it contains the array function that works on variants but whose each element can be used as a string.

    From there, it should not be too hard to rework to your own liking or needs.

    Code:
    lookfor$ = Trim(txtSNSearch.Text)
    
    subpath = Array("dir1", "dir2", "dir3")
    basename = Array("csv1", "csv2", "csv3")
    partname = Array("CW", "Ltorque", "Ramp")
    
    result$ = lookfor$   ' we start by including the model number in the result
    
    ' then we loop into each file to gather the part number
    For i = 0 To 2
        FileName$ = App.Path & "\" & subpath(i) & "\" & basename(i) & ".csv"
        ' here we build a simple error trap to make sure the file exists
        le = 0                      'we must do this because in the loop, previous le was probably not 0
        On Error Resume Next
        le = FileLen(FileName$)     'get the  number of bytes in the file
        On Error GoTo 0
        ' if the file was not found, le will be 0
        ' if the file was found and it contains some bytes, we can proceed
        If le > 0 Then
            ' read the whole file at ounce
            filenum = FreeFile
            Open FileName$ For Binary As filenum
            allfile$ = Input$(le, filenum)
            Close filenum
            ' process the content of the file one line at a time
            allLines = Split(allfile$, vbCrLf)
            For j = 0 To UBound(allLines)
                oneline$ = allLines(j)
                ' eliminate empty lines
                If Len(oneline$) Then
                    ' if you have a properly formatted csv file
                    ' each line here has at least two cells separated by a comma
                    ' the first cell is the model
                    ' the second is the partnumber
                    cells = Split(oneline$, ",")
                    If Trim(cells(0)) = lookfor$ Then
                        If UBound(cells) > 0 Then
                            ' this is the cell containing the part number
                            ' cocatenate with result$
                            result$ = result$ & "  " & partname(i) & " : " & cells(1)
                            ' since we found what we are looking for
                            ' exit the loop
                            Exit For
                        End If
                    End If
                End If
            Next
        End If
    Next
    
    MsgBox result$
    
    Rem write the rest of the code to save in a file
    Last edited by Navion; Oct 24th, 2014 at 09:22 AM. Reason: fixed one typo

  25. #25
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Well, I don't know about all that (I am sure it probably works just fine), but for the OP, here is my example (A lot of things could be done to it for errorchecking, overwriting, and other stuff), but the basics of what I was talking about...using a button to load each file, and another to save the new file...is pretty self-explanatory in this example.)

    Attachment 119951
    Last edited by SamOscarBrown; Oct 24th, 2014 at 07:36 AM.

  26. #26
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Oooppps, I made a little mistake, I did run the code but the CSV parsing did not take place since I had no files.

    The first line in the For j loop should use the j variable instead or i

    I edited direct in the post so there are no errors anymore....

    Two more comments...

    1- you can change the members in the array statements to reflect your exact situation
    2- Again, the code was written to work well with common CSV files. If not, it may not work, but it should not be hard to fix either.

  27. #27
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Also, looking back at the pictures on the very top of this program, it appears that there could be more than one CW past for a given model number. The problem is easily remedied by removing the Exit For in the loop.

    This just emphasizes the hard ship to work on a project whose all elements are not entirely known (or clear). Bottom line here is that bits posted are meant to help understanding about programming when they fall short of their actual goal.

  28. #28

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hi guys, thanks for all the helps. was working on the main VB program to collect the data from 3 stations which i just completed.
    this is how my data look like.
    Name:  test1.jpg
Views: 616
Size:  50.0 KB

    those code that you all provide will goes to the last station that im working now to extract the serial no from the other 2 station and save into final folder.

    will try out again and update you guys again. once again thanks a lot for ur help. much appreciated.
    Last edited by crazydude80; Oct 31st, 2014 at 03:01 AM.

  29. #29

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hI Navion,


    Why three files?, Why three folders? Why the date stamp? --> i have 3 stations that need to collect data. that's why i have 3 files,3 folders & the date stamp will be based on daily log. hope my above pic will clear your quest.

  30. #30

    Thread Starter
    Member
    Join Date
    May 2012
    Posts
    51

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    hi sam & Navion,

    Almost 90% of my projects completed. Would like to thanks both of for your help and support. Really appreciated. Thanks again guys.

  31. #31
    PowerPoster SamOscarBrown's Avatar
    Join Date
    Aug 2012
    Location
    NC, USA
    Posts
    9,143

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    You're welcome....glad to assist.
    One way you can 'thank' folks who help you on this forum is to click on the star on their post (Rate This Post).

  32. #32
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Well I am glad things are working out well for you

  33. #33
    PowerPoster Elroy's Avatar
    Join Date
    Jun 2014
    Location
    Near Nashville TN
    Posts
    9,853

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Wow, well you guys seem to have just gotten this one entirely sorted. When looking at OP's original post, my first thought was Excel Automation, but that may be because that's what his screen shots are. I even had flashes of pulling it all into a database so I could possibly use SQL or a table's index. It sounds like you all got it sorted though.
    Any software I post in these forums written by me is provided "AS IS" without warranty of any kind, expressed or implied, and permission is hereby granted, free of charge and without restriction, to any person obtaining a copy. To all, peace and happiness.

  34. #34
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    All credit to the OP, really. He is the one working hard to code his system.

    One thing though. I think it is more useful to bring out solutions within the realm of the user's experience. Excel automation could have raised more questions than provided answers.

    That's the nice thing about VB6 : RAD. There is always a simple way to build a nice little working system from scratch.

  35. #35
    PowerPoster Elroy's Avatar
    Join Date
    Jun 2014
    Location
    Near Nashville TN
    Posts
    9,853

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Oh gosh, absolutely Navion, especially about the RAD. And truth be told, after reading through the thread, I didn't totally get my head around the problem. From skimming and squinting at his screen shots, I assumed that his CSV files had lots of data in them, but he wanted to build a common file that had all the records/info about some specific search key. Yep, a fairly straightforward project, and many different ways to get it done.

    Take Care.
    Any software I post in these forums written by me is provided "AS IS" without warranty of any kind, expressed or implied, and permission is hereby granted, free of charge and without restriction, to any person obtaining a copy. To all, peace and happiness.

  36. #36
    Fanatic Member
    Join Date
    Jan 2006
    Posts
    557

    Re: VB6-Extract Data from csv files in 3 different folder and update into 1 final fol

    Quote Originally Posted by Elroy View Post
    From skimming and squinting at his screen shots, I assumed that his CSV files had lots of data in them, but he wanted to build a common file that had all the records/info about some specific search key
    That's what I thought too, but apparently, he had other specifications than what I could only see. So my solution was more about a bit of code he could learn something about, and leave him the task of putting the glue where needed apply. And that he did.

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  



Click Here to Expand Forum to Full Width