VBA Word table with bookmarks

[maxtin]

i have a vb6 application that want to write into a Word document. My document is a pre-saved template which has already a table (1 row 3 columns) created in it with a bookmark at the first cell...

my question is how do i iterate through the cells of my table from my bookmark and create a new row each time i iterate through all 3 cells of the current row.

i tried oDoc.bookmark("bookname").range.next but it only seems to work if i didnt insert any text in the cell before, other case, it doesnt iterate and write in the same cell

help please..this is very frustrating

[maxtin]

ok..update

found something to iterate ..works good but crash when it tries to create a new row

obWordApp.Bookmarks("bookname").Range.Cells(1).Select

obWordApp.Selection.Range.Cells(1).Range.Text = "cell1"
obWordApp.Selection.Range.Cells(1).Next.Select
obWordApp.Selection.Range.Cells(1).Range.Text = "cell2"
.
.
.

help!

[Comintern]

What I would do would be to grab a reference to the table from the bookmark. Since the bookmark is in the cell, the tables collection of it's range object will only have one table in it (the one that contains it). From there, instead of working with selections, just reference the table directly. This will be much easier to manipulate. Step through the example code below with the debugger and watch what happens in the Word window. Should be pretty easy to adapt to your needs.

Private Sub WordTableIE()
 
    Dim obWordApp As Word.Application, oDoc As Word.Document, oTable As Word.Table, lRow As Long, lCol As Long
    
    Set obWordApp = New Word.Application
    obWordApp.Visible = True
    
    'Open the document.
    Set oDoc = obWordApp.Documents.Open("D:\Template.doc")
    'Reference the table.
    Set oTable = oDoc.Bookmarks("bookname").Range.Tables(1)
 
    With oTable
        'Loop through all cells.
        For lRow = 1 To .Rows.Count
            For lCol = 1 To .Columns.Count
                'Write a value to the cell.
                .Cell(lRow, lCol).Range.Text = "Row" & lRow & ", Col" & lCol
            Next lCol
        Next lRow
        'Add a row.
        Call .Rows.Add
        'Find out what row number it is.
        lRow = .Rows.Count
        'Write some values.
        For lCol = 1 To .Columns.Count
            .Cell(lRow, lCol).Range.Text = "New Row, Cell" & lCol
        Next lCol
        'Etc.
    End With
    
    Set oTable = Nothing
    
    oDoc.Close (wdDoNotSaveChanges)
    obWordApp.Quit
    
    Set oDoc = Nothing
    Set obWordApp = Nothing
    
End Sub

[RobDog888]

For more info on Word Tables - http://vbforums.com/showthread.php?t=402098

By eliminating the selection object you are reducing the resources needed and increasing the stability of your macro. The Selection object is a visual physical selection which can be changed by a user making their own selection or messing up the macro by clicking and deselecting the selection causing it to become un-set.