[RESOLVED] [VB6] - instead api_doevents

[joaquim]

can i let the events being used\activated without using:

Option Explicit

Private Const PM_REMOVE = &H1&
Private Type Msg
    hwnd As Long
    message As Long
    wParam As Long
    lParam As Long
    time As Long
    ptX As Long
    ptY As Long
End Type
Private Declare Function TranslateMessage Lib "user32" (lpMsg As Msg) As Long
Private Declare Function DispatchMessage Lib "user32" Alias "DispatchMessageA" (lpMsg As Msg) As Long
Private Declare Function PeekMessage Lib "user32" Alias "PeekMessageA" (lpMsg As Msg, _
                                                  ByVal hwnd As Long, _
                                                  ByVal wMsgFilterMin As Long, _
                                                  ByVal wMsgFilterMax As Long, _
                                                 ByVal wRemoveMsg As Long) As Long

Public Sub API_DoEvents(ByVal hwnd As Long)
   
   Dim TMsg As Msg
   Do While PeekMessage(TMsg, hwnd, 0&, 0&, PM_REMOVE)
        TranslateMessage TMsg
        DispatchMessage TMsg
        
  Loop
  
End Sub

????

[Bonnie West]

This is functionally similar to DoEvents but it only yields to the OS when there is actually something to process.

Private Declare Function GetInputState Lib "user32.dll" () As Long
Private Declare Function GetQueueStatus Lib "user32.dll" (ByVal Flags As Long) As Long

'Yields execution only when a message has arrived so that the operating system can process other events.
Public Function DoEventsEx() As Integer
    #Const Keyboard_and_Mouse_Messages_Only = False
    Const QS_ALLINPUT = &H4FF&

    #If Keyboard_and_Mouse_Messages_Only Then
        If GetInputState Then DoEventsEx = DoEvents
       'GetInputState returns TRUE (nonzero) if either a keyboard or mouse message is in the application's
       'input queue. If the application must distinguish between a mouse and a keyboard message, GetInputState
       'returns the value 2 for a keyboard and the value 1024 for a mouse message.
    #Else
        If GetQueueStatus(QS_ALLINPUT) And &HFFFF0000 Then DoEventsEx = DoEvents
       'The high-order word of GetQueueStatus' return value indicates the types of messages currently in the
       'queue. The low-order word indicates the types of messages that have been added to the queue and that
       'are still in the queue since the last call to the GetQueueStatus, GetMessage, or PeekMessage function.
    #End If
End Function

[joaquim]

This is functionally similar to DoEvents but it only yields to the OS when there is actually something to process.

Private Declare Function GetInputState Lib "user32.dll" () As Long
Private Declare Function GetQueueStatus Lib "user32.dll" (ByVal Flags As Long) As Long

'Yields execution only when a message has arrived so that the operating system can process other events.
Public Function DoEventsEx() As Integer
    #Const Keyboard_and_Mouse_Messages_Only = False
    Const QS_ALLINPUT = &H4FF&

    #If Keyboard_and_Mouse_Messages_Only Then
        If GetInputState Then DoEventsEx = DoEvents
       'GetInputState returns TRUE (nonzero) if either a keyboard or mouse message is in the application's
       'input queue. If the application must distinguish between a mouse and a keyboard message, GetInputState
       'returns the value 2 for a keyboard and the value 1024 for a mouse message.
    #Else
        If GetQueueStatus(QS_ALLINPUT) And &HFFFF0000 Then DoEventsEx = DoEvents
       'The high-order word of GetQueueStatus' return value indicates the types of messages currently in the
       'queue. The low-order word indicates the types of messages that have been added to the queue and that
       'are still in the queue since the last call to the GetQueueStatus, GetMessage, or PeekMessage function.
    #End If
End Function

thanks for all

[ColinE66]

Thanks Bonnie - that's very useful...