Please help me develop my cryptogram Encoder / Decoder

[Stoowyguy]

I am trying to make a program on Visual Basics that lets me basically type a message in a text box for example (Hello, How are you doing) and make it come out on Texbox 2 when i click (encrypt) saying (QREEO, QOE XFR KOB FOJNG).. Or if i typed (QREEO, QOE XFR KOB FOJNG) and i click (decrypt) have it come out textbox 2 saying (Hello, How are you doing). Now obvisuly i dont care about case-sensitivity but I do want to be able to code the program so that it know my (secret language) and can translate something back to me if I want it to.. I was thinking I could like code the buttons to have the textbox like say (if textbox1 = "A" then textbox2 = "R" ... something like that I have like really little expierence coding but i do know how to use the program. So I know its alot but code someone at least get me started on what the coding would even be or some suggestions... (Its not all random its an actual code that i put together...)

[Nightwalker83]

Which version of Visual Basic are you using?

[pixxeldigital]

hi
i use visual basic 6 for programming

[gep13]

Hello,

Since this is a VB6 question, I am going to move it to the VB6 Forum.

By the way, pixxeldigital you replied to a thread which was started by Stoowyguy, are both of these your accounts?

Gary

[Doogle]

Here's something to get you started

Option Explicit
Dim strCode As String

Private Sub cmdCode_Click()
Dim strToCode As String
Dim strCoded As String
Dim intI As Integer
Dim intChr As Integer
Dim intPos As Integer
strToCode = UCase(Text1.Text)
For intI = 1 To Len(strToCode)
    '
    ' Pick up the next character in the data to encode
    ' Convert to ASCII
    ' If it's a space then don't encode it
    ' Use the ASCII value to index into the Code String
    ' and pick up up that character as the encoded letter
    ' Repeat for all data to be encoded
    '
    intChr = Asc(Mid$(strToCode, intI, 1))
    If intChr <> 32 Then
        intPos = intChr - Asc("A")
        strCoded = strCoded & Mid$(strCode, intPos + 1, 1)
    Else
        strCoded = strCoded & " "
    End If
Next intI
Text2.Text = strCoded
End Sub

Private Sub cmdDecode_Click()
Dim strCoded As String
Dim strDecode As String
Dim strChr As String
Dim intI As Integer
Dim intPos As Integer
strCoded = Text2.Text
For intI = 1 To Len(strCoded)
    '
    ' Pick up the next encoded character
    ' Find its position within the Code String
    ' If it's not found then it must be a Space Character
    ' If it is found then convert the position to an ASCII Character
    ' in the range A to Z
    ' Add it to the decoded data
    '
    strChr = Mid$(strCoded, intI, 1)
    intPos = InStr(strCode, strChr)
    If intPos > 0 Then
        intPos = intPos + Asc("A") - 1
        strDecode = strDecode & Chr(intPos)
    Else
        strDecode = strDecode & " "
    End If
Next intI
Text3.Text = strDecode
End Sub

Private Sub Form_Load()
strCode = "QAZWSXEDCRFVTGBYHNUJMIKOLP"
Text1.Text = ""
Text2.Text = ""
Text3.Text = ""
End Sub

I'll leave you to work out how to cope with numerics, punctuation and lower case letters. (It's not much fun for you if we do it all for you !)