[RESOLVED] Get all parents from a selected node

[alazarou]

I got a treeview with several levels (about 1500 nodes). How can i get in a listbox all the parent nodes of the selected node?

[ColinE66]

A node only has one parent. Please clarify your question.

[alazarou]

Yes I know, but the nodes parent got a parent ... let me be more clear....
for example...

root
.....Parent A
................SubParent 1
................................node 1
................................node 2
................SubParent 2
................................node 3
.....Parent B
................node 4

if the selected is the "node 3" in the list should in the Subparent 2,Parent A,Root
if the selected is the "node 4" in the list should in the Parent B,Root

[ColinE66]

OK, much clearer. You want all ancestors of a particular node.

Option Explicit

Private Sub Form_Load()
Dim i As Long, j As Long
   For i = 1 To 50
      TreeView1.Nodes.Add , tvwChild, "Node" & i, "Node " & i
   Next i

   On Error Resume Next
   
   Randomize
   For i = 1 To 50
      
      j = Int((50 * Rnd) + 1)
      Set TreeView1.Nodes(i).Parent = TreeView1.Nodes(j)
   Next i

End Sub


Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)

   List1.Clear
   List1.AddItem Node.Text
   Do
      If Not Node.Parent Is Nothing Then
         Set Node = Node.Parent
         List1.AddItem Node.Text
      Else
         Exit Do
      End If
   Loop Until False

End Sub

[MarkT]

I would write the loop differently but yes you would have to loop until there is not a parent node found.

Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
    
    List1.Clear
    List1.AddItem Node.Text
    
    Do While Not Node.Parent Is Nothing
        Set Node = Node.Parent
        List1.AddItem Node.Text
    Loop
End Sub

[ColinE66]

Yup. Although I never use While, personally. Probably would have done it as below if I'd thought about it rather than bashing it out in a few seconds (slightly more readable IMO)...

   List1.Clear
   List1.AddItem Node.Text
   Do Until Node.Parent Is Nothing
      Set Node = Node.Parent
      List1.AddItem Node.Text
   Loop

[alazarou]

works fine thanks !!!

[Schmidt]

Just in case you are not really interested in the Ancestors String-Representations in a List(Box),
but want to use them for "Path-Like" purposes, there's the 'FullPath' property on any Node,
which might be helpful too.

Below is a small example, which is somewhat "misusing" Node.FullPath, to accomplish
what you wanted - here only serving as a reminder, that the Texts of the ancestor-
nodes are already available in a "nicely arranged way" in the Node itself (ready to be
directly used in simple String-Ops).

Option Explicit

Private Sub Form_Load()
  With TreeView1.Nodes
    .Add , , "A", "A"
      .Add "A", tvwChild, "Aa", "Aa"
        .Add "Aa", tvwChild, "Aaa", "Aaa"
  End With

  AddAncestorsFromNode TreeView1.Nodes("Aaa")
End Sub

Private Sub AddAncestorsFromNode(ByVal Node)
  List1.Clear
  For Each Node In Split(Node.FullPath, "\")
    List1.Additem Node 'alternatively List1.AddItem Node, 0 for reverse ordering
  Next
End Sub

Olaf