[RESOLVED] find exact string using instr, ignoring partials

[starscrea2]

Hello,
I am trying to select words that end in "ion" while ignoring words that contain "ion" but don't end in "ion". This code works to detect "ion" and ignore "iones", but it is looking at the last word in the textbox to find the string. So if I type in "iones ion" it will detect the last "ion", but if I type in "ion iones" it ignores the "ion" before the "iones", because it is focusing on the "iones" at the end of the textbox. How can I get the program to do this?

Private Sub Command2_Click()

If InStr(1, Text1.Text, "ion", vbTextCompare) > 0 Then
If Right(Text1.Text, 3) = "ion" Then

List2.AddItem "ion is found"

End If
End If

End Sub

Thanks!

[stlaural]

You could split your string into word and then for each word check if it ends with "ion".
Make sure to trim the spaces and unwanted characters like the period "." or the comma ",".

Another way would be to use regular expressions.

[jemidiah]

Yet another way is to verify that the letter following "ion" (if it exists) is not a-z or A-Z. To select all "ion"'s in a given string you'd need to call InStr repeatedly with ever-increasing starting indexes and filter out values according to the above condition.

[Doogle]

Yet another way would be to use the Like Operator instead of InStr

Option Explicit

Private Sub Command_Click()
Dim str As String
Dim strA() As String
Dim intI As Integer
str = "xion ions relation relations ion ions"
strA = Split(str, " ")
For intI = 0 To UBound(strA)
    If strA(intI) Like "*ion" Then Debug.Print strA(intI)
Next intI
End Sub

[jemidiah]

Yet another way would be to use the Like Operator instead of InStr

I like that option (pun intended ), though as stlaural mentioned you have to remember to account for periods and commas. With the Like syntax, that's not too hard--just make sure the character after "ion" is non-alphabetic or non-existent.

I was imagining the OP was doing something like highlighting the occurrences of word suffixes and that they'd want the index of the start of each occurrence in the original text, which is why I suggested iterating InStr's instead of Split (Split makes it hard to recover the index in the case where you've modified parts of the Split array strings). Now that I've thought about it, though, if you let the Like operator handle filtering, recovering the index isn't hard at all.

[lone_REBEL]

Holijuit! You pundits are trying to make a seemingly simple issue seem so complex. Here, let me try my simplest solution so far. StarsCrea implied that "ion" should be at the end of the word. This implies four possibilities:
1- There is a space after "ion" and "ion" exists in the middle/start of the string (e.g. Water molecules are formed with an Oxygen ION and two Hydrogen ions.)
2- A sentence in the string ends at "ion. " while the string carries on with other data too (e.g. Water molecues contain one Oxygen ION. Sand molecules have two Oxygen ions)
3- The string ends at "ion" (e.g. Water molecules contain one Oxygen ION)
4- The string ends at "ion." (e.g. Water molecules contain one Oxygen ION.)

Here is what is my approach about the matter:

Private Sub Command2_Click()
   If InStr(Text1.Text,"ion ")<>0 Then
      List2.AddItem "ion found at the end of a word"
   ElseIf InStr(Text1.Text "ion. ")<>0 Then
      List2.AddItem "ion found at the end of a sentence"
   ElseIf Right(Text1.Text,3)="ion" Then
      List2.AddItem "ion found at the end of string (Bad grammar. Should contain a period at the end)"
   ElseIf Right(Text1.Text,4)="ion." Then
      List2.AddItem "ion. found at the end of string (Standard English grammar)"
   End If
End Sub

Note that I've posted the code with the possibilities that arose in my own mind. If there are more possibilities of this, you might want to add more ElseIf lines.

[starscrea2]

Thank you to all who suggested solutions. Now, If I type in "solutions", it ignores it, since it ends in S, but if I type in "solution", it detects it, even if the "solution" comes before "solutions". I ended up going with Lone_Rebel's solution...

Thanks again!

[Doogle]

My only critism of lone_Rebel's solution is that the If statement can get quite large if you take into account all the possible punctuation marks etc that could legitimately follow the word. eg. ; : ? ! } ] ) -# " ' that's another 11 ElseIf's to code. Also, assuming you're using a multi-line TextBox, you'll have to take the vbCrLf, or vbNewLine, at the end of each line into account.

[jemidiah]

I agree with Doogle. That solution isn't very robust and I'd hate to see it in commercial code because of how many edge cases it fails. But, maybe my standards are too high in this case. Ah well, glad it worked out.

[lone_REBEL]

I agree with you guys too. This code isn't suitable for commercial apps where you don't have the option to edit the code once you distribute the application on a large scale but should do for school projects and personal use. I think my most accurate and precise attempt would be creating an array of characters which, if appear after "ion" should still make it count (e.g. . , ? ! and other quotation marks). But that would be a bit complex to go with Crea's understanding of VB thats why I went with the relatively simple code which he can understand and modify to his needs.

For you experts I think I would have used something like this (note that this is not the exact code. It is just a general structure of the coding I'd use if I needed it to be precise.

Const allowedlist As Integer=7
Dim puncts(1 to allowedlist) As String
puncts(1)="."
puncts(2)=","
puncts(3)=" "
puncts(4)="?"
'... and so on till you complete your list of punctuation marks

Function DoesStrExist(ByRef data As String, ByRef srch_str As String) As Integer
   Dim i As Integer
   For i=1 to allowedlist
      If InStr(data,srch_str)<>0 Then
         DoesStrExist=Instr(data,srch_str)
         Exit Function
      End If
   Next i
   If Right(data,len(srch_str)=srch_str) Then
      DoesStrExist=len(data)-len(srch_str)+1
      Exit Function
   End If
   DoesStrExist=0
End Function

[Merri]

This works with any alphabet that makes a difference with lower & uppercase letters:

Option Explicit

Public Function FindEOS(String1 As String, String2 As String, Optional ByVal Start As Long = 1, Optional ByVal Compare As VbCompareMethod = vbBinaryCompare) As Long
    Dim C As String, E As Long, L1 As Long, L2 As Long, P As Long
    L1 = Len(String1)
    L2 = Len(String2)
    P = Start - 1
    Do
        P = InStr(P + 1, String1, String2, Compare)
        If P Then
            E = P + L2
            If E > L1 Then
                FindEOS = P
                Exit Do
            Else
                C = Mid$(String1, E, 1)
                If AscW(UCase$(C)) = AscW(LCase$(C)) Then
                    FindEOS = P
                    Exit Do
                End If
            End If
        End If
    Loop While P
End Function

Private Sub Form_Load()
    Debug.Print FindEOS("medios", "ios") ' 4
    Debug.Print FindEOS("medios(", "ios") ' 4
    Debug.Print FindEOS("mediosä", "ios") ' 0
    Debug.Print FindEOS("medios.", "ios") ' 4
    Unload Me
End Sub

It is somewhat fast too and you can easily search for multiple occurances.

[Max187Boucher]

wrong thread