number only problem

[codesearcher]

To restrict my textbox intended for integer, i use keypress and coded it to accept only numbers but i realized i cant input period for decimal. How should this be properly done.

[Bonnie West]

This problem has been discussed here and elsewhere numerous times already. Have you tried searching, codesearcher?

[Bobbles]

Option Explicit
Const VALID_CHARS As String = "0123456789."

Private Sub Text1_KeyPress(KeyAscii As Integer)
  If KeyAscii > 26 Then ' if it's not a control code
    If InStr(VALID_CHARS, Chr(KeyAscii)) = 0 Then
      KeyAscii = 0
    End If
  End If
End Sub

[Zvoni]

This problem has been discussed here and elsewhere numerous times already. Have you tried searching, codesearcher?

Yepp, i even remember a thread where i posted a solution which only accepts one decimal separator

[Lenggries]

Alternatively, you can validate the string after the input:

Private Sub Text1_Change()
    Dim strVal As String
    
    'use static local variable to manage reverting back to previous value
    Static strLast As String

    'trim the value
    strVal = Trim$(Text1.Text)
    
    If Len(Text1.Text) = 0 Then      
        'text field is blank. This is OK, but clearly no need to validate
        'NOTE: delete this first branch of the if statement if an empty next box is also invalid 
        '         (just make sure strLast get's seeded somehow with a valid piece of data... 
        '         might need ot use a modul level field insteadf of the static local)
        strLast = ""
    ElseIf Len(Text1.Text) <> Len(strVal) Then
        'something was trimmed. Set the field to the stripped value,
        'which will trigger this event handler again
        Text1.Text = strVal
    ElseIf IsNumeric(strVal) Then     
        'it's a number
        strLast = strVal
        'NOTE: You can replace IsNumeric() with a general call to a validate() 
        '         function if you want to restrict the type of values they can enter even further.
    Else
        'text field not numeric or blank. Revert to previous value
        'this will re-trigger the event handler, which is fine
        Text1.Text = strLast
    End If
End Sub

I personally prefer this framework when I validate textboxes because it gives me lot's of flexibility, plus it handles things well when someone pastes in a value (which doesn't always generate a keypress). The downside is that you can sometimes see a bit of flickering in the textbox when someone types in invalid characters... or when my cat walks across my keyboard.

[RhinoBull]

Have a look at this CodeBank submission by MartinLiss.

[Zvoni]

Eh? I even found the thread: http://www.vbforums.com/showthread.php?710091-Keycode

[Doogle]

To restrict my textbox intended for integer, i use keypress and coded it to accept only numbers but i realized i cant input period for decimal. How should this be properly done.

If it's intended that the TextBox holds only Integers why would you want to allow a decimal separator ?