XNA to DirectX [RPG] Sprite problem

**SwordEdge** · Mar 13th, 2014, 11:19 AM

Hello poeple!

I dropped XNA for directx3d,directx,directx3dx (directx.....)

So i converted most of my xna code to directx by using this tutorial and this tutorial

Pastebin:
My code dx3dengine

My code DXsprite

My code GameEngine

My OLD XNA CODE

I didnt change anything else but loading the sprites to the "GameForm"
Tinypic(screenshots)
now it looks like (DirectX)
and it should look like (XNA)

Does someone knows whats wrong? by looking at my code, Btw i copied the BitmapToTexture Sub from XNA

MANY MANY THANKS! if you can help me out!

Omg i need this LMAO ice cream!

**SwordEdge** · Mar 13th, 2014, 07:32 PM

Got this to work! but how do i use it in another thread? cus when i run the rendering in another thread it doesnt draw at all

something to do with invoke?

**Jacob Roman** · Mar 13th, 2014, 10:24 PM

Hey SwordEdge, I betcha miss me from the last thread

Next time please post in the Games and Graphics section though. All the game related issues go in that section. Only standard VB questions go in the VB.Net section.

And I know you might be new to DX programming, but if those tutorials didn't tell you, be sure your .NET Framework is set for 3.5, and the CPU target is x86. VB.Net uses DirectX9 sadly since DX10 and DX11 is targeted towards C++. And since DX9 is an older but still widely used DX, it must be set to those settings in your project for it to work.

I don't know why you are multithreading but its not needed at all unless you are making a triple A title and rendering millions of polygons in a 3D world. So you don't need to multithread for simple 2D RPG's. Matter of fact, I have an algorithm to make the worlds as large as you want with zero slowdown. No multithreading used.

Another thing is that you are making the initialization unnecessarily complex, and it doesn't need to be wrapped in a class at all because it already is a class. Why wrap a class within a class? When you dispose of it for example, you end up disposing the class that ends up disposing the device. See what I mean, it ends up becoming a hierarchy of disposals. And thankfully you got a DirectX guru here to help get you a proper DX initialization.

Also you don't need to call it 3D if your RPG is going to be 2D. Yes you are using Direct3D for 2D, but since its being initialized for 2D, you can call it DX2DEngine. Otherwise if you were to refer back to your project months or years down the road you would be asking yourself "Did I make it 2D or 3D?" Or even worse...if someone looked at your code and wasn't too sure how you initialized it, whether its 2D or 3D. Anyways, initialization is as simple as this:

vb.net Code:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
 
Public Class frmMain
 
    Private Device As Device
    Private Display_Mode As DisplayMode
    Private Screen As PresentParameters = New PresentParameters
 
    Private Fullscreen_Enabled As Boolean
    Private Running As Boolean
 
    Private Sub DirectX_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 1920
            Display_Mode.Height = 1080
            Display_Mode.Format = Format.A8B8G8R8
            Screen.Windowed = False
            Screen.BackBufferCount = 1
            Screen.BackBufferWidth = Display_Mode.Width
            Screen.BackBufferHeight = Display_Mode.Height
        Else
            Screen.Windowed = True
        End If
 
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
        Device = New Device(0, DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target, Color.FromArgb(0, 0, 0), 1.0, 0)
        Device.BeginScene()
        'Rendering code goes here
        Device.EndScene()
        Device.Present()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Render()
            Application.DoEvents()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to fullscreen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        With Me
            .Show()
            .Width = 330
            .Height = 250
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True)
            .Text = "DirectX Tutorial"
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        DirectX_Initialize()
        Running = True
 
    End Sub
 
    Private Sub Shutdown()
 
        Running = False
        Device.Dispose()
        Application.Exit()
 
    End Sub
 
    Private Sub frmMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles MyBase.KeyDown
 
        If e.KeyCode = Keys.Escape Then Shutdown()
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
 
        If Fullscreen_Enabled = False Then
            Running = False
            Device.Reset(Screen)
            Application.DoEvents()
            Running = True
        End If
 
    End Sub
 
End Class

This allows you to enter either fullscreen or windowed mode. With this, a simple way to draw a polygon would be to do this:

vb.net Code:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
 
Public Class frmMain
 
    Private Device As Device
    Private Display_Mode As DisplayMode
    Private Screen As PresentParameters = New PresentParameters
 
    Private Fullscreen_Enabled As Boolean
    Private Running As Boolean = True
 
    Private Vertex_List As CustomVertex.TransformedColored() = New CustomVertex.TransformedColored(3) {}
 
    Private Sub DirectX_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 1920
            Display_Mode.Height = 1080
            Display_Mode.Format = Format.A8B8G8R8
            Screen.Windowed = False
            Screen.BackBufferCount = 1
            Screen.BackBufferWidth = Display_Mode.Width
            Screen.BackBufferHeight = Display_Mode.Height
        Else
            Screen.Windowed = True
        End If
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
        Device = New Device(0, DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
    End Sub
 
    Private Function Create_Custom_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single, ByVal RHW As Single, ByVal Color As Integer) As CustomVertex.TransformedColored
 
        Dim Vertex As CustomVertex.TransformedColored = New CustomVertex.TransformedColored
 
        Vertex.Position = New Vector4(X, Y, Z, 1)
        Vertex.Rhw = RHW
        Vertex.Color = Color
 
        Return Vertex
 
    End Function
 
    Private Sub Create_Polygon()
 
        Vertex_List(0) = Create_Custom_Vertex(0, 0, 0, 1, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(1) = Create_Custom_Vertex(100, 0, 0, 1, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(2) = Create_Custom_Vertex(0, 100, 0, 1, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(3) = Create_Custom_Vertex(100, 100, 0, 1, Color.FromArgb(255, 255, 255).ToArgb)
 
    End Sub
 
    Private Sub Draw_Polygon()
 
        Device.VertexFormat = CustomVertex.TransformedColored.Format
        Device.DrawUserPrimitives(PrimitiveType.TriangleStrip, 2, Vertex_List)
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target, Color.FromArgb(0, 0, 0), 1.0#, 0)
        Device.BeginScene()
        'Rendering code goes here
        Create_Polygon()
        Draw_Polygon()
        Device.EndScene()
        Device.Present()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Render()
            Application.DoEvents()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to fullscreen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        With Me
            .Show()
            .Width = 330
            .Height = 250
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True)
            .Text = "DirectX Tutorial"
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        DirectX_Initialize()
        Running = True
 
    End Sub
 
    Private Sub Shutdown()
 
        Running = False
        Device = Nothing
        Application.Exit()
 
    End Sub
 
    Private Sub frmMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles MyBase.KeyDown
 
        If e.KeyCode = Keys.Escape Then Shutdown()
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
 
        If Fullscreen_Enabled = False Then
            Running = False
            Device.Reset(Screen)
            Application.DoEvents()
            Running = True
        End If
 
    End Sub
 
End Class

Continued next post.....

**Jacob Roman** · Mar 13th, 2014, 10:25 PM

Continued from last post:

To texturemap the polygon with an image loaded from file you would do this:

vb.net Code:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
 
Public Class frmMain
 
    Private Device As Device
    Private Display_Mode As DisplayMode
    Private Screen As PresentParameters = New PresentParameters
 
    Private Fullscreen_Enabled As Boolean
    Private Running As Boolean = True
 
    Private Vertex_List As CustomVertex.TransformedColoredTextured() = New CustomVertex.TransformedColoredTextured(0 To 3) {}
    Private Texture As Texture
 
    Private Sub DirectX_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 1920
            Display_Mode.Height = 1080
            Display_Mode.Format = Format.A8B8G8R8
            Screen.Windowed = False
            Screen.BackBufferCount = 1
            Screen.BackBufferWidth = Display_Mode.Width
            Screen.BackBufferHeight = Display_Mode.Height
        Else
            Screen.Windowed = True
        End If
 
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
 
        Device = New Device(0, DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
    End Sub
 
    Private Function Create_Custom_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single, ByVal Color As Integer, ByVal TU As Integer, ByVal TV As Integer) As CustomVertex.TransformedColoredTextured
 
        Dim Vertex As CustomVertex.TransformedColoredTextured = New CustomVertex.TransformedColoredTextured
 
        Vertex.Position = New Vector4(X, Y, Z, 1)
        Vertex.Color = Color
        Vertex.Tu = TU
        Vertex.Tv = TV
 
        Return Vertex
 
    End Function
 
    Private Sub Create_Polygon()
 
        Vertex_List(0) = Create_Custom_Vertex(0, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 0)
        Vertex_List(1) = Create_Custom_Vertex(100, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 0)
        Vertex_List(2) = Create_Custom_Vertex(0, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 1)
        Vertex_List(3) = Create_Custom_Vertex(100, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 1)
 
    End Sub
 
    Private Sub Draw_Polygon()
 
        Device.VertexFormat = CustomVertex.TransformedColoredTextured.Format
        Device.SetTexture(0, Texture)
        Device.DrawUserPrimitives(PrimitiveType.TriangleStrip, 2, Vertex_List)
 
    End Sub
 
    Private Sub Load_Texture(ByRef Texture As Texture, ByVal Filepath As String, ByVal Transparency_Color As Integer)
 
        Texture = TextureLoader.FromFile(Device, Filepath, 512, 512, 1, Usage.None, Format.A8B8G8R8, Pool.Managed, Filter.Point, Filter.Point, Transparency_Color)
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target, Color.Black, 1.0, 0)
        Device.BeginScene()
        'Rendering code goes here.
        Create_Polygon()
        Draw_Polygon()
        Device.EndScene()
        Device.Present()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Render()
            Application.DoEvents()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to full screen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Information) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        With Me
            .Show()
            .Width = 330
            .Height = 250
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True)
            .Text = "DirectX Tutorial"
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        DirectX_Initialize()
        Load_Texture(Texture, Application.StartupPath() & "\texture.jpg", System.Drawing.Color.FromArgb(0, 0, 0, 0).ToArgb)
        Running = True
 
    End Sub
 
    Private Sub Shutdown()
 
        Running = False
        Texture.Dispose()
        Texture = Nothing
        Device = Nothing
        Application.Exit()
 
    End Sub
 
 
    Private Sub frmMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles MyBase.KeyDown
 
        If e.KeyCode = Keys.Escape Then Shutdown()
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
 
        If Fullscreen_Enabled = False Then
            Running = False
            Device.Reset(Screen)
            Application.DoEvents()
            Running = True
        End If
 
    End Sub
End Class

To make the texturemapped polygon transparent so the backcolor is removed, and the alpha values can be controlled to fade in/out the sprites:

vb.net Code:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
 
Public Class frmMain
 
    Private Device As Device
    Private Display_Mode As DisplayMode
    Private Screen As PresentParameters = New PresentParameters
 
    Private Fullscreen_Enabled As Boolean
    Private Running As Boolean = True
 
    Private Vertex_List As CustomVertex.TransformedColoredTextured() = New CustomVertex.TransformedColoredTextured(0 To 3) {} 'create an array of vertices
    Private Texture As Texture
 
    Private Function Create_Custom_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single, ByVal Color As Integer, ByVal TU As Integer, ByVal TV As Integer) As CustomVertex.TransformedColoredTextured
 
        Dim Vertex As CustomVertex.TransformedColoredTextured
 
        Vertex.Position = New Vector4(X, Y, Z, 1)
        Vertex.Color = Color
        Vertex.Tu = TU
        Vertex.Tv = TV
 
        Return Vertex
 
    End Function
 
    Private Sub DirectX_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 1920
            Display_Mode.Height = 1080
            Display_Mode.Format = Format.A8B8G8R8
            Screen.Windowed = False
            Screen.BackBufferCount = 1
            Screen.BackBufferWidth = Display_Mode.Width
            Screen.BackBufferHeight = Display_Mode.Height
        Else
            Screen.Windowed = True
        End If
 
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
 
        Device = New Device(0, DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
        Device.SetRenderState(RenderStates.AlphaBlendEnable, True)
 
        Device.SetTextureStageState(0, TextureStageStates.ColorOperation, TextureOperation.Modulate)
        Device.SetTextureStageState(0, TextureStageStates.ColorArgument1, TextureArgument.TextureColor)
        Device.SetTextureStageState(0, TextureStageStates.ColorArgument2, TextureArgument.Diffuse)
 
        Device.SetTextureStageState(0, TextureStageStates.AlphaOperation, TextureOperation.Modulate)
        Device.SetTextureStageState(0, TextureStageStates.AlphaArgument1, TextureArgument.TextureColor)
        Device.SetTextureStageState(0, TextureStageStates.AlphaArgument2, TextureArgument.Diffuse)
 
        Device.SetRenderState(RenderStates.SourceBlend, Blend.SourceAlpha)
        Device.SetRenderState(RenderStates.DestinationBlend, Blend.InvSourceAlpha)
        Device.SetRenderState(RenderStates.BlendOperation, TextureOperation.Add)
 
        Device.SetSamplerState(0, SamplerStageStates.MinFilter, TextureFilter.Point)
        Device.SetSamplerState(0, SamplerStageStates.MagFilter, TextureFilter.Point)
 
    End Sub
 
    Private Sub Create_Polygon()
 
        Vertex_List(0) = Create_Custom_Vertex(0, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 0)
        Vertex_List(1) = Create_Custom_Vertex(100, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 0)
        Vertex_List(2) = Create_Custom_Vertex(0, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 1)
        Vertex_List(3) = Create_Custom_Vertex(100, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 1)
 
    End Sub
 
    Private Sub Draw_Polygon()
 
        Device.VertexFormat = CustomVertex.TransformedColoredTextured.Format
        Device.SetTexture(0, Texture)
        Device.DrawUserPrimitives(PrimitiveType.TriangleStrip, 2, Vertex_List)
 
    End Sub
 
    Private Sub Load_Texture(ByRef Texture As Texture, ByVal Filepath As String, ByVal Transparency_Color As Integer)
 
        Texture = TextureLoader.FromFile(Device, Filepath, 512, 512, 1, Usage.None, Format.A8B8G8R8, Pool.Managed, Filter.Point, Filter.Point, Transparency_Color)
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1.0, 0)
        Device.BeginScene()
        'Rendering code goes here.
        Create_Polygon()
        Draw_Polygon()
        Device.EndScene()
        Device.Present()
        Application.DoEvents()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Render()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to full screen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Information) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        With Me
            .Show()
            .Width = 330
            .Height = 250
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True) 'Do not draw forms background
            .Text = "DirectX Tutorial"
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        DirectX_Initialize()
        Load_Texture(Texture, Application.StartupPath() & "\Sprite1.png", System.Drawing.Color.FromArgb(255, 0, 0, 0).ToArgb)
        Running = True
 
    End Sub
 
    Private Sub Shutdown()
 
        Running = False
        Texture = Nothing
        Device = Nothing
        Application.Exit()
 
    End Sub
 
 
    Private Sub frmMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles MyBase.KeyDown
 
        If e.KeyCode = Keys.Escape Then Shutdown()
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
 
        If Fullscreen_Enabled = False Then
            Running = False
            'Resets everything
            '---------------------------------------------
            Device.Reset(Screen)
            Device.SetRenderState(RenderStates.AlphaBlendEnable, True)
 
            Device.SetTextureStageState(0, TextureStageStates.ColorOperation, TextureOperation.Modulate)
            Device.SetTextureStageState(0, TextureStageStates.ColorArgument1, TextureArgument.TextureColor)
            Device.SetTextureStageState(0, TextureStageStates.ColorArgument2, TextureArgument.Diffuse)
 
            Device.SetTextureStageState(0, TextureStageStates.AlphaOperation, TextureOperation.Modulate)
            Device.SetTextureStageState(0, TextureStageStates.AlphaArgument1, TextureArgument.TextureColor)
            Device.SetTextureStageState(0, TextureStageStates.AlphaArgument2, TextureArgument.Diffuse)
 
            Device.SetRenderState(RenderStates.SourceBlend, Blend.SourceAlpha)
            Device.SetRenderState(RenderStates.DestinationBlend, Blend.InvSourceAlpha)
            Device.SetRenderState(RenderStates.BlendOperation, TextureOperation.Add)
 
            Device.SetSamplerState(0, SamplerStageStates.MinFilter, TextureFilter.Point)
            Device.SetSamplerState(0, SamplerStageStates.MagFilter, TextureFilter.Point)
            '---------------------------------------------
            Application.DoEvents()
            Running = True
        End If
 
    End Sub
End Class

Continued next post...

**Jacob Roman** · Mar 13th, 2014, 10:34 PM

Continued from last post...

To give the sprite fluent animation you would do this:

Animation first half

vb.net Code:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
 
Public Class frmMain
 
    Private Structure RECT
 
        Dim Left As Single
        Dim Top As Single
        Dim Right As Single
        Dim Bottom As Single
 
    End Structure
 
    Private Structure Animation_Type
 
        Dim Frame_Size() As RECT
        Dim Number_Of_Frames As Integer
        Dim Number_Of_Textures As Integer
        Dim Current_Frame As Single
        Dim Frame_Counter As Integer
        Dim Speed As Single
        Dim Initial_Frame As Integer
        Dim Mode As Integer 'Single Shot, Loop, etc.
        Dim Offset() As Vector2
        Dim Texture_Number() As Integer
 
    End Structure
 
    Private Structure Sprite_Type
 
        Dim Position As Vector2
        Dim Animation_State As Animation_Type
        <VBFixedString(256)> Dim Texture_Path() As String
        Dim Texture_List() As Texture
        Dim Total_Number_Of_Textures As Integer
        Dim Vertex_List As CustomVertex.TransformedColoredTextured()
        Dim Scale_Factor As Single
 
    End Structure
 
    Private Const COLOR_DEPTH_16_BIT As Format = Format.R5G6B5
    Private Const COLOR_DEPTH_24_BIT As Format = Format.A8R8G8B8
    Private Const COLOR_DEPTH_32_BIT As Format = Format.X8R8G8B8
 
    Private Const ANIMATION_MODE_SINGLE_SHOT As Integer = 0
    Private Const ANIMATION_MODE_LOOP As Integer = 1
 
    Private Device As Device
    Private Display_Mode As DisplayMode
    Private Screen As PresentParameters = New PresentParameters
 
    Private Fullscreen_Enabled As Boolean
    Private Fullscreen_Width As Integer
    Private Fullscreen_Height As Integer
    Private Window_Width As Integer
    Private Window_Height As Integer
    Private Running As Boolean = True
 
    Private Scalar As Vector2
    Private Sprite As Sprite_Type
 
    Private Function Create_Custom_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single, ByVal Color As Integer, ByVal TU As Integer, ByVal TV As Integer) As CustomVertex.TransformedColoredTextured
 
        Create_Custom_Vertex.Position = New Vector4(X, Y, Z, 1)
        Create_Custom_Vertex.Color = Color
        Create_Custom_Vertex.Tu = TU
        Create_Custom_Vertex.Tv = TV
 
    End Function
 
    Public Function Load_Texture(ByVal File_Path As String, ByVal Transparency_Color As Integer) As Texture
 
        Load_Texture = TextureLoader.FromFile(Device, File_Path, 512, 512, 1, Usage.None, Format.A8B8G8R8, Pool.Managed, Filter.Point, Filter.Point, Transparency_Color)
 
    End Function
 
    Private Sub Setup_Sprite()
 
        If Fullscreen_Enabled = True Then
            Scalar.X = 1
            Scalar.Y = 1
        ElseIf Fullscreen_Enabled = False Then
            Scalar.X = Convert.ToSingle(Window_Width / Fullscreen_Width)
            Scalar.Y = Convert.ToSingle(Window_Height / Fullscreen_Height)
        End If
 
        With Sprite
            .Position.X = 200
            .Position.Y = 400
            .Scale_Factor = 2
            .Vertex_List = New CustomVertex.TransformedColoredTextured(0 To 3) {}
            With .Animation_State
                .Number_Of_Frames = 6
                .Number_Of_Textures = 4
                .Speed = 0.2
                .Initial_Frame = 0
                .Mode = ANIMATION_MODE_LOOP
                ReDim .Frame_Size(.Number_Of_Frames)
                ReDim .Offset(.Number_Of_Frames)
                ReDim .Texture_Number(.Number_Of_Frames)
                .Frame_Size(0).Left = -61 : .Frame_Size(0).Top = -92 : .Frame_Size(0).Right = 61 : .Frame_Size(0).Bottom = 92
                .Frame_Size(1).Left = -62 : .Frame_Size(1).Top = -91 : .Frame_Size(1).Right = 62 : .Frame_Size(1).Bottom = 91
                .Frame_Size(2).Left = -61 : .Frame_Size(2).Top = -92 : .Frame_Size(2).Right = 61 : .Frame_Size(2).Bottom = 92
                .Frame_Size(3).Left = -60 : .Frame_Size(3).Top = -94 : .Frame_Size(3).Right = 60 : .Frame_Size(3).Bottom = 94
                .Frame_Size(4).Left = -57 : .Frame_Size(4).Top = -95 : .Frame_Size(4).Right = 57 : .Frame_Size(4).Bottom = 95
                .Frame_Size(5).Left = -60 : .Frame_Size(5).Top = -94 : .Frame_Size(5).Right = 60 : .Frame_Size(5).Bottom = 94
                Dim I As Integer
                'Were gonna use the center of the sprite for Position X and Y as well as make the sprite bigger using a scale factor
                For I = 0 To UBound(.Frame_Size)
                    With .Frame_Size(I)
                        .Left = (.Left / 2) * Sprite.Scale_Factor
                        .Top = (.Top / 2) * Sprite.Scale_Factor
                        .Right = (.Right / 2) * Sprite.Scale_Factor
                        .Bottom = (.Bottom / 2) * Sprite.Scale_Factor
                    End With
                Next I
                .Offset(0).X = 0 : .Offset(0).Y = 3
                .Offset(1).X = -1 : .Offset(1).Y = 4
                .Offset(2).X = 0 : .Offset(2).Y = 3
                .Offset(3).X = 0 : .Offset(3).Y = 0
                .Offset(4).X = -1 : .Offset(4).Y = 0
                .Offset(5).X = 0 : .Offset(5).Y = 0
                .Texture_Number(0) = 0
                .Texture_Number(1) = 1
                .Texture_Number(2) = 0
                .Texture_Number(3) = 2
                .Texture_Number(4) = 3
                .Texture_Number(5) = 2
 
            End With
 
        End With
 
    End Sub
 
    Public Sub Load_Sprite_Textures()
 
        Dim Current_Texture As Integer
 
        With Sprite
            .Total_Number_Of_Textures = 4
 
            ReDim .Texture_List(.Total_Number_Of_Textures)
            ReDim .Texture_Path(.Total_Number_Of_Textures)
 
            .Texture_Path(0) = Application.StartupPath & "\Ken - Fighting Stance1.png"
            .Texture_Path(1) = Application.StartupPath & "\Ken - Fighting Stance2.png"
            .Texture_Path(2) = Application.StartupPath & "\Ken - Fighting Stance3.png"
            .Texture_Path(3) = Application.StartupPath & "\Ken - Fighting Stance4.png"
 
            For Current_Texture = 0 To .Total_Number_Of_Textures - 1
                .Texture_List(Current_Texture) = Load_Texture(.Texture_Path(Current_Texture), System.Drawing.Color.FromArgb(255, 255, 0, 255).ToArgb)
            Next Current_Texture
        End With
 
    End Sub
 
    Private Sub Create_Polygon()
 
        Sprite.Vertex_List(0) = Create_Custom_Vertex(0, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 0)
        Sprite.Vertex_List(1) = Create_Custom_Vertex(100, 0, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 0)
        Sprite.Vertex_List(2) = Create_Custom_Vertex(0, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 1)
        Sprite.Vertex_List(3) = Create_Custom_Vertex(100, 100, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 1)
 
    End Sub
 
    Private Sub Animate_Sprite()
 
        Dim Frame As RECT
 
        Device.VertexFormat = CustomVertex.TransformedColoredTextured.Format
 
        With Sprite
            With .Animation_State
                If .Number_Of_Frames <> 0 Then
                    If .Current_Frame <= 0 Then .Current_Frame = 0
                    Select Case .Mode
                        Case ANIMATION_MODE_SINGLE_SHOT
                            If .Number_Of_Frames = 1 Then
                                .Current_Frame = 0
                            ElseIf .Number_Of_Frames > 1 Then
                                If .Current_Frame >= (.Number_Of_Frames - 1) Then
                                    .Current_Frame = (.Number_Of_Frames - 1)
                                End If
                            End If
                        Case ANIMATION_MODE_LOOP
                            If .Current_Frame > (.Number_Of_Frames - 1) Then
                                .Current_Frame = 0
                            End If
                    End Select
                End If
 
                Frame.Left = (Sprite.Position.X + .Frame_Size(CInt(.Current_Frame)).Left + (.Offset(CInt(.Current_Frame)).X)) * Scalar.X
                Frame.Top = (Sprite.Position.Y + .Frame_Size(CInt(.Current_Frame)).Top + .Offset(CInt(.Current_Frame)).Y) * Scalar.Y
                Frame.Right = (Sprite.Position.X + .Frame_Size(CInt(.Current_Frame)).Right + (.Offset(CInt(.Current_Frame)).X)) * Scalar.X
                Frame.Bottom = (Sprite.Position.Y + .Frame_Size(CInt(.Current_Frame)).Bottom + .Offset(CInt(.Current_Frame)).Y) * Scalar.Y
 
                With Frame
                    Sprite.Vertex_List(0) = Create_Custom_Vertex(.Left, .Top, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 0)
                    Sprite.Vertex_List(1) = Create_Custom_Vertex(.Right, .Top, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 0)
                    Sprite.Vertex_List(2) = Create_Custom_Vertex(.Left, .Bottom, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 0, 1)
                    Sprite.Vertex_List(3) = Create_Custom_Vertex(.Right, .Bottom, 0, System.Drawing.Color.FromArgb(255, 255, 255, 255).ToArgb, 1, 1)
                End With
 
                Device.SetTexture(0, Sprite.Texture_List(Sprite.Animation_State.Texture_Number(CInt(.Current_Frame))))
                If Running = True Then .Current_Frame += .Speed
            End With
            Device.DrawUserPrimitives(PrimitiveType.TriangleStrip, 2, .Vertex_List)
        End With
 
    End Sub
 
    Private Sub Set_Renderstates()
 
        'Right here will alphablend the polygon
        Device.SetRenderState(RenderStates.AlphaBlendEnable, True)
 
        'Needed for alphablending
        '----------------------------------------------------------------------------------------------------
        Device.SetTextureStageState(0, TextureStageStates.ColorOperation, TextureOperation.Modulate)
        Device.SetTextureStageState(0, TextureStageStates.ColorArgument1, TextureArgument.TextureColor)
        Device.SetTextureStageState(0, TextureStageStates.ColorArgument2, TextureArgument.Diffuse)
 
        Device.SetTextureStageState(0, TextureStageStates.AlphaOperation, TextureOperation.Modulate)
        Device.SetTextureStageState(0, TextureStageStates.AlphaArgument1, TextureArgument.TextureColor)
        Device.SetTextureStageState(0, TextureStageStates.AlphaArgument2, TextureArgument.Diffuse)
 
        Device.SetRenderState(RenderStates.SourceBlend, Blend.SourceAlpha)
        Device.SetRenderState(RenderStates.DestinationBlend, Blend.InvSourceAlpha)
        Device.SetRenderState(RenderStates.BlendOperation, TextureOperation.Add)
        '----------------------------------------------------------------------------------------------------
 
        'These lines are not needed, but it's nice to be able to filter the
        'textures to make them look nicer.
 
        Device.SetSamplerState(0, SamplerStageStates.MinFilter, TextureFilter.Point)
        Device.SetSamplerState(0, SamplerStageStates.MagFilter, TextureFilter.Point)
 
    End Sub
 
    Private Sub DirectX9_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 800
            Display_Mode.Height = 600
            Display_Mode.Format = COLOR_DEPTH_16_BIT
            'Check to see if fullscreen mode is supported before you use it.
            If Manager.CheckDeviceType(0, DeviceType.Hardware, Display_Mode.Format, Display_Mode.Format, False) Then
                ' Perfect, this is valid
                Screen.Windowed = False
                Screen.BackBufferCount = 1
                Screen.BackBufferWidth = Display_Mode.Width
                Screen.BackBufferHeight = Display_Mode.Height
            Else
                MessageBox.Show("Your video card doesn't support this screen resolution.", "", MessageBoxButtons.OK, MessageBoxIcon.Error)
            End If
        Else
            Screen.Windowed = True
        End If
 
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
 
        'Create our device
        Device = New Device(0, DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
        Set_Renderstates()
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target, Color.FromArgb(255, 0, 0, 0).ToArgb, 1.0, 0)
        Device.BeginScene()
        Create_Polygon()
        Animate_Sprite()
        Device.EndScene()
        Device.Present()
        Application.DoEvents()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Render()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to full screen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Information) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        Fullscreen_Width = 800
        Fullscreen_Height = 600
        Window_Width = 640
        Window_Height = 480
 
        With Me
            .Show()
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True) 'Do not draw forms background
            .Text = "DirectX Tutorial"
            .Width = Window_Width
            .Height = Window_Height
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        DirectX9_Initialize()
        Load_Sprite_Textures()
        Setup_Sprite()
        Running = True
 
    End Sub

Continued next post...

**Jacob Roman** · Mar 13th, 2014, 10:35 PM

Continued from last post....

Animation second half

vb.net Code:

Private Sub Shutdown()
 
        Dim Current_Texture As Integer
 
        Running = False
        For Current_Texture = 0 To Sprite.Total_Number_Of_Textures - 1
            Sprite.Texture_List(Current_Texture).Dispose() : Sprite.Texture_List(Current_Texture) = Nothing
        Next Current_Texture
        Device = Nothing
        Application.Exit()
 
    End Sub
 
    Private Sub frmMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles MyBase.KeyDown
 
        If e.KeyCode = Keys.Escape Then Shutdown()
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize
 
        If Fullscreen_Enabled = False Then
            Running = False 'Stop the loop
            Device.Reset(Screen) 'Reset the device. To not allow stretching, prior to this line, have Screen.Backbufferwidth & heights = 0.
            Set_Renderstates()
            Render() 'So we can see it stretch. As we stretch, especially when stretching larger, we get a black artifact. To avoid this we stop the animation and draw the current frame we have.
            Application.DoEvents() 'Must have to prevent the mouse event from locking up
            Running = True 'Reenable the loop
        End If
 
    End Sub
End Class

Hopefully you got something out of that little mini tutorial but that should lead you in the right direction in the world of DirectX

And your sprite class and textures should be coded a bit differently. You could have it to where you have a sub routine that loads all the textures to a sprite texture list, and you can work out the ID numbers to each of the animation states (like in my animation tutorial I showed you.)

And I can stress it enough, lay off the multithreading...and timers. I explained it all in the last thread, and so did dday afterwards

If you need help getting a tile engine going let me know.

Thread: XNA to DirectX [RPG] Sprite problem

Thread Tools

Display

XNA to DirectX [RPG] Sprite problem

Re: XNA to DirectX [RPG] Sprite problem

Re: XNA to DirectX [RPG] Sprite problem

Re: XNA to DirectX [RPG] Sprite problem

Re: XNA to DirectX [RPG] Sprite problem

Re: XNA to DirectX [RPG] Sprite problem

Posting Permissions