Get logged on user's full name from Active Directory

[chris128]

Here's an example of how you can retrieve a user's full name from Active Directory when you just have their username (which is all you can get via managed code - not even sure if there is any way to get their full name via Windows API without querying AD).

You need to add a reference to System.DirectoryServices before this will work.

'Import System.DirectoryServices at the top of your class
 
'-------------
'Function definition
Private Function GetRealNameFromAd(ByVal UsernameToFind As String) As String
        Using searcher As New DirectorySearcher(New DirectoryEntry())
            searcher.PageSize = 1000
            searcher.SearchScope = SearchScope.Subtree
            searcher.Filter = "(&(samAccountType=805306368)(sAMAccountName=" & UsernameToFind & "))"
            Using Results As SearchResultCollection = searcher.FindAll
                If Results Is Nothing OrElse Results.Count <> 1 Then
                    Throw New ApplicationException("Invalid number of results returned - either no users were found or more than one user account was found")
                End If
                Using UserDE As DirectoryEntry = Results(0).GetDirectoryEntry
                    Return CStr(UserDE.Properties("givenName").Value) & " " & CStr(UserDE.Properties("sn").Value)
                End Using
            End Using
        End Using
End Function
 
'--------------
'Example of using it:
Try
     MessageBox.Show("Real name for " & Environment.Username & " is " & GetRealNameFromAd(Environment.Username), "Real Name Found", MessageBoxButtons.OK, MessageBoxIcon.Information)
Catch ex As Exception
     MessageBox.Show("The following error was encountered during the Active Directory search: " & ex.Message, "Error During Search", MessageBoxButtons.OK, MessageBoxIcon.Error)
End Try