[RESOLVED] Bring MessageBox to Front

[krtxmrtz]

I'm using this code to load data from a file by dragging the file icon on to the app's main form:

Private Sub Form_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, X As Single, Y As Single)
 
    If Data.Files.Count > 1 Then
        MsgBox "Only one file can be loaded"
        Exit Sub
    End If
    
    TextFile = Data.Files(1)
    'Now the string variable TextFile has the path to the file name
    'to be read and processed
    '...
    '...some other stuff here to do the job...
 
End Sub

The inconvenient is the msgbox appears on the background and is not visible if some other window is covering it so the user is not even aware he/she's being prompted for action. How do I bring the msgbox on top?

[Spoo]

Krtx

My understanding is that MsgBox is modal .. ie, always on top.

This "other" window you are referring to .. is it from your app
or could it be from some other app?

Spoo

[krtxmrtz]

...
This "other" window you are referring to .. is it from your app
or could it be from some other app?

Spoo

It's not from my app, of course. It's an open folder from Windows Explorer.

[RhinoBull]

Try forcing your main form to forground first and then check for file count.

[krtxmrtz]

Try forcing your main form to forground first and then check for file count.

It worked, thank you!

[krtxmrtz]

It worked, thank you!

As a matter of fact I was a bit to hasty to answer, the thing is it worked the first time but then it has since failed.

When I start the app I then open a folder to pick a file to drag. I think the problem is the app form should get the focus back, not (just?) get topmost state.

[RhinoBull]

How did you implement it?

[krtxmrtz]

How did you implement it?

'In a module:
Private Declare Function SetWindowPos Lib "user32" (ByVal hWnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOSIZE = &H1
Private Const SWP_SHOWWINDOW = &H40
Private Const SWP_NOActivate = &H10
Public Enum WindowPos
    vbtopmost = -1&
    vbnottopmost = -2&
End Enum
 
Public Sub SetFormPosition(hWnd As Long, Position As WindowPos)
    Const wFlags As Long = SWP_NOMOVE Or SWP_NOSIZE Or SWP_SHOWWINDOW Or SWP_NOActivate
    
    If Position = vbtopmost Or Position = vbnottopmost Then
        SetWindowPos hWnd, Position, 0, 0, 0, 0, wFlags
    End If
    
End Sub
 
'In the main form:
Private Sub Form_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, x As Single, y As Single)
    
    SetFormPosition Me.hWnd, vbtopmost
    
    If Data.Files.Count > 1 Then
        MsgBox "Only one file can be loaded", vbOKOnly, "Notice"
        Exit Sub
    End If
    
    TextFile = Data.Files(1)
    LoadImage
    
End Sub

[RhinoBull]

Try using SetForegroundWindow api without any checking.

Private Declare Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Long

'...

Private Sub Form_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, x As Single, y As Single)
    
    SetForegroundWindow Me.hWnd
    
    If Data.Files.Count > 1 Then
        MsgBox "Only one file can be loaded", vbOKOnly, "Notice"
        Exit Sub
    End If
    
    TextFile = Data.Files(1)
    LoadImage
    
End Sub

[krtxmrtz]

Try using SetForegroundWindow api without any checking...

Works fine and steadily in time.

Thanks again.

[RhinoBull]

Thanks for the feedback.