[RESOLVED] Check if form has been loaded already

[krtxmrtz]

My application starts with Form1 and then at some point the user can click a button to load Form2 and do some job. When done, Form2 is hidden, not unloaded.

I want to test at a specific place in Form1 whether Form2 has already been loaded (and hidden) or not.

[LaVolpe]

If you only have 2 forms, check the Forms.Count property. If that returns 2, then check Form2.Visible. But don't check .Visible first else you'll load the form if it wasn't already loaded.

[Magic Ink]

Try this;

Private Sub Command1_Click()
    
    Form2.Show
        
End Sub

Function IsForm2Loaded(Visible As Boolean) As Boolean

    Dim Fm As Form
    
    For Each Fm In Forms()
        If Fm.Name = "Form2" Then
            IsForm2Loaded = True
            If Fm.Visible Then
                Visible = True
            End If
            Exit Function
        End If
    Next

End Function

Private Sub Command2_Click()
        
    Dim Visible As Boolean
        
    If IsForm2Loaded(Visible) Then
        MsgBox "Form2 is Loaded and " & IIf(Visible, "Visible", "Hidden")
    Else
        MsgBox "Form2 is not Loaded"
    End If

End Sub

[krtxmrtz]

If you only have 2 forms, check the Forms.Count property. If that returns 2, then check Form2.Visible. But don't check .Visible first else you'll load the form if it wasn't already loaded.

Indeed, there are only 2 forms. Form2 is loaded in modal mode and I don't need to check for visibility.

Thanks.

[krtxmrtz]

It works fine. Thank you!

Try this;...

[krtxmrtz]

It works fine. Thank you!

As a matter of fact I answered too fast and overlooked the fact you're not passing the forms's name as parameter. In the example I proposed it was Form2 but in general I'd like to check for any specific form.

The problem I ran into with other code I found in the forums is the form gets automatically loaded the moment its name is encountered.

[Magic Ink]

>you're not passing the forms's name as parameter

I'll leave that to you ...

[krtxmrtz]

>you're not passing the forms's name as parameter

I'll leave that to you ...

All right so I'll keep asking for help.

Is there any way then to retrieve and assign all the project's form names to string variables without having them load at the same time?

[westconn1]

Is there any way then to retrieve and assign all the project's form names to string variables without having them load at the same time?

not dynamically, that can only be done with forms that are already loaded

[DataMiser]

You could read them from your vbp file then save them to a txt file that would be included with the program and read them from there into your variables at launch.

[Spoo]

Krtx

Picking up on DataMiser's idea, as an alternative, you
could read the .vbw file .. it is even shorter.

Spoo

[DataMiser]

The only problem with reading from the vbw is that you may not be able to tell forms from modules from classes depending on your naming conventions.

The vbp file shows you which are forms making it very easy to grap them all with a few lines of code.

Example vbw

frmLogin = 44, 44, 579, 488, , 22, 22, 557, 466, C
mdiMain = -139, 85, 396, 529, , 44, 44, 579, 488, C
modLOtimer = 0, 0, 535, 444,

Example vbp

Form=frmLogin.frm
Form=mdiMain.frm
Module=modLOtimer; modLOtimer.bas

[Code Doc]

I used to write programs with several forms. I generally tracked them being loaded by establishing a global boolean array variable. During the Form Load event, I set it to True. Then I set it to False when the form was unloaded. That worked for me, but I often wished there was a simpler procedure.

[Spoo]

DataMiser

You are absolutely correct .. the unspoken implication
of my vbw suggestion was the very naming convention
issue that you mention.

Clearly, the vbp's Form= prefix makes it a snap, even
if there are a few more lines in that file to read.

BTW, do you have any idea what the parameters in the
vbw file refer to?

Spoo

[Spoo]

Doc

Your "brute force" approach may be the easiest and hence
the most elegant afterall.

Spoo

[dw85745]

I'm with Code Doc on this one.
I also use an array to track which forms are loaded.

[DataMiser]

BTW, do you have any idea what the parameters in the
vbw file refer to?

Spoo

No idea at all, I was wondering the same thing.

btw as to the topic at hand there is a very easy way to find out which forms are currently loaded.

Dim f As Form
For Each f In Forms
    Debug.Print f.Name
Next

[krtxmrtz]

Both parsing the vbp file at program start and CodeDoc's suggestion seem reasonable and easy enough. Offhand I don't see which is more convenient, maybe I'll implement both and see which one I'm happier with.

Thanks to all of you folks.

[krtxmrtz]

...

Dim f As Form
For Each f In Forms
    Debug.Print f.Name
Next

Doesn't that load the forms?

[krtxmrtz]

You could read them from your vbp file then save them to a txt file that would be included with the program and read them from there into your variables at launch.

I suppose there's no need to save them to a text file. After they've been read from the vbp file you simply store them in an array.

[Magic Ink]

>Doesn't that load the forms?

It does not because the Forms Collection only includes the Loaded Forms.

[krtxmrtz]

>Doesn't that load the forms?

It does not because the Forms Collection only includes the Loaded Forms.

I see...

So, working on your idea I finally have used this code:

'Array of currently loaded forms
Dim ldForms() As String
Private Sub Form_Click()
    Dim i As Integer
    Dim f As Form
    
    'Assign names of loaded forms to array
    i = 0
    For Each f In Forms
        ReDim Preserve ldForms(i)
        ldForms(i) = f.Name
        i = i + 1
    Next
    
    'Check the code
    For i = 0 To UBound(ldForms)
        Debug.Print ldForms(i)
    Next
    
End Sub

Also, I have implemented the vbp file parsing option which provides all the projet's form names like this:

Private Sub GetFormsNames()
    Dim ff As Integer, i As Integer
    Dim s As String
    
    i = 0
    ff = FreeFile
    Open App.Path & "\" & App.Title & ".vbp" For Input As #ff
        Do
            Line Input #ff, s
            If Left(s, 5) = "Form=" Then
                ReDim Preserve pfNames(i)
                pfNames(i) = Mid(s, 6)
                i = i + 1
            End If
        Loop While Not EOF(ff)
    Close #ff
    
End Sub

where pfNames has been declared elsewhere (possibly as public in a module):
Public pfNames() As String

and then you'd have to check the array to find out which forms are loaded.

Summing up, it's obvious that your solution is by far the easiest and most convenient, (hats off to you)

[DataMiser]

I suppose there's no need to save them to a text file. After they've been read from the vbp file you simply store them in an array.

The reason I suggested saving them to a text file is that you could include them with the program when you ship it. Of course if the program is only going to be ran where the source code is located then the vbp would be fine but if it is to be distributed most people would not want to include any of the source files.

[krtxmrtz]

The reason I suggested saving them to a text file is that you could include them with the program when you ship it. Of course if the program is only going to be ran where the source code is located then the vbp would be fine but if it is to be distributed most people would not want to include any of the source files.

You're quite right, I didn't think of that.
So before distributing you could even create and edit the text file manually -unless the number of forms is so large that makes it worth parsing the vbp file.

[Magic Ink]

Pehaps I'm missing something but just what is the point of including the vbp file or a text file including the Form names within it. Surely if all the Form names are known at design time then you can hard code them and built an array/ list if you must; there is little point complicating things by importing static data from an external file.

[DataMiser]

It would depend on the project and the number of forms. You could hard code them into the project by hand and go back and make changes as needed. You could write a little utility that would create the text file at any time with only a few lines of code. Then add a function to your program that could read the file. You could create a little utility that would create the code for hard coding at the click of a button then paste that into your project.

IMO hard coding by hand would make sense only if it were a small project and you do not plan to do this with other projects in the future, otherwise it makes sense to do it with a few lines of code that you can use over and over as needed.

Maybe I'm just lazy but that is what I would do