Sorting list of objects

[borowik]

Hi,

I've created class which has 3 fields:

• Name
• Date and time of birth
• Weight

I create several objects and then put them into the list. Thanks to that later I can iterate list and display content of object on the asp page.

It looks like table below:
|Mike John|7/4/2012 6:55:31 AM|3450|
|Lisa Ann|7/3/2012 6:43:31 AM|3650|
|Betty|6/3/2012 8:47:31 AM|2850|

User would like to have option to sort according to values one of these columns.

How could I sort list of these objects?


Regards,
Lukasz

[.paul.]

try this:

Public Class Form1
 
    Dim people As New List(Of person)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
        people.Add(New person("Mike John", DateTime.Parse("7/4/2012 6:55:31 AM"), 3450))
        people.Add(New person("Lisa Ann", DateTime.Parse("7/3/2012 6:43:31 AM"), 3650))
        people.Add(New person("Betty", DateTime.Parse("6/3/2012 8:47:31 AM"), 2850))
 
    End Sub
 
    Private Sub ComboBox1_SelectedIndexChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectedIndexChanged
        'the combobox contains 3 strings
        ' 0 = byName
        ' 1 = byDOB
        '2 = byWeight
 
        'the checkbox specifies ascending (checked) or descending (unchecked)
 
        Select Case ComboBox1.SelectedIndex
            Case 0
                If CheckBox1.Checked Then 'ascending
                    people.Sort(Function(x, y) x.name.CompareTo(y.name))
                Else 'descending
                    people.Sort(Function(x, y) y.name.CompareTo(x.name))
                End If
            Case 1
                If CheckBox1.Checked Then 'ascending
                    people.Sort(Function(x, y) x.DOB.CompareTo(y.DOB))
                Else 'descending
                    people.Sort(Function(x, y) y.DOB.CompareTo(x.DOB))
                End If
            Case 2
                If CheckBox1.Checked Then 'ascending
                    people.Sort(Function(x, y) x.weight.CompareTo(y.weight))
                Else 'descending
                    people.Sort(Function(x, y) y.weight.CompareTo(x.weight))
                End If
        End Select
 
        For Each p As person In people
            Debug.Print(p.ToString)
        Next
        Debug.Print("")
 
    End Sub
 
End Class

this is the person class:

Public Class person
    Public name As String
    Public DOB As DateTime
    Public weight As Integer
 
    Public Sub New(ByVal name As String, ByVal DOB As DateTime, ByVal weight As Integer)
        Me.name = name
        Me.DOB = DOB
        Me.weight = weight
    End Sub
 
    Public Overrides Function ToString() As String
        Return String.Format("{0}, {1}, {2}", Me.name, Me.DOB, Me.weight)
    End Function
 
End Class

[borowik]

Thank you very much!

Lukasz

[ForumAccount]

Paul, what unit of weight are you using?!

[.paul.]

Paul, what unit of weight are you using?!

i dunno i just followed the OP's instructions...

[borowik]

Hi,

How could I sort objects for example first according to the Name and then according to Weight? (I assume that there can be several people with the same name)

Lukasz

[.paul.]

try this:

people.Sort(Function(x, y) If(x.name = y.name, x.weight.CompareTo(y.weight), x.name.CompareTo(y.name)))

[MattP]

Paul, what unit of weight are you using?!

Here's a table listing average baby weight in grams by gestational age: http://www.babycenter.com/average-fe...h-weight-chart.

[borowik]

Thanks Paul,

Lukasz