BGW Array

I have a background work reading an XML file. I want it to return an array of results which happen to be values.

I want to be able to place all the values as a point on a panel as an X asis which will be lined up with a y+10 pixels on the y axis.

I have the BGW reading the XML file and getting the values. all i need to know is how to return an array list or something similar to a can draw my line graph

something like this. this is the xml i used to test it:

Quote:

---

<?xml version="1.0" encoding="utf-8"?>
<Points>
<Value x="10" y="10"/>
<Value x="20" y="20"/>
<Value x="30" y="30"/>
<Value x="40" y="40"/>
<Value x="50" y="50"/>
</Points>

---

vb Code:

Public Class Form1
 
    Dim xmlPoints() As Point
 
    Private Sub BackgroundWorker1_DoWork(ByVal sender As System.Object, ByVal e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Dim xml As XDocument = XDocument.Load("xml.txt")
        Dim points() As Point = (From node In xml...<Value> Select New Point(CInt(node.@x), CInt(node.@y))).ToArray
 
        e.Result = points
 
    End Sub
 
    Private Sub BackgroundWorker1_RunWorkerCompleted(ByVal sender As Object, ByVal e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
        xmlPoints = DirectCast(e.Result, Point())
        Me.Invalidate()
    End Sub
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        BackgroundWorker1.RunWorkerAsync()
    End Sub
 
    Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
        If xmlPoints Is Nothing Then Return
        e.Graphics.DrawLines(Pens.Red, xmlPoints)
    End Sub
 
End Class