-
Oct 14th, 2005, 10:50 AM
#1
Classic VB - How do I make properties?
You can make properties for the following things: Forms, UserControls and Class Modules. Basically any element that will behave as an object.
When to use properties?
Properties are handy when you want to generalize your code: if you're changing a setting of something, it might be better to create it as a property. Especially if you might have a need to get a return value as well. The property code can then do some additional stuff, such as switching form's menu items automatically to correct value, so you don't need to do it from whereever you set the property.
Property Get
Property Get is rather simple: it always returns a value.
VB Code:
' this could be in a usercontrol
Dim m_Caption As String
Public Property Get Caption() As String
Caption = m_Caption
End Property
After this you could call it like this from a form the usercontrol is placed on:
VB Code:
Me.Caption = UserControl1.Caption
You can also pass objects:
VB Code:
' again, in a usercontrol
Dim m_Picture As IPictureDisp
' reference to "Ole Automation" required! by default it is included
Public Property Get Picture() As IPictureDisp
Set Picture = m_Picture
End Property
In this case you would call it like this:
VB Code:
Set Me.Picture = UserControl.Picture
Property Let and Property Set
Property Let is used when you pass a variable. Set is used when you pass an object.
VB Code:
Dim m_Caption As String
Public Property Let Caption(ByVal NewCaption As String)
m_Caption = NewCaption
End Property
Usage:
VB Code:
UserControl1.Caption = "This is my control!"
VB Code:
Dim m_Picture As IPictureDisp
Public Property Set Caption(ByRef NewPicture As IPictureDisp)
Set m_Picture = NewPicture
End Property
Usage:
VB Code:
Set UserControl1.Picture = Picture1.Picture
Some notes about the examples
I kept the examples as clean as possible. For this reason, I didn't include additional coding that would redraw the usercontrol for example. Redrawing would be placed in the property handling as otherwise your control would never change. It is a good idea to make a general redrawing procedure within your usercontrol to keep it visually updated with ease.
The same applies for forms and class modules, though class modules aren't visible. You could use class modules with events though, so when a property gets changed, an event would fire:
VB Code:
' in a form
Dim WithEvents MyClass As clsMyClass
This, however, is out of our topic.
Adding it all up
- use a property instead of a sub or function if you need to also get the value
- use a sub if you just need to set something
- use a function if you need to set something and require a return value of the result (such as if the function succeeded)
- Property Get works with any data, be it a regular variable or an object
- Property Let is for regular variables
- Property Set is for objects
Comments and feedback
Send these via a private message; the replies in the FAQ forum can only contain new information regarding the subject. So any questions, thank yous etc. via a pm
Last edited by si_the_geek; Oct 14th, 2005 at 07:02 PM.
-
Oct 16th, 2005, 01:18 PM
#2
Re: Classic VB - How do I make properties?
You can also specify parameters for property methods.
A common example of this is when writing a collection class.
VB Code:
Property Get Item(ByVal Index As Long) As MyClassType
Set Item = BaseCollection(Index)
End Property
Property Set Item(ByVal Index As Long, ByRef pObject As MyClassType)
Set BaseCollection(Index) = pObject
End Property
The function signatures (type and number of arguments) for the Get and Set/Let methods must match, save for the additional final parameter on the Set/Let routine which is what is being assigned to the property.
As Merri mentioned, Property Set is called when you assign an object reference using the Set keyword. The object is passed by reference. Property Let is called when you assign a value type (Long, String etc.) optionally using the (deprecated) Let keyword, and it is passed by value.
So, you would use the above property Get/Set methods like this:
VB Code:
Dim AnObject As MyClassType
Set AnObject = MyCollectionClass.Item(5) ' Get
Set MyCollectionClass.Item(5) = AnObject ' Set
It works, but you may notice that the built-in VB Collection class has a slightly neater syntax:
VB Code:
Set AnObject = MyCollection(5)
To accomplish this, you need to set the Item property as the default method of your collection class. To do this, click anywhere in your procedure, and from the Tools menu, select Procedure Attributes. Click Advanced to expand the dialog, and from the Procedure ID dropdown, select (Default). This will enable the use of the shorthand syntax shown above.
Also, while you are in that dialog box you will see some other interesting options, which can be saved for another topic
-
Dec 4th, 2009, 10:49 AM
#3
Re: Classic VB - How do I make properties?
Another tidbit or two about properties.
In a usercontrol, if you want to persist the property, you should add the PropertyChanged method when the property changes. Of course you will need to cache the property in the usercontrol's WriteProperty event.
vb Code:
Dim m_Picture As IPictureDisp Public Property Set Picture(newPic As IPictureDisp) Set m_Picture = newPic PropertyChanged "Picture" End Property
Ever notice that you can assign an image to Picture property using the keyword Set and without using that keyword?
vb Code:
Set Me.Picture = LoadPicture(filename) Me.Picture = LoadPicture(filename)
Well if you code your custom "Picture" property with Let and your customer uses Set keyword, an error will occur. Likewise, if you code "Picture" with Set and your customer does not use the Set keyword, an error will occur.
By using both Let and Set, you can save your customers from those annoying errors. Though this example uses a picture object in the sample code, this same logic can be used for any properties that use Objects.
vb Code:
' coded within a class or usercontrol Dim m_Picture As IPictureDisp Public Property Get Picture() As IPictureDisp Set Picture = m_Picture End Property Public Property Set Picture(newImage As IPictureDisp) Set m_Picture = newImage ' do other things as needed, like redrawing after image changed, validating, etc End Property Public Property Let Picture(newImage As IPictureDisp) Set Me.Picture = newImage ' re-route the Let call to our Set call End Property
Last edited by LaVolpe; Dec 4th, 2009 at 11:27 AM.
Reason: correct couple of typos
Posting Permissions
- You may not post new threads
- You may not post replies
- You may not post attachments
- You may not edit your posts
-
Forum Rules
|
Click Here to Expand Forum to Full Width
|