Understanding Multi-Threading in VB.Net

[Niya]

The SynchronizationContext is used to submit methods to run on the thread associated with the context.

In your case, the SynchronizationContext object belongs to the UI thread therefore whenever a method is executing on any other thread and needs to run a method back on the UI thread, it uses the SynchronizationContext's Send to do so.

[psoftware]

Sorry, but it's a bit hard write in english because it's the first time I do it in a forum, and this is a difficult argument
I used your ThreadExtensions Class, and now i need to call some subs in RemoteClient classes, which are created in the BackgroundWorker thread, from the UI Thread....(from button click event subs and others). How can I do this?

[Niya]

Well classes in the strictest sense aren't really thread specific, running methods are. That means a single class can have many different methods running at the same time on different threads. You can call the class' methods from the UI thread as you call any method. The only problem with this is when your method intends to interact with an object that another method running on another thread is interacting with. In that case you would need to consider some kind of synchronization so that the two threads don't try to access the object at exactly the same time. If such a condition doesn't exist then you can safely call the method from the UI in the normal way.

The only reason we even need a SynchronizationContext with multi-threaded objects is because controls are a special case and need to be manipulated on the thread they were created on(usually the UI thread). When controls aren't involve things become much simpler.

[psoftware]

This is exactly what I want...

In that case you would need to consider some kind of synchronization so that the two threads don't try to access the object at exactly the same time.

How can I do this? I have to call some subs in my RemoteClient class which permits my application to send text to the clients... I call this subs from both threads (UI thread adn BackgroundWorker thread) and It could happen the two threads try to access the sub and the objects used in the sub, at exactly the same time....

[Niya]

Well calling the same method multiple times from different threads isn't actually a problem. Running methods are really instances of the methods. What you need to look out for are lines of code that access objects outside the scope of the methods for example a private field.

Consider the following:-

Public Class Test
 
    Public Sub Method1()
        For i = 1 To 100
            Debug.Print(i)
        Next
    End Sub
 
End Class

You are free to call Method1 as many times as you want from as many threads as you want. If you called it from one thread the same time another thread calls it, then there would be two different instances of the same method running. There is no danger with this. However, imagine this:-

Public Class Test
    Private lstNumbers As New List(Of Integer)
 
    Public Sub Method2()
 
        For i = 1 To 100
            lstNumbers.Add(CStr(lstNumbers.Count))
        Next
 
    End Sub
 
 
End Class

Now there is a real problem when calling the above Method2 more than once from different threads. This is because these different instances of the running Method2 would be accessing the same list and there is a danger both threads access the list at the same time. The solution would be to synchronize access to the list like this:-

Public Class Test
    Private lstNumbers As New List(Of Integer)
 
    Public Sub Method2()
 
        For i = 1 To 100
            SyncLock lstNumbers
                lstNumbers.Add(CStr(lstNumbers.Count))
            End SyncLock
        Next
 
    End Sub
 
 
End Class

SyncLock would block if it was called on the same object, in this case lstNumbers, on another thread. When that other thread passes its End SyncLock then the blocked thread would be allowed to proceed and other calls to SyncLock on lstNumbers from other threads would be blocked in the same manner until it reaches its End SyncLock.

[psoftware]

You're the best vb.net programmer I've never seen... How can I say a big thank you?? Thanks to you I managed to fix issues that plagued me for months!!

[Niya]

Oh its no problem my friend

[Seventje]

Hi!

First of all, thanks for the great tutorial, it's been very very instructive.
And now the question, what would be the procedure to use two buttons and two labels that do the same thing, or in my application they would need both differnt inputs from my I/O system? (I'm quite a newbie to this so maybe it's a stuipid question)

Thanks !

[Niya]

Tell me more about what you want to do with the I/O system.

[Seventje]

Basicly I want to read inputs from it ("start"), next I would activate outputs to activate relays and put tension on my testprobe, next would be to test the output of the testprobe with analog input channels.

[Niya]

Ok, I don't really know too much about relays and test probes but if I understand correctly, these things you speak are I/O devices and you want to process input on one thread and output on another....is this correct ?

[Seventje]

No, I want to use two or more threads that execute the same code but use differnt inputs/outputs, thats why I would need more than one variable in those threads, for example:

if input(nc) = 1 then
activate output0(nc)
end if

Thread number one would use input 0 and thread number two would use input 8, trough the nc variable, same with the output.
Maybe I'm just talking weird, sorry if I am

[Niya]

Oh I see, the real problem is that you want to run the same method on different threads with different parameters. Well in the most basic cases you don't have to do anything special, you can just call the same method more than once each time on a different thread. However, if there is some kind of interaction between them or they are accessing the same resource then we have to cater to it.

Now, what approach are you taking to want to take with this. In this thread I show two forms of doing straight threaded coding. The first one where I show how to simply execute methods from a Form on different thread and the second way was to make a class with asynchronous methods and events that are raised on the UI thread. Which way are you thinking of ?

[Seventje]

I would need the second way is that I would need 2 variables for each thread, the number of thread (nc in the example above) and it's "place", since I've been teached to make a process that's secuencial with select case, each thread would be in another step of the process. For example, the fist thread is still on case number 10 and the second thread on case number 35. Is there some other way to make the same thing but easier?

And to not complicate things much, yes, they access the same resource, I'm thinking of making some sort of buffer to execute them.

Thanks

[Niya]

Ok....I think I kinda get what you're saying now....lets see what you have so far and how we can thread it.

[Seventje]

For now I got the following:

Public Class Counter
Private context As Threading.SynchronizationContext = Threading.SynchronizationContext.Current

Public Event CountChanged As EventHandler(Of CountChangedEventArgs)
Protected Overridable Sub OnCountChanged(ByVal e As CountChangedEventArgs)
RaiseEvent CountChanged(Me, e)
End Sub

Public Sub CountAsync(ByVal paso As Integer)
ThreadExtensions.QueueUserWorkItem(New Func(Of Integer, String)(AddressOf Count), paso)
End Sub
Public Sub CountAsync2(ByVal paso As Integer)
ThreadExtensions.QueueUserWorkItem(New Func(Of Integer, String)(AddressOf Count), paso)
End Sub
Public Function Count(ByVal paso As Integer) As String
' Dim startTime As DateTime = DateTime.Now
Dim e As CountChangedEventArgs

For i = 0 To paso
e = New CountChangedEventArgs(i, paso)
Select Case i
Case 0
If context Is Nothing Then
OnCountChanged(e)
Else
ThreadExtensions.ScSend(context, New Action(Of CountChangedEventArgs)(AddressOf OnCountChanged), e)
End If
Threading.Thread.Sleep(2000)
Case 2

If context Is Nothing Then
OnCountChanged(e)
Else
ThreadExtensions.ScSend(context, New Action(Of CountChangedEventArgs)(AddressOf OnCountChanged), e)
End If
Threading.Thread.Sleep(200)
End Select
Next

' Return "Count took : " + (DateTime.Now - startTime).ToString
End Function
End Class

Public Class CountChangedEventArgs
Inherits EventArgs

Private _NumeroThread As Integer
Private _Paso As Integer

Public Sub New(ByVal nc As Integer, ByVal paso As Integer)
_NumeroThread = nc
_Paso = paso
End Sub
Public ReadOnly Property NumeroThread() As Integer
Get
Return _NumeroThread
End Get
End Property
Public ReadOnly Property Paso() As Integer
Get
Return _Paso
End Get
End Property
End Class


Public Class ThreadExtensions
Private args() As Object
Private DelegateToInvoke As [Delegate]

Public Shared Function QueueUserWorkItem(ByVal method As [Delegate], ByVal ParamArray args() As Object) As Boolean
Return Threading.ThreadPool.QueueUserWorkItem(AddressOf ProperDelegate, New ThreadExtensions With {.args = args, .DelegateToInvoke = method})
End Function

Public Shared Sub ScSend(ByVal sc As Threading.SynchronizationContext, ByVal del As [Delegate], ByVal ParamArray args() As Object)
sc.Send(New Threading.SendOrPostCallback(AddressOf ProperDelegate), New ThreadExtensions With {.args = args, .DelegateToInvoke = del})
End Sub

Private Shared Sub ProperDelegate(ByVal state As Object)
Dim sd As ThreadExtensions = DirectCast(state, ThreadExtensions)

sd.DelegateToInvoke.DynamicInvoke(sd.args)
End Sub
End Class

Public Class Form1

Private WithEvents m_cn As New Counter

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
m_cn.CountAsync(20)
End Sub
Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
m_cn.CountAsync2(30)
End Sub

Private Sub m_cn_CountChanged(ByVal sender As Object, ByVal e As CountChangedEventArgs) Handles m_cn.CountChanged
Label1.Text = CStr(e.NumeroThread)
Label2.Text = CStr(e.NumeroThread)
End Sub
End Class

I have no idea how to do the same thing with two threads. Thanks in advance !

[Niya]

Why do you have two asynchronous Count methods ? You do realize you can have one and call it as many times as you want right ? And each one will execute on a separate thread. I don't really see much of a problem here. You have to remember that an executing method is actually an executing instance of a method.

[SNiiP3R]

Hi,

I have a question. The following Sub from your tutorial takes an address of the Count function with the 'String' as the return type.

    Public Sub CountAsync(ByVal Max As Integer)
        ThreadExtensions.QueueUserWorkItem(New Func(Of Integer, String)(AddressOf Count), Max)
    End Sub

My question is, is there anyway I can change the code so that it would work with Subs instead of Functions. Since my Connect Sub does not return anything, I don't need it to be a Function ? So, what I mean is the following:

    Public Sub ConnectAsync(ByVal IP As String, ByVal Port As Integer)
        ThreadExtensions.QueueUserWorkItem(New Func(Of String, Integer)(AddressOf Connect), IP, Port)
    End Sub

    Public Sub Connect(ByVal IP As String, Port As Integer)
        'Some code here
    End Sub

I have tried something like 'New Sub()' but that obviously did not work.


Thank you

[SNiiP3R]

Okay, I figured it out. Please ignore my previous post.

Apparently, when we're dealing with Subs that don't return anything we have to use New Action(). So the above Sub would look something like this,

    Public Sub ConnectAsync(ByVal IP As String, ByVal Port As Integer)
        ThreadExtensions.QueueUserWorkItem(New Action(Of String, Integer)(AddressOf Connect), IP, Port)
    End Sub

I'm still however, not too sure what to do with Subs that have no parameters ? For example,

    Public Sub Disconnect()
        ThreadExtensions.QueueUserWorkItem()
    End Sub

    Private Sub sockDisconnect()

    End Sub

New Action() in this case is not working for some reason.

[Niya]

Use the non generic Action delegate type.

'
    Public Sub Disconnect()
        ThreadExtensions.QueueUserWorkItem(New Action(AddressOf sockDisconnect))
    End Sub

[soviet87]

Niya, I really have to say, by far this is the-best breakdown I have ever seen of multithreading for vb.net. I was having so much issues trying to figure this out for my self. You put this in plain,easy to follow language. I am forever great-full! As you can see it is 5:30AM and I have not been to sleep and I felt the need to register for the forums just to tell you this, thank you very much.

[Niya]

Thank you friend....I'm glad it helped you

I thought it might be helpful to try and explain it in the way I would have liked someone to explain it to me when I didn't know how to do it. I seemed to have hit the mark Thx

[DaleAlanB]

Niya, Thank you for providing these examples. I don't know if your still following this thread (as the last post was almost 4 months ago). However in case you are, would you be so kind as to provide an identical example of your count program without utilizing your ThreadExtensions routine. I'm using VB2005 and it will not resolve some of the 'With' instructions you used in the routine. And please don't tell me to upgrade, there are reasons why I'm using VB2005 and .net framework 2.0, which I won't discuss as it is off topic. Threading is a something I haven't had a need to code until now - so I'm new at it. Any help would be appreciated.

What I'm trying to do is to create a second thread that runs continuously in an endless loop. The code in the loop will read about a dozen Boolean values set from the UI thread, and send them out through the serial port to another device (PLC), then turn around and read some other data back from the serial port. Once the data is read back, it is unpacked and then checked to see if any values have changed since the last read. If so, I want to raise a 'status change' event on the UI thread and pass to the event what changed (which class instance) and the new property value (which can be set from either thread). After raising the event (if necessary), the thread will loop back to the beginning and start the communications again (a monitor program). The UI thread will respond to the event and update the screen accordingly. I have the communications part working. I'm trying to work out the threading - your count program pretty much has the functions I need - only I'm unable to use parts of the ThreadExtensions routine as they will not resolve in VB2005. How else can I do this?

Thanks.

[Niya]

Use this one:-

Public Class ThreadExtensions
    Private args() As Object
    Private DelegateToInvoke As [Delegate]
 
    Private Sub New(ByVal delegateArgs As Object(), ByVal delegateInstance As [Delegate])
        Me.args = delegateArgs
        Me.DelegateToInvoke = delegateInstance
    End Sub
 
    Public Shared Function QueueUserWorkItem(ByVal method As [Delegate], ByVal ParamArray args() As Object) As Boolean
        Return Threading.ThreadPool.QueueUserWorkItem(AddressOf ProperDelegate, New ThreadExtensions(args, method))
    End Function
 
    Public Shared Sub ScSend(ByVal sc As Threading.SynchronizationContext, ByVal del As [Delegate], ByVal ParamArray args() As Object)
        sc.Send(New Threading.SendOrPostCallback(AddressOf ProperDelegate), New ThreadExtensions(args, del))
    End Sub
 
    Private Shared Sub ProperDelegate(ByVal state As Object)
        Dim sd As ThreadExtensions = DirectCast(state, ThreadExtensions)
 
        sd.DelegateToInvoke.DynamicInvoke(sd.args)
    End Sub
End Class

[DaleAlanB]

Thanks a bunch Niya. That works perfectly in VB2005.

Dale

[hondatron]

Hi Niya.
i have a small question! Can help me.
example: i have a url: (http://mangafox.me/manga/kingdom_hea...04/c030/1.html). And i wana get comic pictures in this page. Specifically, Downloading 3-4 or more pages in same time to speed up load.
only way I solved my problem.

[Niya]

In the section where I show how to do multi-threaded classes, I made a class that executed the count on a non-UI thread. In your case you would have a your download method instead of a count. You simply instantiate multiple classes to perform multiple downloads.

[hondatron]

thanks Niya.