[RESOLVED] List Max/Min vs. Sort

Hi All,
I have a custom class and I have implemented iComparable for several fields via nested helper classes. (ala this article http://support.microsoft.com/kb/321292)

I'd like to be able to use a function similar to the Array.Sort(Array, IComparer) with a list(of T). This works great with arrays, but I really prefer using lists.

I'd also like to be able to use the list(of T).max/min functions as well with a specific IComparer rather than ONLY the compare method in my custom class.

i.e. I'd like to be able to get the max/min of a list(of T) for more than just one field.

Any good way to do that without writing a max/min function? (which I realize I could have written in the time to write this message... :-))

Thanks!
Nick

here's an example:

vb.net Code:

Public Class Class1
    Public a As Integer
    Public b As Decimal
    Public c As String
End Class

vb.net Code:

Public Class comparer
    Implements IComparer(Of Class1)
 
    Private _field As String
    Public Property field() As String
        Get
            Return _field
        End Get
        Set(ByVal value As String)
            _field = value
        End Set
    End Property
 
    Public Enum order
        ascending
        descending
    End Enum
 
    Private _order As order
    Public Property sortOrder() As order
        Get
            Return _order
        End Get
        Set(ByVal value As order)
            _order = value
        End Set
    End Property
 
    Public Sub New(ByVal field As String, ByVal sortOrder As order)
        Me.field = field
        Me.sortOrder = sortOrder
    End Sub
 
    Public Function Compare(ByVal x As Class1, ByVal y As Class1) As Integer Implements System.Collections.Generic.IComparer(Of Class1).Compare
        If field = "a" Then
            If Me.sortOrder = order.ascending Then
                Return CInt(x.a).CompareTo(CInt(y.a))
            ElseIf Me.sortOrder = order.descending Then
                Return CInt(y.a).CompareTo(CInt(x.a))
            End If
        ElseIf field = "b" Then
            If Me.sortOrder = order.ascending Then
                Return CDec(x.b).CompareTo(CDec(y.b))
            ElseIf Me.sortOrder = order.descending Then
                Return CDec(y.b).CompareTo(CDec(x.b))
            End If
        ElseIf field = "c" Then
            If Me.sortOrder = order.ascending Then
                Return x.c.CompareTo(y.c)
            ElseIf Me.sortOrder = order.descending Then
                Return y.c.CompareTo(x.c)
            End If
        End If
    End Function
End Class

vb.net Code:

Public Class Form1
 
    Private myList As New List(Of Class1)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        myList.Add(New Class1 With {.a = 5, .b = 1.5D, .c = "c"})
        myList.Add(New Class1 With {.a = 3, .b = 0.75D, .c = "a"})
        myList.Add(New Class1 With {.a = 7, .b = 2.25D, .c = "b"})
    End Sub
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        'to sort a generic list with an icomparer
        myList.Sort(New comparer("c", comparer.order.ascending))
        'you can use LINQ with min + max
        MsgBox(myList.Min(Function(c1) c1.a))
        MsgBox(myList.Max(Function(c1) c1.c))
    End Sub
 
End Class

to return a different field:

vb.net Code:

MsgBox(myList.Find(Function(c1) c1.a = myList.Min(Function(c2) c2.a)).c)

Hi All,
This works! Thanks Paul!
Nick