[RESOLVED] close button

[hooman59]

Hi friends

I have a question about these 3 buttons(min,max,close) on the top corner of form; how can I have only min button available without close button.
(the exit button that I ve on my form is not only ,unload me, or ,end , it does some other things before exit so I cant use X button)

thank you in advance

[Nightwalker83]

Try this:

Option Explicit
 
Private Declare Function GetSystemMenu Lib "user32" _
    (ByVal hwnd As Long, _
     ByVal bRevert As Long) As Long
 
Private Declare Function RemoveMenu Lib "user32" _
    (ByVal hMenu As Long, _
     ByVal nPosition As Long, _
     ByVal wFlags As Long) As Long
     
Private Const MF_BYPOSITION = &H400&
Private Sub Form_Load()
DisableCloseButton Me
End Sub
Public Function DisableCloseButton(frm As Form) As Boolean
 
'PURPOSE: Removes X button from a form
'EXAMPLE: DisableCloseButton Me
'RETURNS: True if successful, false otherwise
'NOTES:   Also removes Exit Item from
'         Control Box Menu
 
 
    Dim lHndSysMenu As Long
    Dim lAns1 As Long, lAns2 As Long
    
    
    lHndSysMenu = GetSystemMenu(frm.hwnd, 0)
 
    'remove close button
    lAns1 = RemoveMenu(lHndSysMenu, 6, MF_BYPOSITION)
 
   'Remove seperator bar
    lAns2 = RemoveMenu(lHndSysMenu, 5, MF_BYPOSITION)
    
    'Return True if both calls were successful
    DisableCloseButton = (lAns1 <> 0 And lAns2 <> 0)
 
End Function

[dilettante]

It might be much cleaner to just move this blob of logic to Form_Unload and change your button event to Unload Me.

This should solve the problem without the need for any foreign UI hacking that just adds confusion for users.

[hooman59]

thank u for help,solved now

[Chris-Mario]

I know this thread is marked as [Solved] but here's another thing you could have done/can do:
Put everything you need to be done before the program ends into

Private Sub Form_QueryUnload()
 
    ' Your Code Here! :]
 
End Sub