Sumproduct with LINQ

[RK62]

Can I calculate sumproduct by applying LINQ to List collection?

For example, if I have a list of my custom object with four items as:
Value Percentage Category
1000 6,0% A
3000 5,0% B
2000 7,0% A
4000 5,5% B

How to return the weighted Percentage for each category with LINQ? Weight is the Value.

[.paul.]

do you mean like this:

Public Class Form1
 
    Dim myList As New List(Of customObject)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New customObject(1000, 6D, "A"))
        myList.Add(New customObject(3000, 5D, "B"))
        myList.Add(New customObject(2000, 7D, "A"))
        myList.Add(New customObject(4000, 5.5D, "B"))
 
        Dim groups = (From co In myList _
                     Group co By category = co.Category Into Group _
                     Select New With { _
                     .Category = category, _
                     .weightSum = Group.Sum(Function(g) g.Value), _
                     .percentageSum = Group.Sum(Function(g) g.Percentage)} _
                     ).ToList
 
    End Sub
End Class

Public Class customObject
    Public Value As Integer
    Public Percentage As Decimal
    Public Category As String
 
    Public Sub New(ByVal Value As Integer, ByVal Percentage As Decimal, ByVal Category As String)
        Me.Value = Value
        Me.Percentage = Percentage
        Me.Category = Category
    End Sub
 
End Class

[.paul.]

or did you mean this?:

Public Class Form1
 
    Dim myList As New List(Of customObject)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New customObject(1000, 6D, "A"))
        myList.Add(New customObject(3000, 5D, "B"))
        myList.Add(New customObject(2000, 7D, "A"))
        myList.Add(New customObject(4000, 5.5D, "B"))
 
        Dim groups = From co In myList _
                     Select New With { _
                     .Category = co.Category, _
                     .Product = co.Value * (co.Percentage / 100)}
 
        Dim groupSums = (From g In groups _
                         Group g By category = g.Category Into Group _
                         Select New With { _
                         .Category = category, _
                         .productSum = Group.Sum(Function(g) g.Product)} _
                         ).ToList
 
    End Sub
End Class

[RK62]

or did you mean this?:

Public Class Form1
 
    Dim myList As New List(Of customObject)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New customObject(1000, 6D, "A"))
        myList.Add(New customObject(3000, 5D, "B"))
        myList.Add(New customObject(2000, 7D, "A"))
        myList.Add(New customObject(4000, 5.5D, "B"))
 
        Dim groups = From co In myList _
                     Select New With { _
                     .Category = co.Category, _
                     .Product = co.Value * (co.Percentage / 100)}
 
        Dim groupSums = (From g In groups _
                         Group g By category = g.Category Into Group _
                         Select New With { _
                         .Category = category, _
                         .productSum = Group.Sum(Function(g) g.Product)} _
                         ).ToList
 
    End Sub
End Class

This one seems to get it right.
How would that be extended to divide the productSum with each category's total value (to get the weighted Percentage) ?

So with the above we get:
Category productSum
A 200
B 370

I would further need to get:
Category WeightedPercentage
A 0.0666667 -> (i.e. 200 divided by 3000)
B 0.0528571 -> (i.e. 370 divided by 7000)

[.paul.]

try this:

Public Class Form1
    Dim myList As New List(Of customObject)
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New customObject(1000, 6D, "A"))
        myList.Add(New customObject(3000, 5D, "B"))
        myList.Add(New customObject(2000, 7D, "A"))
        myList.Add(New customObject(4000, 5.5D, "B"))
        Dim groups = From co In myList _
        Select New With { _
        .Category = co.Category, _
        .Product = co.Value * (co.Percentage / 100), _
        .Value = co.Value}
 
        Dim groupSums = (From g In groups _
        Group g By category = g.Category Into Group _
        Select New With { _
        .Category = category, _
        .productSum = Group.Sum(Function(g) g.Product), _
        .WeightedPercentage = .productSum / Group.Sum(Function(g) g.Value)} _
        ).ToList
        
    End Sub
End Class
 
Public Class customObject
    Public Value As Integer
    Public Percentage As Decimal
    Public Category As String
 
    Public Sub New(ByVal Value As Integer, ByVal Percentage As Decimal, ByVal Category As String)
        Me.Value = Value
        Me.Percentage = Percentage
        Me.Category = Category
    End Sub
 
End Class

[RK62]

try this:

Public Class Form1
    Dim myList As New List(Of customObject)
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New customObject(1000, 6D, "A"))
        myList.Add(New customObject(3000, 5D, "B"))
        myList.Add(New customObject(2000, 7D, "A"))
        myList.Add(New customObject(4000, 5.5D, "B"))
        Dim groups = From co In myList _
        Select New With { _
        .Category = co.Category, _
        .Product = co.Value * (co.Percentage / 100), _
        .Value = co.Value}
 
        Dim groupSums = (From g In groups _
        Group g By category = g.Category Into Group _
        Select New With { _
        .Category = category, _
        .productSum = Group.Sum(Function(g) g.Product), _
        .WeightedPercentage = .productSum / Group.Sum(Function(g) g.Value)} _
        ).ToList
        
    End Sub
End Class
 
Public Class customObject
    Public Value As Integer
    Public Percentage As Decimal
    Public Category As String
 
    Public Sub New(ByVal Value As Integer, ByVal Percentage As Decimal, ByVal Category As String)
        Me.Value = Value
        Me.Percentage = Percentage
        Me.Category = Category
    End Sub
 
End Class

Perfect! Thank you.