[RESOLVED] Sub Or Function Not Defined

[Erricki]

Hy, everyone .I am trying to write a code for a puzzle game in VB 6 and i am getting the error "Sub or function not defined". This is my whole vb code for the game :

[Erricki]

Option Explicit
Dim puzzle0 As Integer
Dim puzzle1 As Integer
Dim puzzle2 As Integer
Dim puzzle3 As Integer
Dim puzzle4 As Integer
Dim puzzle5 As Integer
Dim puzzle6 As Integer
Dim puzzle7 As Integer
Dim puzzle8 As Integer
Dim puzzle9 As Integer
Dim puzzle10 As Integer
Dim puzzle11 As Integer
Dim puzzle12 As Integer
Dim puzzle13 As Integer
Dim puzzle14 As Integer
Dim puzzle15 As Integer
Dim puzzle16 As Integer
Dim puzzle17 As Integer
Dim puzzle18  As Integer
Dim puzzle19 As Integer
Dim puzzle20 As Integer
Dim puzzle21 As Integer
Dim puzzle22 As Integer
Dim puzzle23 As Integer
Dim puzzle24 As Integer
Dim puzzle25 As Integer
Dim puzzle26 As Integer
Dim puzzle27 As Integer
Dim puzzle28 As Integer
Dim puzzle29 As Integer
Dim puzzle30 As Integer
Dim puzzle31 As Integer
 
 
Private Sub cmdexit_Click()
End
End Sub
 
Private Sub cmdsolve_Click()
Solve
End Sub
 
Private Sub cmdstart_Click()
cmdstart.Enabled = False
cmdsolve.Enabled = True
Initialize_Puzzle
End Sub
 
Private Sub Form_Load()
cmdsolve.Enabled = False
Randomize
Solve
End Sub
 
Public Sub Initialize_Puzzle()
Dim X As Integer
Dim innerLoop As Integer
Dim liRandomIndex As Integer
Dim lbUsed As Boolean
Dim lbFoundDup As Boolean
For X = 0 To 31
    puzzle(X) = 99
Next X
For X = 0 To 31
    Picture1(X).Enabled = True
Next X
For X = 0 To 31
    Picture1(X).BackColor = vbBlue
Next X
For X = 0 To 31
    Picture2(X).Enabled = True
Next X
For X = 0 To 31
    Set Picture2(X).Picture = LoadPicture
Next X
For X = 0 To 31
    Picture2(X).BackColor = vbWhite
Next X
For X = 0 To 31
    lbUsed = True
    Do Until lbUsed = False
        liRandomIndex = Int(32 * Rnd)
        lbFoundDup = False
        For innerLoop = 0 To 31
            If puzzle(innerLoop) = liRandomIndex Then
                lbFoundDup = True
            End If
        Next innerLoop
        If lbFoundDup = False Then
            Picture1(X).Picture = PictureClip1.GraphicCell(liRandomIndex)
            puzzle(X) = liRandomIndex
            lbUsed = False
            Exit Do
        End If
    Loop
Next X
End Sub
 
Private Sub Picture2_DragDrop(Index As Integer, Source As Control, X As Single, Y As Single)
If Source.BackColor = vbBlack Or Source.BackColor = vbBlue Then
    If Picture2(Index).BackColor = vbBlack Then
        Exit Sub
    ElseIf Picture2(Index).BackColor = vbWhite Then
        Picture2(Index).Picture = Source.Picture
        Picture2(Index).BackColor = vbBlack
        Set Source.Picture = LoadPicture
        Source.BackColor = vbWhite
        Exit Sub
    End If
End If
 
If TypeOf Source Is PictureBox And Source.BackColor = vbBlue Then
    Picture2(Index).Picture = Source.Picture
    Set Source.Picture = LoadPicture
    Picture2(Index).BackColor = vbBlack
End IfEnd Sub
 
Private Sub Picture2_DragOver(Index As Integer, Source As Control, X As Single, Y As Single, State As Integer)
    Source.MousePointer = 0
End Sub
 
Public Sub Solve()
Dim X As Integer
cmdsolve.Enabled = False
For X = 0 To 31
    Picture1(X).Picture = PictureClip1.GraphicCell(X)
Next X
For X = 0 To 31
    Picture1(X).Enabled = False
Next X
For X = 0 To 31
    Picture2(X).Enabled = False
Next X
cmdstart.Enabled = True
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  cmdexit_Click
End Sub

[Erricki]

I am getting an error : "Sub or Function not defined" at the line : Public Sub Initialize_Puzzle()
and the line :
puzzle(X) = 99
is on a grey background ..
so what can I do , guys ?
thanks

[MartinLiss]

Where is puzzle Dim-ed?

[Erricki]

At the beginning , buddy , under Option Explicit ..

[MartinLiss]

Replace all those dims with
Dim puzzle(31) As Integer

or better

Private puzzle(31) As Integer

[Erricki]

Alright, it worked, passed from that at compiling, but I got another error at line :
Picture1(X).Picture = PictureClip1.GraphicCell(X)
the error is :
Method or data member not found .
thanks for helping

[MartinLiss]

Do you have a Picture1 control array on your form?

[Erricki]

yes, buddy , i can make an archive of the form and send you .

[MartinLiss]

Just attach the zip of your project to a post by using the 'Manage Attachments' you'll find under 'Additional Options' when you create the new post.

[Hack]

Split From An Old Thread Into Its Own Thread

Please do not piggy back questions onto other member's thread, even if you have the same question. Always create your own thread.

Thanks.

[Erricki]

alright, got it , thanks .

[Erricki]

buddy , i saw the problem ... I just had to insert once more the PictureClip and set the properties and it worked , thanks a lot ...

[MartinLiss]

BTW your Initialize_Puzzle routine can be reduced to this:

Public Sub Initialize_Puzzle()
Dim X As Integer
Dim innerLoop As Integer
Dim liRandomIndex As Integer
Dim lbUsed As Boolean
Dim lbFoundDup As Boolean
For X = 0 To 31
    puzzle(X) = 99
    Picture1(X).Enabled = True
    Picture1(X).BackColor = vbBlue
    Picture2(X).Enabled = True
    Set Picture2(X).Picture = LoadPicture
    Picture2(X).BackColor = vbWhite
    lbUsed = True
    Do Until lbUsed = False
        liRandomIndex = Int(32 * Rnd)
        lbFoundDup = False
        For innerLoop = 0 To 31
            If puzzle(innerLoop) = liRandomIndex Then
                lbFoundDup = True
            End If
        Next innerLoop
        If lbFoundDup = False Then
            Picture1(X).Picture = PictureClip1.GraphicCell(liRandomIndex)
            puzzle(X) = liRandomIndex
            lbUsed = False
            Exit Do
        End If
    Loop
Next X
End Sub

[MartinLiss]

You could also add this sub (from our CodeBank):

Public Sub ShuffleArray(pvarArray As Variant)
    Dim i As Long
    Dim iMin As Long
    Dim iMax As Long
    Dim lngReplace As Long
    Dim varSwap As Variant
    
    iMin = LBound(pvarArray)
    iMax = UBound(pvarArray)
    For i = iMax To iMin + 1 Step -1
        lngReplace = Int((i - iMin + 1) * Rnd + iMin)
        varSwap = pvarArray(i)
        pvarArray(i) = pvarArray(lngReplace)
        pvarArray(lngReplace) = varSwap
    Next
End Sub

and this code:

Public Sub Initialize_Puzzle()
Dim X As Integer
Dim innerLoop As Integer
Dim liRandomIndex As Integer
Dim lbUsed As Boolean
Dim lbFoundDup As Boolean
' Create an array filled with the numbers 0 to 31
Dim intRandom(31) As Integer
For X = 0 To 31
    intRandom(X) = X
Next
' Shuffle the array
ShuffleArray intRandom
' You can then do this without worrying about generating duplicate random numbers:
For X = 0 to 31
    puzzle(X) = intRandom(X)
'… the rest of the code in your Sub.

[Erricki]

Thanks .

[MartinLiss]

You're welcome and you may realize this already but you could put this under Option Explicit

Private intRandom(31) As Integer

and put this in Form_Load since it only has to be done once.

Dim X As Integer
For X = 0 To 31
intRandom(X) = X
Next