[RESOLVED] Running multiple instances of IE using ShellExecute

If I double click on the Icon on the Desktop for IE I can do it multiple times and get a separate instances of IE running at the same time. However, if I try to launch multiple instances of IE using the ShellExecute API I can get only one instance of IE as each one will use the same instance just giving it a new URL.

How can I launch multiple instances of IE using VB6 code and passing it an argument?

Which IE version you are using?

I have IE 8 and ShellExecute opens new instance for each call, review IE settings specially tab's settings, maybe there is an option cause that behavior.

you could also use createobject

I have IE 7. I have tried changing options that have to do with tabs but still I only get one instance of IE. With tabs on I get all sites I Shell to they are just on the same instance of IE and I have to switch tabs to go to each site and I would rather have an instance for each site.

@westconn1

Do you have example of CreateObject that will create instances of IE?

Another method would be to use the CreateProcess API

Code:

---

Option Explicit

Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" _
                        (ByVal lpApplicationName As String, _
                        ByVal lpCommandLine As String, _
                        lpProcessAttributes As Long, _
                        lpThreadAttributes As Long, _
                        ByVal bInheritHandles As Long, _
                        ByVal dwCreationFlags As Long, _
                        lpEnvironment As Any, _
                        ByVal lpCurrentDriectory As String, _
                        lpStartupInfo As STARTUPINFO, _
                        lpProcessInformation As PROCESS_INFORMATION) As Long
                       
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
   

Private Type STARTUPINFO
        cb As Long
        lpReserved As String
        lpDesktop As String
        lpTitle As Long
        dwX As Long
        dwY As Long
        dwXSize As Long
        dwYSize As Long
        dwXCountChars As Long
        dwYCountChars As Long
        dwFillAttribute As Long
        dwFlags As Long
        wShowWindow As Integer
        cbReserved2 As Integer
        lpReserved2 As Long
        hStdInput As Long
        hStdOutput As Long
        hStdError As Long
End Type

Private Type PROCESS_INFORMATION
        hProcess As Long
        hThread As Long
        dwProcessId As Long
        dwThreadId As Long
End Type

Private Sub Command_Click()
Dim lngReturn As Long
Dim strIE As String
Dim strCL As String
Dim udtStart As STARTUPINFO
Dim udtPI As PROCESS_INFORMATION
udtStart.cb = Len(udtStart)
strIE = """C:\Program Files\Internet Explorer\iexplore.exe"" "
strCL = strIE & "http://www.yahoo.com"
lngReturn = CreateProcess(vbNullString, strCL, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, vbNullString, udtStart, udtPI)
lngReturn = CloseHandle(udtPI.hProcess)
lngReturn = CloseHandle(udtPI.hThread)
End Sub

---

Since you mentioned IE, I will offer you this solution.

Code:

---

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Const SW_SHOWNORMAL = 1

Private Sub Command1_Click()
Dim strUrl As String

    strUrl = "http://www.vbforums.com/showthread.php?686911-Running-multiple-instances-of-IE-using-ShellExecute"

    ShellExecute Me.hwnd, "Open", "iexplore.exe", strUrl, vbNullString, SW_SHOWNORMAL
End Sub

---

Using ShellExecute are there parameters to control the X, Y and Size of IE? I see that there are using CreateProcess


EDIT:

I just tried CreateProcess and modified the parameters but they don't appear to work

Code:

---

  '
  '
Private Const STARTF_USEPOSITION = &H4
Private Const STARTF_USESIZE = &H2
Private Const STARTF_USESHOWWINDOW = &H1
Private Const SW_SHOWDEFAULT = 10
  '
  '
Private Sub RunYahoo()
 Dim lngReturn As Long
 Dim strIE As String
 Dim strCL As String
 Dim udtStart As STARTUPINFO
 Dim udtPI As PROCESS_INFORMATION

 udtStart.cb = Len(udtStart)

'
 ' These do not appear to work
 '
 udtStart.wShowWindow = SW_SHOWDEFAULT
 
 udtStart.dwFlags = STARTF_USEPOSITION Or STARTF_USESIZE Or STARTF_USESHOWWINDOW
 udtStart.dwFlags = STARTF_USEPOSITION Or STARTF_USESIZE

 udtStart.dwX = 8370
 udtStart.dwY = 120
 udtStart.dwXSize = 5085
 udtStart.dwYSize = 5910

 strIE = """C:\Program Files\Internet Explorer\iexplore.exe"" "
 strCL = strIE & "http://www.yahoo.com"

 lngReturn = CreateProcess(vbNullString, strCL, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, vbNullString, udtStart, udtPI)
 lngReturn = CloseHandle(udtPI.hProcess)
 lngReturn = CloseHandle(udtPI.hThread)
End Sub

---

I also tried using the same above code except I substituted my own VB application instead of IE. It appears that no matter how I initialize the parameters of the STARTUPINFO structure the app always starts up with the size of the app created at design time. Also the X and Y are always what was specified in the Form's Properties StartUpPosition field.

if you create an instance with createobject, you can resize and position the window, before making it visible

Code:

---

Set wb = CreateObject("internetexplorer.application")
wb.Navigate2 someurl
wb.Top = 300
wb.Left = 300
wb.Width = 500
wb.Height = 300
wb.Visible = True
Set wb = Nothing  ' leave for user

---

OK, that works great, westconn. How do you set it up for VB application?

Quote:

---

How do you set it up for VB application?

---

different question, you can only use this for programs with com interface, office apps, internet explorer etc
shellexecute should work for them, but of course if app.previnstance is used, only one can be run regardless, i doubt that any of them will run in the same instance, unless specifically coded to do so

I've been playing with CreateProcess and can't get the StartupInfo data 'recognised'. A work around is to use SetWindowPos after the process has been created
Form Code:

Code:

---

Option Explicit

Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" _
                        (ByVal lpApplicationName As String, _
                        ByVal lpCommandLine As String, _
                        lpProcessAttributes As Long, _
                        lpThreadAttributes As Long, _
                        ByVal bInheritHandles As Long, _
                        ByVal dwCreationFlags As Long, _
                        lpEnvironment As Any, _
                        ByVal lpCurrentDriectory As String, _
                        lpStartupInfo As STARTUPINFO, _
                        lpProcessInformation As PROCESS_INFORMATION) As Long
                       
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Declare Function EnumWindows Lib "user32" _
                        (ByVal lpEnumFunc As Long, _
                        ByVal lParam As Long) As Boolean
                           
Private Declare Function WaitForSingleObject Lib "kernel32" _
                        (ByVal hHandle As Long, _
                        ByVal dwMilliseconds As Long) As Long

Private Type STARTUPINFO
        cb As Long
        lpReserved As String
        lpDesktop As String
        lpTitle As Long
        dwX As Long
        dwY As Long
        dwXSize As Long
        dwYSize As Long
        dwXCountChars As Long
        dwYCountChars As Long
        dwFillAttribute As Long
        dwFlags As Long
        wShowWindow As Integer
        cbReserved2 As Integer
        lpReserved2 As Long
        hStdInput As Long
        hStdOutput As Long
        hStdError As Long
End Type

Private Type PROCESS_INFORMATION
        hProcess As Long
        hThread As Long
        dwProcessId As Long
        dwThreadId As Long
End Type

Private Sub Command_Click()
Dim lngReturn As Long
Dim strCL As String
Dim udtStart As STARTUPINFO
Dim udtPI As PROCESS_INFORMATION
udtStart.cb = Len(udtStart)
strCL = """C:\program files\microsoft Visual Studio\VB98\project1.exe"""
lngReturn = CreateProcess(vbNullString, strCL, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, ByVal 0&, vbNullString, udtStart, udtPI)
WaitForSingleObject udtPI.hProcess, 100&
lngPID = udtPI.dwProcessId
EnumWindows AddressOf EnumWindowsProc, ByVal 0&
lngReturn = CloseHandle(udtPI.hProcess)
lngReturn = CloseHandle(udtPI.hThread)
End Sub

---

and in a Module:

Code:

---

Option Explicit

Private Declare Function GetWindowThreadProcessId Lib "user32" _
                    (ByVal hwnd As Long, _
                    lpdwProcessId As Long) As Long
                   
Private Declare Function SetWindowPos Lib "user32" _
                        (ByVal hwnd As Long, _
                        ByVal hWndInsertAfter As Long, _
                        ByVal x As Long, _
                        ByVal y As Long, _
                        ByVal cx As Long, _
                        ByVal cy As Long, _
                        ByVal wFlags As Long) As Long
                       
Private Const SWP_NOZORDER As Long = 4

Public lngPID As Long
           
Public Function EnumWindowsProc(ByVal hwnd As Long, ByVal lParam As Long) As Boolean
Dim lngRet As Long
Dim lngPID1 As Long
lngRet = GetWindowThreadProcessId(hwnd, lngPID1)
If lngPID1 = lngPID Then
    lngRet = SetWindowPos(hwnd, 0&, 400&, 400&, 10&, 10&, SWP_NOZORDER)
End If
EnumWindowsProc = True
End Function

---

It doesn't appear to position and size according to the parameters

lngRet = SetWindowPos(hwnd, 0&, 400&, 400&, 10&, 10&, SWP_NOZORDER)

I can change those values and it always keeps the previous position/size.

The first time I ran the code the app appeared as a small window approx in the middle of the screen. Next time I ran code and changed the values the app appeared at the same location and size of the 1st time. I made many changes to the values and each time I run the code the app still positions at the same place and the size is the same

Strange. It works fine for me.

I noticed you use

strCL = """C:\program files\microsoft Visual Studio\VB98\project1.exe"""


where I used

strCL = """C:\Program Files\Internet Explorer\iexplore.exe"" "

Work this source coded commands:

Code:

---

If App.PrevInstance = True Then Unload Me

---

You are able to work this into the current App, but then you might be able to work in into a Shell command, by using making a Call to the file, which is being Shelled into execution. Then this is the tricky stuff right here: You have to work your way around: IE's App.Path, but using the App.Path and then try not to make it a static path, becuase there will then be problems that arise along with doing that. But then you are then able to then make the batch file, by making the call as per like this: blah blah \ iexplorer.exe, then using the necessary information gained from the Thread, I can then say that you would have to re-route the exe file to then be executed using a batch file or cmd file, it's your choice. I would then choose the cmd file, because getting the new age thing happening, and then finally you can then use the App.PrevInstance on the batch or cmd file, then that would mean that you don't have to totally modify anything. But there is also a way to totally change the execution of a program, using the Windows Registry, which I think that you don't want to do, in this actual fact of the matter at hand...

@JM: Check Task Manager and make sure there's no 'orphan' iexplore processes running. IE doesn't seem to behave like other programs. I could reproduce the problem you're seeing when I had such 'orphans' - the PID returned in udtPI did not have a corresponding hwnd hence the SetWindowPos was never executed, although a new browser window opened up.

I suspect the 'orphans' were created when I was testing and stopped the program before the CloseHandle statements were executed.

The SetWindowPos did execute - I singled stepped through the Enum sub and know that it hit SetWindowPos and as I manually executed that statement the IE did not change at all. Even your example you posted only worked one time and thereafter after I changed the parameters (making sure no other instance of IE was running) IE would pop up again but it always kept the same position and size as what it was when I ran your code the first time. I did this over and over and always the same thing. I finally just gave up on it. It's beyond me.

EDIT

I ran the code using my own applications and it does work correctly with them. So, keeping the same parameters (the ones that sized and positioned my own app correctly) I changed back to IE and still IE did not size/position according to the parameters; it popped up at it's old size/position. You think maybe IE get's it size/info from the registry and uses that over riding everything else?

This is rather very hard in that I am still working on this Thread. So then here we go again, for another day...

i am very sorry, that I haven't been able to get to work on what the OP has asked, of us. It is because I have been sleeping all of these days, for the past week. Even when I am meant to be working, not sure why. It must have caught up to me, and then it is taking the well you know what out of me, instead of taking me around the corner and then well putting me into lala land, for the whole week, maybe or maybe not for the rest of the week, too. Also I just woke up, hand lunch and then well it's meant for knock off time, well then see you tomorrow, even!! I really hope so, that I am not the one that is able to knock off into lala land, again at the late stage in the week!!

@JM: Don't think i'll be much more help since i can't reproduce the problem you're experiencing with IE

It doesn't matter, Doogle, but thanks for your input as it does help me with using my own applications. I can get what I want using the CreateObject method for IE.

So then if there isn't a problem, then why did you call a Thread, then??? There are some kinds of registry keys, that can be modified to deal with your Thread. But then that wouldn't be really good, because of the fact of the matter that if you totally modifty the IE content of the registry, then that isn't really good, in deed. Due to tht fact that it could go wrong...

I didn't say there wasn't a problem I opened the thread because I want to know how to run multiple instances of IE using ShellExecute but that didn't get resolved then someone suggested using CreateObject and then I got that to work the way I wanted it to but it was not meant for my own applications so someone suggested using CreatProcess and that was the last option suggested but I couldn't get it to work so I said to Doogle it doesn't matter because I got what I needed using CreateObject. Do you understand?

Yes I do understand. But then I suggested to make a FrontEnd Loader from an VB6 COM EXE Windows File, and then setup single isntance detecting using the App.PrevInstance command string, thus making what you wanted without making any changes to the Internet Explorer or even the Registry, because you don't want to totally modifty that. Due to the second windows, and also the Popup Windows that exist inside the Windows 32-Bit plaform. You can however be able to remove the Popups, by selecting the Popup blocker, by doing what you wish to do by selecting a instance of the Window, itself...

However I am still at amazement by what you are trying to do. Because Internet Explorer must be a multipul instance Windows Application. This thus means that you must have at least a Window for the Main or Mother Window. Then making a Child Window, as for a second isntance, of the same Application, however being a bit modiftied in the way that it is being able to handle processes...

I have no idea what you are talking about. Very confusing. Anyway, I don't have a problem bringing up multiple instances of IE; only in the sizing and positioning of the instances.

Something like an API, which is called: WindowsPos, something something, like that???

I tried that. It didn't work

.Top and .Left, really should work here. But then they cannot, cause of they are Form Properties. However there is also another some about the Form Position of the Shell command. That I have been able to look upon. You can then make the Form, which is what I guess what it is a Form??? But then during the command of Shell, you might be able to switch in a X and Y typed Integer, as you can during a .Show and a With command block, eg: With blah blah .Left = 34 and so on...

Apart from that, I can't help you cause #1: Your not showing your source code, in any kind of CODE tags... #2: There really isn't a problem, just a function process that has to be writtren...

Quote:

---

Originally Posted by ThEiMp

Apart from that, I can't help you cause #1: Your not showing your source code, in any kind of CODE tags... #2: There really isn't a problem, just a function process that has to be writtren...

---

Sure I am - see posts 5, 7 and 11. That's the code I'm using and it doesn't work for the position and size of IE.

I can Size and Position ActiveX Controls that feature Forms inside, to have their .Left, .Top, .Height and als their .Width properties set. But then I cannot see how we can change these settings. Also if that is source code, then you have to actually tell me that it is. I thought that it was stripped down to feature only the relevant source of the problem...

@TheImp: If you take the trouble to read all the Posts in the Thread you'll see that it's got nothing to do with Active X controls with or without Forms inside. It's about wanting to programatically size an Internet Explorer Window. Initially the problem was trying to do that when Internet Explorer had been started via a ShellExecute statement and later moved on to the situation where it had been started using CreateProcess.

You'll also notice that as far as OP is concerned, the Thread is Resolved, so unless you've got a reliable method to do what is required in either or both cases, I suggest we leave this Thread alone.