Listview Highlight Due Date

I have a listview loaded from database and I want to change font color under Due Date Column if due date already is already pass.

This is the code I use to load data in LISTVIEW

Code:

---

'HEADERS
With ListView2
    .View = lvwReport
    .ColumnHeaders.Clear
    .ColumnHeaders.Add , , "id:", 0
    .ColumnHeaders.Add , , "Invoice #:", 1700
    .ColumnHeaders.Add , , "OR #:", 1000
    .ColumnHeaders.Add , , "Date:", 2200
    .ColumnHeaders.Add , , "Type:", 1500
    .ColumnHeaders.Add , , "Due Date:", 2300
    .ColumnHeaders.Add , , "Credit:", 1800
    .ColumnHeaders.Add , , "Debit:", 1800
    .ColumnHeaders.Add , , "Balance:", 1900
    .ColumnHeaders.Add , , "Balance:", 0
    .ColumnHeaders.Add , , "Base ID:", 0
End With

---

Code:

---

Private Sub list2fills()
Dim si As MSComctlLib.ListSubItem
Dim itm As ListItem
   
    Set Rs4 = cn.Execute("SELECT * from invoice where ID= " & Text1 & "")
        If Not Rs4.EOF Then
            Rs4.MoveFirst
            ListView2.ListItems.Clear
            Do While Not Rs4.EOF
       
            Set P = ListView2.ListItems.Add(, , Rs4!ID)
            P.SubItems(1) = Rs4.Fields!invoiceno & ""
            P.SubItems(2) = Rs4.Fields!orID & ""
            P.SubItems(3) = Format(Rs4.Fields!dateinv, "MMMM DD, YYYY")
            P.SubItems(4) = Rs4.Fields!Type
            P.SubItems(5) = Format(Rs4.Fields!duedate, "MMMM DD, YYYY")
            P.SubItems(6) = Format(Rs4.Fields!amount & "", "##, ##0.00")
            P.SubItems(7) = Format(Rs4.Fields!debit & "", "##, ##0.00")
            P.SubItems(8) = Format(Rs4.Fields!balance & "", "##, ##0.00")
            P.SubItems(9) = Rs4.Fields!amount & ""
            P.SubItems(10) = Rs4.Fields!baseID
            Rs4.MoveNext
            Loop
        Else
        ListView2.ListItems.Clear
        End If
End Sub

---

You could try something like this:

Code:

---

           
P.SubItems(5) = Format(Rs4.Fields!duedate, "MMMM DD, YYYY")
If Rs4![duedate] <  Now Then ListView2.ListItems(ListView2.ListItems.Count).ListSubItems(5).ForeColor = vbRed

---

Quote:

---

Originally Posted by Doogle

You could try something like this:

Code:

---

           
P.SubItems(5) = Format(Rs4.Fields!duedate, "MMMM DD, YYYY")
If Rs4![duedate] <  Now Then ListView2.ListItems(ListView2.ListItems.Count).ListSubItems(5).ForeColor = vbRed

---

---

Thanks Doogle!... It work!