Determining regional setting in VBA code

[Quimbly]

How do you do it?

In other words, at run-time, I want to determine the system regional settings and be able to test against the returned info.

Of course, using something like MonthName(1), it would give me either an English name for January, or the word in some other language. But there's got to be a better way...

Any suggestions?

[Quimbly]

Well, I found this code:

Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" (ByVal Locale As Long, ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
 
Public Function ReadLocaleInfo(ByVal lInfo As Long) As String
    
    Dim sBuffer As String
    Dim rv As String
    
    sBuffer = String$(256, 0)
    rv = GetLocaleInfo(LOCALE_USER_DEFAULT, lInfo, sBuffer, Len(sBuffer))
    
    If rv > 0 Then
        ReadLocaleInfo = Left$(sBuffer, rv - 1)
    Else
        'MsgBox "Not found"
        ReadLocaleInfo = ""
    End If
End Function

I've tried it with the following inputs:

MsgBox ("UserDefault: " & ReadLocaleInfo(LOCALE_USER_DEFAULT))
MsgBox ("SDecimal: " & ReadLocaleInfo(LOCALE_SDECIMAL))
MsgBox ("ILDate: " & ReadLocaleInfo(LOCALE_ILDATE))
MsgBox ("Country: " & ReadLocaleInfo(LOCALE_ICOUNTRY))

...and in each case, it returned an empty string.

Any ideas?

[RobDog888]

I have this example from allapi.net which is where you may have
got the example from and they use different const.'s
This works for me but the UserDefault.

Option Explicit
 
Private Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" (ByVal Locale As Long, _
ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
 
Private Const LOCALE_USER_DEFAULT = &H400
Private Const LOCALE_SDECIMAL As Long = &HE
Private Const LOCALE_ILDATE As Long = &H22
Private Const LOCALE_ICOUNTRY As Long = &H5
Private Const LOCALE_SENGCOUNTRY = &H1002 ' English name of country
Private Const LOCALE_SENGLANGUAGE = &H1001  ' English name of language
Private Const LOCALE_SNATIVELANGNAME = &H4  ' native name of language
Private Const LOCALE_SNATIVECTRYNAME = &H8  ' native name of country
 
Public Function GetInfo(ByVal lInfo As Long) As String
    Dim Buffer As String
    Dim Ret As String
    Buffer = String$(256, 0)
    Ret = GetLocaleInfo(LOCALE_USER_DEFAULT, lInfo, Buffer, Len(Buffer))
    If Ret > 0 Then
        GetInfo = Left$(Buffer, Ret - 1)
    Else
        GetInfo = ""
    End If
End Function
 
Private Sub Form_Load()
    MsgBox "You live in " & GetInfo(LOCALE_SENGCOUNTRY) & _
    " (" & GetInfo(LOCALE_SNATIVECTRYNAME) & ")," & vbCrLf & "and you speak " & GetInfo(LOCALE_SENGLANGUAGE) & _
    " (" & GetInfo(LOCALE_SNATIVELANGNAME) & ").", vbInformation 'WORKS CORRECTLY
    MsgBox ("UserDefault: " & GetInfo(LOCALE_USER_DEFAULT)) 'STILL EMPTY STRING
    MsgBox ("SDecimal: " & GetInfo(LOCALE_SDECIMAL)) 'RETURNS "."
    MsgBox ("ILDate: " & GetInfo(LOCALE_ILDATE))     'RETURNS "0"
    MsgBox ("Country: " & GetInfo(LOCALE_ICOUNTRY))  'RETURNS "1"
End Sub

[Quimbly]

Thanks for the response...

As it turns out, if I just use the hex codes, things work fine.

[ZeBula8]

Application.International(xlCountrySetting)

this will return the regional country settings and you will be able to set your application accordingly.