[RESOLVED] From String?

[i00]

Just wondering how to create my own custom property that is an object but that allows a string to be passed in to the property grid to configure it...

For example, with a font type property you can type "Microsoft Sans Serif, 18pt" into the property grid and it will create the appropriate font structure and fill it.

Thanks in advance
Kris

[.paul.]

here's an example of expandable properties:

http://code.msdn.microsoft.com/count...ntrol-2da92ac3

[i00]

I know how to create expandable properties ... And I don't want this property in question to be expandable ... I want to be able to put in something as a string ... and it creates an object based on that string... color for eg is not expandable and you can put text into it and it converts it to the corresponding filled structure.

Thanks
Kris

[MarMan]

Does the object support creating with a string? Does it have a constructor that accepts a string? If not then you you will need to code that yourself and only you know what rules you would be inventing.

[.paul.]

here's how:

Imports System.ComponentModel
 
Public Class UserControl1
 
    Private _color As Color
    <TypeConverter(GetType(colorConverter))> _
    Public Property Color() As Color
        Get
            Return _color
        End Get
        Set(ByVal value As Color)
            _color = value
        End Set
    End Property
 
End Class

uses a typeconverter class:

Imports System.ComponentModel
 
Public Class colorConverter
    Inherits TypeConverter
 
    Public Overrides Function CanConvertFrom(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal sourceType As System.Type) As Boolean
        Return sourceType Is GetType(String)
    End Function
 
    Public Overrides Function ConvertFrom(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal culture As System.Globalization.CultureInfo, ByVal value As Object) As Object
        If TypeOf value Is String Then
            Return Color.FromName(value.ToString)
        End If
        Return MyBase.ConvertFrom(context, culture, value)
    End Function
 
    Public Overrides Function CanConvertTo(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal destinationType As System.Type) As Boolean
        Return destinationType Is GetType(Color)
    End Function
 
    Public Overrides Function ConvertTo(ByVal context As System.ComponentModel.ITypeDescriptorContext, ByVal culture As System.Globalization.CultureInfo, ByVal value As Object, ByVal destinationType As System.Type) As Object
        If TypeOf value Is Color Then
            Return DirectCast(value, Color).Name
        End If
        Return MyBase.ConvertTo(context, culture, value, destinationType)
    End Function
 
End Class

[i00]

Thanks ... just what i needed