MSFlexgrid - Set column width to text width..

[Static]

How do I set the column width to be = to the amount of text

(the text length varies)

[jcfowl]

Very good question.

Although I've never tried the way I'd approach is:

Check all Rows for Largest number of Characters
Use Length of that word to and then You need to
Figure out the Twips per Character.

I've only seen Twips Per Pixel so I'm not sure where to
go from here.

[Static]

thats what im doing...
but ..the TextWidth() command isnt quite enough

it comes up with 1125 for one col where the column needs about 1400 to fit it...


hmmm...

thanks

[Static]

nevermind..now that I removed the cellfontbold = true... it works

the bold was messing up the textwidth()

thanks

[Serge]

Here is a Generic routine I've put together a while back:

Public Sub ResizeGrid(pGrid As MSFlexGrid, pForm As Form)
    Dim intRow As Integer
    Dim intCol As Integer
    
    With pGrid
        For intCol = 0 To .Cols - 1
            For intRow = 0 To .Rows - 1
                If .ColWidth(intCol) < pForm.TextWidth(.TextMatrix(intRow, intCol)) + 100 Then
                   .ColWidth(intCol) = pForm.TextWidth(.TextMatrix(intRow, intCol)) + 100
                End If
            Next
        Next
    End With
End Sub

Then just call this routine like this:


ResizeGrid MSFlexGrid1, Form1

[Static]

similar to what I did..

But.. As I added each row...I checked...if the textwidth + 100 > current column width the make the colwidth = textwidth + 100

only problem is some of the cols have to be bold. Im working on a solution...

[rplcmint]

This seemed to work for me. Scrolling through every cell in that column, finding the max Twip size and then adjusting the cell for the max size:

Private Sub mnuAdjust_Click(Index As Integer)
Dim i As Integer
Dim maxTwips As Integer
Dim Twips As Integer

With Me.MSFlexGrid1
Me.ScaleMode = vbTwips
For i = 0 To .Rows - 1
Twips = Me.TextWidth(.TextMatrix(i, .ColSel))
If Twips > maxTwips Then
maxTwips = Twips
End If
Next i

.ColWidth(.ColSel) = maxTwips * Me.MSFlexGrid1.Font.Size / Me.Font.Size + 100 '* Screen.TwipsPerPixelX

End With


End Sub


Thanks for the help.

[techgnome]

Originally posted by geoff_xrx
similar to what I did..

But.. As I added each row...I checked...if the textwidth + 100 > current column width the make the colwidth = textwidth + 100

only problem is some of the cols have to be bold. Im working on a solution...

When using TextWidth, it uses the Font settings of the object - your form in this case. If you set your form's font settings to the same as the font settings of the col you are trying set the width on, you'll get the right numbers.

TG