[RESOLVED] Environment loading-rendering-rotating.

[PAPYRON]

I won't work more with black screen and only a 3d gun.
Now i has 4 images, or a dds's from directx sdk media folder.
I wanna make it become a "world" inside the window (I mean... landscape).
And how can i do that?

[Jacob Roman]

Here is a small sample code I created (in practically 4 programming languages o.O) that allows you to move around like in a FPS. However I haven't created it in vb.net yet, I also have code that renders a skybox as well which is also nice to have. If you give me time I can create it for you. But in the mean time, heres the FPS code. Use W S A D to move around and the mouse to move the camera:

Option Explicit On
Option Strict On
 
Imports Microsoft.DirectX
Imports Microsoft.DirectX.Direct3D
Imports Microsoft.DirectX.DirectInput
 
Public Class frmMain
 
    Private Const FOV As Single = Math.PI / 4
    Private Const ASPECT_RATIO As Single = 4 / 3
    Private Const NEAR_Z As Single = 1
    Private Const FAR_Z As Single = 10000
 
    Private Device As Direct3D.Device
    Private Display_Mode As DisplayMode
    Private Screen As New PresentParameters
 
    Private Mouse_Device As DirectInput.Device
    Private Mouse_State As MouseState
    Private Mouse As Vector2
 
    Private Keyboard_Device As DirectInput.Device
    Private Keyboard_State As KeyboardState
 
    Private Vertex_List(3) As CustomVertex.PositionColored
 
    Private View_Matrix As Matrix
    Private Projection_Matrix As Matrix
 
    Private Camera_Position As Vector3
    Private Camera_Angle As Vector3
 
    Private Fullscreen_Enabled As Boolean
    Private Running As Boolean
 
    Private Sub DirectX_Initialize()
 
        If Fullscreen_Enabled = True Then
            Display_Mode.Width = 800
            Display_Mode.Height = 600
            Display_Mode.Format = Direct3D.Format.R5G6B5
            Screen.Windowed = False
            Screen.BackBufferCount = 1
            Screen.BackBufferWidth = Display_Mode.Width
            Screen.BackBufferHeight = Display_Mode.Height
        Else
            Screen.Windowed = True
        End If
 
        Screen.SwapEffect = SwapEffect.Copy
        Screen.BackBufferFormat = Display_Mode.Format
        Screen.AutoDepthStencilFormat = DepthFormat.D16
        Screen.EnableAutoDepthStencil = True
 
        Device = New Direct3D.Device(0, Direct3D.DeviceType.Hardware, Me.Handle, CreateFlags.SoftwareVertexProcessing, Screen)
 
    End Sub
 
    Private Sub DirectInput_Initialize_Mouse()
 
        Mouse_Device = New DirectInput.Device(SystemGuid.Mouse)
        Mouse_Device.SetDataFormat(DeviceDataFormat.Mouse)
        Mouse_Device.SetCooperativeLevel(Me, CooperativeLevelFlags.Background Or CooperativeLevelFlags.NonExclusive)
        Mouse_Device.Acquire()
 
    End Sub
 
    Private Sub Mouse_Controls()
 
        Mouse_State = Mouse_Device.CurrentMouseState
 
        Mouse.X = Mouse.X + Mouse_State.X
        Mouse.Y = Mouse.Y + Mouse_State.Y
 
        If Mouse.X > Me.Width Then Mouse.X = Me.Width
        If Mouse.X < 0 Then Mouse.X = 0
 
        If Mouse.Y > Me.Height Then Mouse.Y = Me.Height
        If Mouse.Y < 0 Then Mouse.Y = 0
 
        Camera_Angle.X += Mouse_State.Y
        Camera_Angle.Y += Mouse_State.X
 
        If Camera_Angle.X >= 90 Then Camera_Angle.X = 90
        If Camera_Angle.X <= -90 Then Camera_Angle.X = -90
 
    End Sub
 
    Private Sub DirectInput_Initialize_Keyboard()
 
        Keyboard_Device = New DirectInput.Device(SystemGuid.Keyboard)
        Keyboard_Device.SetDataFormat(DeviceDataFormat.Keyboard)
        Keyboard_Device.SetCooperativeLevel(Me, CooperativeLevelFlags.Background Or CooperativeLevelFlags.NonExclusive)
        Keyboard_Device.Acquire()
 
    End Sub
 
    Private Function DirectInput_Key_State(ByVal Key_Code As DirectInput.Key) As Boolean
 
        Keyboard_State = Keyboard_Device.GetCurrentKeyboardState
        Return Keyboard_State.Item(Key_Code)
 
    End Function
 
    Private Sub Keyboard_Controls()
 
        Const Camera_Speed As Long = 5
 
        If DirectInput_Key_State(Key.W) Then 'Move Forward
            Camera_Position.X -= Convert.ToSingle(Math.Sin(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
            Camera_Position.Z -= Convert.ToSingle(Math.Cos(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
        End If
 
        If DirectInput_Key_State(Key.S) Then 'Move Backward
            Camera_Position.X += Convert.ToSingle(Math.Sin(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
            Camera_Position.Z += Convert.ToSingle(Math.Cos(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
        End If
 
        If DirectInput_Key_State(Key.A) Then 'Move Left
            Camera_Position.X += Convert.ToSingle(Math.Cos(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
            Camera_Position.Z -= Convert.ToSingle(Math.Sin(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
        End If
 
        If DirectInput_Key_State(Key.D) Then 'Move Right
            Camera_Position.X -= Convert.ToSingle(Math.Cos(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
            Camera_Position.Z += Convert.ToSingle(Math.Sin(Camera_Angle.Y * Math.PI / 180)) * Camera_Speed
        End If
 
        If DirectInput_Key_State(Key.Q) Then 'Look Left
            Camera_Angle.Y -= 1
        End If
 
        If DirectInput_Key_State(Key.E) Then 'Look Right
            Camera_Angle.Y += 1
        End If
 
        If DirectInput_Key_State(Key.R) Then 'Look Up
            Camera_Angle.X -= 1
        End If
 
        If DirectInput_Key_State(Key.F) Then 'Look Down
            Camera_Angle.X += 1
        End If
 
        If DirectInput_Key_State(Key.C) Then 'Move Up
            Camera_Position.Y -= Camera_Speed
        End If
 
        If DirectInput_Key_State(Key.Z) Then 'Move Down
            Camera_Position.Y += Camera_Speed
        End If
 
    End Sub
 
    Private Sub Settings()
 
        Device.SetRenderState(RenderStates.ZEnable, True)
        Device.SetRenderState(RenderStates.ZBufferWriteEnable, True)
        Device.SetRenderState(RenderStates.CullMode, Cull.None)
        Device.SetRenderState(RenderStates.Lighting, False)
 
    End Sub
 
    Private Function Create_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single) As Vector3
 
        Dim Vertex As Vector3
 
        Vertex.X = X
        Vertex.Y = Y
        Vertex.Z = Z
 
        Return Vertex
 
    End Function
 
    Private Function Create_Custom_Vertex(ByVal X As Single, ByVal Y As Single, ByVal Z As Single, ByVal Color As Integer) As CustomVertex.PositionColored
 
        Dim Vertex As CustomVertex.PositionColored = New CustomVertex.PositionColored
 
        Vertex.Position = New Vector3(X, Y, Z)
        Vertex.Color = Color
 
        Return Vertex
 
    End Function
 
    Private Sub Setup_Matrices()
 
        View_Matrix = Matrix.LookAtRH(Create_Vertex(Camera_Position.X, Camera_Position.Y, Camera_Position.Z), Create_Vertex(0, 0, 0), Create_Vertex(0, 1, 0))
        Device.Transform.View = View_Matrix
 
        Projection_Matrix = Matrix.PerspectiveFovRH(FOV, ASPECT_RATIO, NEAR_Z, FAR_Z)
        Device.Transform.Projection = Projection_Matrix
 
    End Sub
 
    Private Sub Camera_Control()
 
        Dim Camera_Translation_Matrix As Matrix
        Dim Camera_Angle_Matrix_X As Matrix
        Dim Camera_Angle_Matrix_Y As Matrix
 
        View_Matrix = Matrix.Identity
        Camera_Translation_Matrix = Matrix.Identity
 
        Camera_Translation_Matrix = Matrix.Translation(Camera_Position.X, Camera_Position.Y, -Camera_Position.Z)
        View_Matrix = Matrix.Multiply(View_Matrix, Camera_Translation_Matrix)
 
        Camera_Angle_Matrix_Y = Matrix.RotationY((Convert.ToSingle(Math.PI) * Camera_Angle.Y) / 180)
        View_Matrix = Matrix.Multiply(View_Matrix, Camera_Angle_Matrix_Y)
 
        Camera_Angle_Matrix_X = Matrix.RotationX((Convert.ToSingle(Math.PI) * Camera_Angle.X) / 180)
        View_Matrix = Matrix.Multiply(View_Matrix, Camera_Angle_Matrix_X)
 
        Device.Transform.View = View_Matrix
 
    End Sub
 
    Private Sub Create_Polygon()
 
        Vertex_List(0) = Create_Custom_Vertex(-50, 100, 0, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(1) = Create_Custom_Vertex(50, 100, 0, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(2) = Create_Custom_Vertex(-50, 0, 0, Color.FromArgb(255, 255, 255).ToArgb)
        Vertex_List(3) = Create_Custom_Vertex(50, 0, 0, Color.FromArgb(255, 255, 255).ToArgb)
 
    End Sub
 
    Private Sub Draw_Polygon()
 
        Device.VertexFormat = CustomVertex.PositionColored.Format
        Device.DrawUserPrimitives(PrimitiveType.TriangleStrip, 2, Vertex_List)
 
    End Sub
 
    Private Sub Create_Platform()
 
        Vertex_List(0) = Create_Custom_Vertex(-1000, 0, -1000, Color.FromArgb(255, 0, 0).ToArgb)
        Vertex_List(1) = Create_Custom_Vertex(1000, 0, -1000, Color.FromArgb(0, 255, 0).ToArgb)
        Vertex_List(2) = Create_Custom_Vertex(-1000, 0, 1000, Color.FromArgb(0, 0, 255).ToArgb)
        Vertex_List(3) = Create_Custom_Vertex(1000, 0, 1000, Color.FromArgb(255, 0, 255).ToArgb)
 
    End Sub
 
    Private Sub Reset_Device()
 
        If Me.WindowState <> FormWindowState.Minimized And Fullscreen_Enabled = False Then
            Running = False
            Device.Reset(Screen)
            Settings()
            Setup_Matrices()
            Application.DoEvents()
            Running = True
        End If
 
    End Sub
 
    Private Sub Render()
 
        Device.Clear(ClearFlags.Target Or ClearFlags.ZBuffer, Color.FromArgb(0, 0, 0), 1, 0)
        Device.BeginScene()
        Create_Polygon()
        Draw_Polygon()
        Create_Platform()
        Draw_Polygon()
        Device.EndScene()
        Device.Present()
 
    End Sub
 
    Private Sub Game_Loop()
 
        Do While Running = True
            Mouse_Controls()
            Keyboard_Controls()
            Camera_Control()
            Render()
            If DirectInput_Key_State(Key.Escape) Then Shutdown()
            Application.DoEvents()
        Loop
 
    End Sub
 
    Private Sub Main()
 
        If MessageBox.Show("Click Yes to go to fullscreen (Recommended)", "", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = DialogResult.Yes Then
            Fullscreen_Enabled = True
        End If
 
        With Me
            .Show()
            .Width = 330
            .Height = 250
            .SetStyle(ControlStyles.AllPaintingInWmPaint Or ControlStyles.Opaque, True)
            .Text = "DirectX Tutorial"
            If Fullscreen_Enabled = True Then .FormBorderStyle = Windows.Forms.FormBorderStyle.None
        End With
 
        Camera_Position.X = 0
        Camera_Position.Y = -50
        Camera_Position.Z = 250
 
        DirectX_Initialize()
        DirectInput_Initialize_Mouse()
        DirectInput_Initialize_Keyboard()
        Settings()
        Setup_Matrices()
        Running = True
 
    End Sub
 
    Private Sub Shutdown()
 
        If Running = True Then
            Running = False
            Mouse_Device.Unacquire()
            Mouse_Device.Dispose()
            Keyboard_Device.Unacquire()
            Keyboard_Device.Dispose()
            Device.Dispose()
            Application.Exit()
        End If
 
    End Sub
 
    Private Sub frmMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        Main()
 
    End Sub
 
    Private Sub frmMain_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
 
        Shutdown()
 
    End Sub
 
    Private Sub frmMain_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles MyBase.Paint
 
        Game_Loop()
 
    End Sub
 
    Private Sub frmMain_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles MyBase.Resize
 
        Reset_Device()
 
    End Sub
 
End Class

[PAPYRON]

Works nice. And I wanna code it myself. You make me want to play counter-strike.
And how can I load the dds environment files - No, they loaded by: Surface.From file, aren't they? How to glue them to the world?
Or a mesh with mountains, trees, and more?

[Jacob Roman]

Hmmm never really worked with dds files. Personally Id be creating my own, like I did with my Bosskillers game for my worlds. Best if you create your own format unless you seriously research the ins and outs and find out how that file works, and managed to find tons of source code in either vb.net, or vb6. Vb6 you can easily port to vb.net mind you and since it been out a hell of a lot longer, you should find code. Worse case scenario is finding source code on dds files and converting C++ to vb.net. Thats what I would do if i were you. Or if you need to, just hardcode the locations of your meshes and create your own terrain/worlds.

[PAPYRON]

ground mesh (ground, mountain, houses) may easily 100x easier.