The sleep function for my VB6 doesn't work, it just freezes up the application. Can anyone give me a sleep function that won't freeze up the application?
Printable View
The sleep function for my VB6 doesn't work, it just freezes up the application. Can anyone give me a sleep function that won't freeze up the application?
How about the API?
In your delcarations section add this
To use itCode:Private Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As Long)
Code:Sleep 1000 ' to sleep for 1 second
Yeah, I was talking about that code, the only problem I have after that is that it doesn't seem to want to do all the codes after that sleep functionQuote:
Originally Posted by LaVolpe
Then something else is happening. Sleep only pauses your code then the next lines continue on. You may want to be more specific and post some relevant code that we can look at.
That's because the Sleep API freezes all events and the next line of code in your app until the Sleep period has expired. By it self I find it nearly useless. My favorite sub incorporates the Sleep API (in 2mS increments) and some additional code to create the Pause sub. Just use Pause (Sec or fraction of a second) where you would use Sleep.Quote:
Originally Posted by Derkel
Code:Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
' Credits: (Milk (Sleep+Pause Sub)). (Wayne Spangler (Pause Sub))
Private Sub Pause(ByVal Delay As Single)
Delay = Timer + Delay
If Delay > 86400 Then 'more than number of seconds in a day
Delay = Delay - 86400
Do
DoEvents ' to process events.
Sleep 1 ' to not eat cpu
Loop Until Timer < 1
End If
Do
DoEvents ' to process events.
Sleep 1 ' to not eat cpu
Loop While Delay > Timer
End Sub
CDRIVE, That looks good to overcome the situation when pass midnight, however that has some minor problems:
- As Timer() never reaches 86400, if Delay = 86400 (rare) then only the second Do...Loop runs 1 round: approx only 1 millisecond delay.
So, instead of If Delay > 86400 Then , that should be If Delay >= 86400 Then- Delay may be greater than multiple of 86400, such as Delay = 259210 (=3*86400+10), then after Delay = Delay - 86400 you still have Delay > 86400.
Below is my Pause() function, it uses only one Do...Loop.
As Timer() is only updated every 1/64 sec = 15.625 millisecs, you can give the loop sleep a bit longer before checking Timer() vs TimeOut.
If higher-resolution timing is required then Timer() is not good enough, perhaps we have to use something else such as QueryPerformanceCounter()
Code:Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Public Sub Pause(SecsDelay As Single)
Dim TimeOut As Single
Dim PrevTimer As Single
PrevTimer = Timer
TimeOut = PrevTimer + SecsDelay
Do While PrevTimer < TimeOut
Sleep 4 '-- Timer is only updated every 1/64 sec = 15.625 millisecs.
DoEvents
If Timer < PrevTimer Then TimeOut = TimeOut - 86400 '-- pass midnight
PrevTimer = Timer
Loop
End Sub
Ah, I thought the TS was referring to what's happening, or not happing, in other events during the Sleep interval.Quote:
Originally Posted by LaVolpe
Anhn, thanks for pointing that out. Even though I can't imagine a delay >86400 it's still worth mentioning. ;)Quote:
Originally Posted by anhn
Many thanks to LaVolpe for this posting of a sleep function. I needed a way to add a pause to a standard code module and the API call is exactly what the doctor ordered. :)
The problem with DoEvents is that cause the Vb5/6 runtime to run any other event. Vb6 have re-entrance in event subroutine, so a pause in any of these subroutines or subroutines in a "bas" module, that we call from event subroutines, can't guarantee that a pause has a meaning of a pause.
So we have to break the re-entrance. I use a static variable once:
Sub That_Event()
static once as boolean
if once then exit sub
once=true
' our code here
once=false
exit sub
We can use a public "donothing" as boolean, so if it is true no event subroutine can do anything...until our pause end.
Deleted
Just playing around and saw all the answers. Just throwing this out:
Code:Private Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As Long)
Private Sub Command1_Click()
Dim iTestIt As Integer
iTestIt = 1
Dim i As Integer
For i = 1 To 10
Text1.Text = iTestIt
Text1.Refresh
Sleep 1000
iTestIt = iTestIt + 1
Next i
End Sub
the vb.timer is quite nice, as it will not freeze the form.
it all depends what u need it for and what kind of state u want the form to have while "processing" whatever you are doing.
before working with game-loops, i used the vb.timer.
its easy to make the timer do "operations", recursively, example:
using sleep it will freeze the form and the functions, halting your program.Code:Dim operation as integer
Dim funpr1 as integer
Private Sub doOperation(ByVal Op&)
' something '
End Sub
Private Sub function1()
funpr1 = funpr1 + 1
doOperation funpr1
If funpr1 = 10 Then operation = 0
End Sub
Private Sub Timer1_Timer()
Select Case operation
Case 0: ' nothing '
Case 1: function1
Case 2: function2
Case 3: function3
End Select
End Sub
better to avoid using sleep if possible.
This thread has been started more than a decade ago! :D
It started, went dormant for six years, revived for a brief time, went dormant for another five years....see y'all back here again around 2024 or 2025.
Yeah, that may be it.