Advanced VB/Office Guru™ Word SpellChecker™.NET

[RobDog888]

Yes an no. You need to have separate compiles for each of the Office versions you are going to support which will include changing your references etc and recompiling. There is no issue for Vista with this, only other issues like security, virtualizations and the UAC. All of which are unrelated to the PIAs and Office.

[nbrege]

RD ... can you post some instructions on how to implement your class into an existing project? Here's what I tried: I created a new module, then I pasted your class into that module. In my main code I tried to call the SpellMe function, but it's telling me that "SpellMe" is not declared.

[vbheadache]

Hi guys, i really hope this thread is still active, anyway...


This post is fantasic and the spellcheck works great. But it i need it to do just one little thing extra. I really hope you can help

Is it possible to specify where the Spelling options dialog will appear on the screen? At the moment it just deafults to the center of the screen but im using a multi headed system and so want the Spelling dialog to appear on a second screen.

When modifing the preferences...

'<PREP CHECK SPELLING OPTIONS DIALOG BOX (MODIFY TO YOUR PREFERENCES)>                
moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.CheckGrammarWithSpelling = True

is it possible to modify the dialogs position if so how?

Kind regards

[Xancholy]

RobDogg - great stuff. Has there been an 2008 update ?

What happens if the end user does not have MS-Office installed ?

[RobDog888]

Thanks

Well this is setup with early binding but since its .NET you can include the PIAs to avoid that but you could also just change the code to Late binding and its already set to use a Try Catch for the existance of Word and message if they dont have it installed.

[RobDog888]

Hi guys, i really hope this thread is still active, anyway...


This post is fantasic and the spellcheck works great. But it i need it to do just one little thing extra. I really hope you can help

Is it possible to specify where the Spelling options dialog will appear on the screen? At the moment it just deafults to the center of the screen but im using a multi headed system and so want the Spelling dialog to appear on a second screen.

When modifing the preferences...

'<PREP CHECK SPELLING OPTIONS DIALOG BOX (MODIFY TO YOUR PREFERENCES)>                
moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.CheckGrammarWithSpelling = True

is it possible to modify the dialogs position if so how?

Kind regards

There is no built in abilities in Word to position the dialog so you may be able to subclass the dialog creation using Moeurs C++ dll and reposition it by changing its windowsplacement at that time.

[RobDog888]

RD ... can you post some instructions on how to implement your class into an existing project? Here's what I tried: I created a new module, then I pasted your class into that module. In my main code I tried to call the SpellMe function, but it's telling me that "SpellMe" is not declared.

Just copy and paste all the code into a blank new class. If you look at my code you can see its a class and already named etc.

[RobDog888]

RobDogg - great stuff. Has there been an 2008 update ? ...

I suposse its time for an update/improvement. I have a few ideas on this but perhaps I'll update this soon as I am getting ready to write a few more FAQs again.

[csauer]

RobDog888- This code looks great. However, I am getting the same errors CodeHammer did awhile back, yet I believe I have added the Reference to word, it does appear under references in the solution expolorer.

error: Type 'Word.Application' is not defined.
Suggests: Microsoft.Office.Interop.Word.Application

Other errors: Name "Word" not declared


Any suggestions? Thanks.

[RobDog888]

Ok, you may not have the .Interop installed on your system.

See the link in my sig - "Office Primary Interop Assemblies" that should resolve the errors.

[VB6Learner]

Uh no Errors but Dialog not showing what do I have to put in my button! Im using VB2008!

[Always_Confused]

I am getting an error on "Exit Function".

It says:
Function 'SpellMe' doesn't return a value on all code paths. A null reference exception could occur at run time when the result is used.

Friend Function SpellMe(ByVal msSpell As String) As String

        Dim oDoc As Word.Document
        Dim iWSE As Integer
        Dim iWGE As Integer
        Dim iResp As Integer
        Dim sReplace As String

        If msSpell = String.Empty Then Exit Function

        Try
            InitializeMe()

VS2008 3.5sp1

Option Explicit On
Option Strict On

[NickThissen]

That is not an error, it is a warning. It is warning you that the function SpellMe is not always returning a value. In this case, where you use Exit Function, there is no return value.

This doesn't need to be a hazard in your application, because you should always use appropriate null object checks. But if you don't do these checks, and use the result of this function directly, you may get an 'object reference not set' error.

[BukHix]

Is this how I should be calling this?

Dim sp As New clsSpellMe
TextBox1.Text = sp.SpellMe(TextBox1.Text)

[scholattu]

Hi,

How do I keep the text formatting after applying the spell check in a richtextbox? As it replaces the whole text, I am losing the text formatting and also other objects like images inside the richtextbox.

Is there a way to tell the spellcheck to look only in texts and update?

thanks,

[nbrege]

RobDog ... will this work with Office 2007? Some of our users are SOMETIMES getting this error:

Call was rejected by callee. (Exception from HRESULT: 0x80010001 (RPC_E_CALL_REJECTED)).

Do you know how I can fix this? Thanks...

[TysonLPrice]

I added the 12.0 version to the Select Case and am not experiencing any issues using it.

[moti barski]

to activate this :
1 what is needed to be installed/dl ?
2 what dll is to be referenced ?

how do i pass a string spell check it and get a : corrected string or 3 top correction strings options
(walkthrough) ?

[Nightwalker83]

to activate this :
1 what is needed to be installed/dl ?
2 what dll is to be referenced ?

Nothing! The only mention of references I found was MS Word xx.0 Object Library is needs referencing for the VB6 version of the above code. Although, you could try referencing the MS Word xx.0 Object Library in the vb.net project and see what happens.

[TysonLPrice]

It is all available as posted but...

1. Make a reference to Microsoft xx.x Object library.
2. Create a Windows project.
3. Add a text box
4. Add a command button.
5. Create the class.

Form logic:

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim x As New clsSpellMe

        TextBox1.Text = x.SpellMe(TextBox1.Text)


    End Sub

Class

Option Explicit On
Option Strict On
'Copyright © 2005 by RobDog888 (VB/Office Guru™). All Rights reserved.
'
'Distribution: You can freely use this code in your own
'              applications provided that this copyright
'              is left unchanged, but you may not reproduce
'              or publish this code on any web site, online
'              service, or distribute as source on any
'              media without express permission.
'From http://www.vbforums.com/showthread.php?t=359879
Imports Microsoft.Office.Interop

Public Class clsSpellMe

    Friend moApp As Word.Application
    Private mbKillMe As Boolean

    Friend Property KillMe() As Boolean
        Get
            InitializeMe()
            KillMe = mbKillMe
        End Get
        Set(ByVal Value As Boolean)
            mbKillMe = Value
        End Set
    End Property

    Friend Sub InitializeMe()
        Try
            '<INITIALIZE WORD>
            moApp = DirectCast(GetObject(, "Word.Application"), Word.Application)
        Catch ex As Exception
            If TypeName(moApp) = "Nothing" Then
                moApp = DirectCast(CreateObject("Word.Application"), Word.Application)
                mbKillMe = True
            Else
                MessageBox.Show(ex.Message, "VB/Office Guru™ SpellChecker™.NET", _
                MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
            End If
        End Try
    End Sub

    Friend Function SpellMe(ByVal msSpell As String) As String

        Dim oDoc As Word.Document
        Dim iWSE As Integer
        Dim iWGE As Integer
        Dim iResp As Integer
        Dim sReplace As String

        If msSpell = String.Empty Then
            SpellMe = ""
            Exit Function
        End If
        Try
            InitializeMe()
            Select Case moApp.Version
                Case "9.0", "10.0", "11.0", "12.0"
                    oDoc = moApp.Documents.Add(, , 1, True)
                Case "8.0"
                    oDoc = moApp.Documents.Add
                Case Else
                    MessageBox.Show("Unsupported Version of Word.", "VB/Office Guru™ SpellChecker™.NET", _
                    MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
                    SpellMe = ""
                    Exit Function
            End Select
            oDoc.Words.First.InsertBefore(msSpell)
            iWSE = oDoc.SpellingErrors.Count
            iWGE = oDoc.GrammaticalErrors.Count
            '<CHECK SPELLING AND GRAMMER DIALOG BOX>
            If iWSE > 0 Or iWGE > 0 Then
                '<HIDE MAIN WORD WINDOW>
                moApp.Visible = False
                If (moApp.WindowState = moApp.WindowState.wdWindowStateNormal) Or _
                    (moApp.WindowState = moApp.WindowState.wdWindowStateMaximize) Then
                    moApp.WindowState = moApp.WindowState.wdWindowStateMinimize
                Else
                    moApp.WindowState = moApp.WindowState.wdWindowStateMinimize
                End If
                '</HIDE MAIN WORD WINDOW>
                '<PREP CHECK SPELLING OPTIONS DIALOG BOX (MODIFY TO YOUR PREFERENCES)>
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.CheckGrammarWithSpelling = True
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.SuggestSpellingCorrections = True
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.IgnoreUppercase = True
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.IgnoreInternetAndFileAddresses = True
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.IgnoreMixedDigits = False
                moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Application.Options.ShowReadabilityStatistics = False
                '</PREP CHECK SPELLING OPTIONS DIALOG BOX (MODIFY TO YOUR PREFERENCES)>
                '<DO ACTUAL SPELL CHECKING>
                moApp.Visible = True
                moApp.Activate()
                iResp = moApp.Dialogs(Word.WdWordDialog.wdDialogToolsSpellingAndGrammar).Display
                '</DO ACTUAL SPELL CHECKING>
                If iResp < 0 Then
                    moApp.Visible = True
                    MessageBox.Show("Corrections Being Updated!", "VB/Office Guru™ SpellChecker™", _
                    MessageBoxButtons.OK, MessageBoxIcon.Information)
                    oDoc.Select()
                    oDoc.Range.Copy()
                    sReplace = DirectCast(Clipboard.GetDataObject.GetData("System.String", True), String)
                    '<FIX FOR POSSIBLE EXTRA LINE BREAK AT END OF TEXT>
                    If (InStrRev(sReplace, Chr(13) & Chr(10))) = (Len(sReplace) - 1) Then
                        sReplace = Mid$(sReplace, 1, Len(sReplace) - 2)
                    End If
                    '</FIX FOR POSSIBLE EXTRA LINE BREAK AT END OF TEXT>
                    SpellMe = sReplace
                ElseIf iResp = 0 Then
                    MessageBox.Show("Spelling Corrections Have Been Canceled!", "VB/Office Guru™ SpellChecker™.NET", _
                    MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
                    SpellMe = msSpell
                End If
            Else
                MessageBox.Show("No Spelling Errors Found" & Environment.NewLine & "Or No Suggestions Available!", _
                "VB/Office Guru™ SpellChecker™.NET", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
                SpellMe = msSpell
            End If
            '</CHECK SPELLING AND GRAMMER DIALOG BOX>
            oDoc.Close(False)
            oDoc = Nothing
            '<HIDE WORD IF THERE ARE NO OTHER INSTANCES>
            If KillMe = True Then
                moApp.Visible = False
            End If
            '</HIDE WORD IF THERE ARE NO OTHER INSTANCES>
        Catch ex As Exception
            MessageBox.Show(ex.Message, "VB/Office Guru™ SpellChecker™.NET", _
            MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
        End Try

    End Function

End Class

[Whiteshua]

I have a textbox on a continuous form with a memo field control source. On double click, the text box will open another form that has it's contents displayed in a larger view, with the option to spell check, modify the text in the field and then update and close, transferring the modified text back to the original textbox control.

I want to be able to run the grammar checker in word on this expanded form as well.

Any ideas? Any .mdbs already ready already?

P.S. Unfortunately, my office still uses ACCESS 2003 and will continue to do so for an indefinite amount of time...

[RobDog888]

Just preset in code what options you want before invoking the spelling dialog. Its shown in my first post. See line 78: '<PREP CHECK SPELLING OPTIONS DIALOG BOX (MODIFY TO YOUR PREFERENCES)>

[Amerigo]

It is amazing that so many have figured out how to use this although there isn't one mention anywhere as to how to call this class to start auto-checking text fields on a form. So, how is this accomplished?

[RobDog888]

Because checking fields on a form is simply just passing the fields in a loop to the SpellMe function after you instantiate the clsSpellMe class. My initial example is just for one big "field" if you will. Its up to you how you want to call or utilize it for your own needs.

[TheDevGuy]

Hallo, not sure if this is still supported, I love the class but cannot get it to work for me. i added version 12.0 to my moApp.Versions.

Im using office 2007

I get the following error

TheAdd method or property is not available because the document is a rich text edit control..

hope I can get this going, its exactly what im looking for.

thanks