Finding the IP address of a machine.

How do I get the IP address of a machine using VB6 code?

You can use:

vb Code:

Text1.Text = winsock.RemoteHostIP

Although, how are you going to connect to the remote machine in the first place?

Quote:

---

Originally Posted by Nightwalker83

You can use:

vb Code:

Text1.Text = winsock.RemoteHostIP

Although, how are you going to connect to the remote machine in the first place?

---

Actually, I want to get the IP address of the local machine.

Quote:

---

Originally Posted by svg3414

Actually, I want to get the IP address of the local machine.

---

Ah ok! In that case it is:

vb Code:

Private Sub Form_Load()
Text1.Text = Winsock1.LocalIP
End Sub

The reality isn't so simple.

An individual computer can have multiple adapters and each adapter can have multiple IP addresses. Which of these N * M addresses gets returned by the Winsock control depends on what actions have been performed on the control first (such as an action that specified which IP address to use).

In the degenerate case you'll usually get the first (i.e. "preferred") one though, and in the extreme degenerate case of John Doe's home PC there is only one anyway.

This is changing though. As more John Does out there start running VM software they'll find they have software adapters installed on their machines for bridging to VMs.


But the funny part is, none of this may relate to the question that is trying to be asked here anyway. After all, knowing "your IP address" is generally pretty useless since you can use the loopback address for local operations.

I suspect the OP here may be asking how to find his router's public IP address.

Quote:

---

Originally Posted by dilettante

The reality isn't so simple.
...........
I suspect the OP here may be asking how to find his router's public IP address.

---

Well I will clarify. The situation is something like this.

My company has some 200 branches with some 1200 machines connected on a WAN. The Head Office will send periodical statements to the branches. When a statement arrives, a window will pop up on the branch machine and the user has to click a button. On clicking the button a message will be sent to the machine at Head Office which should contain the IP address of the machine. I hope it is clear now. :)

Well then did the simple Winsock control approach resolve the question?

If so you can mark this revolved via the Thread Tools menu above.

Quote:

---

Originally Posted by svg3414

Well I will clarify. The situation is something like this.

My company has some 200 branches with some 1200 machines connected on a WAN. The Head Office will send periodical statements to the branches. When a statement arrives, a window will pop up on the branch machine and the user has to click a button. On clicking the button a message will be sent to the machine at Head Office which should contain the IP address of the machine. I hope it is clear now. :)

---

That being the situation I might suggest the following, knowing the IP could change and it sounds like you want proof that a specific machine clicked ok. (e.g. IP addresses can/will probably change. DHCP and all...)

Assuming the machine name would suffice you could easily use something like this.....

vb Code:

Private Sub Command1_Click()
    Dim strMachineName  As String
    strMachineName = Environ$("COMPUTERNAME")
    ' Send your message here
End Sub

I knew I had this code some where. I do not recall where I picked this up, I am not the author.

So, just in case you MUST have the IP address.....

vb Code:

Option Explicit
 
Public Const MAX_WSADescription As Long = 256
Public Const MAX_WSASYSStatus As Long = 128
Public Const ERROR_SUCCESS       As Long = 0
Public Const WS_VERSION_REQD     As Long = &H101
Public Const WS_VERSION_MAJOR    As Long = WS_VERSION_REQD \ &H100 And &HFF&
Public Const WS_VERSION_MINOR    As Long = WS_VERSION_REQD And &HFF&
Public Const MIN_SOCKETS_REQD    As Long = 1
Public Const SOCKET_ERROR        As Long = -1
 
Public Type HOSTENT
   hName      As Long
   hAliases   As Long
   hAddrType  As Integer
   hLen       As Integer
   hAddrList  As Long
End Type
 
Public Type WSADATA
   wVersion      As Integer
   wHighVersion  As Integer
   szDescription(0 To MAX_WSADescription)   As Byte
   szSystemStatus(0 To MAX_WSASYSStatus)    As Byte
   wMaxSockets   As Integer
   wMaxUDPDG     As Integer
   dwVendorInfo  As Long
End Type
 
Public Declare Function WSAGetLastError Lib "wsock32" () As Long
 
Public Declare Function WSAStartup Lib "wsock32" _
  (ByVal wVersionRequired As Long, _
   lpWSADATA As WSADATA) As Long
 
Public Declare Function WSACleanup Lib "wsock32" () As Long
 
Public Declare Function gethostname Lib "wsock32" _
  (ByVal szHost As String, _
   ByVal dwHostLen As Long) As Long
 
Public Declare Function gethostbyname Lib "wsock32" _
  (ByVal szHost As String) As Long
 
Public Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (hpvDest As Any, _
   ByVal hpvSource As Long, _
   ByVal cbCopy As Long)
 
 
Public Function GetIPAddress() As String
 
   Dim sHostName    As String * 256
   Dim lpHost    As Long
   Dim HOST      As HOSTENT
   Dim dwIPAddr  As Long
   Dim tmpIPAddr() As Byte
   Dim i         As Integer
   Dim sIPAddr  As String
 
   If Not SocketsInitialize() Then
      GetIPAddress = ""
      Exit Function
   End If
 
  'gethostname returns the name of the local host into
  'the buffer specified by the name parameter. The host
  'name is returned as a null-terminated string. The
  'form of the host name is dependent on the Windows
  'Sockets provider - it can be a simple host name, or
  'it can be a fully qualified domain name. However, it
  'is guaranteed that the name returned will be successfully
  'parsed by gethostbyname and WSAAsyncGetHostByName.
 
  'In actual application, if no local host name has been
  'configured, gethostname must succeed and return a token
  'host name that gethostbyname or WSAAsyncGetHostByName
  'can resolve.
   If gethostname(sHostName, 256) = SOCKET_ERROR Then
      GetIPAddress = ""
      MsgBox "Windows Sockets error " & Str(WSAGetLastError()) & _
              " has occurred. Unable to successfully get Host Name."
      SocketsCleanup
      Exit Function
   End If
 
  'gethostbyname returns a pointer to a HOSTENT structure
  '- a structure allocated by Windows Sockets. The HOSTENT
  'structure contains the results of a successful search
  'for the host specified in the name parameter.
 
  'The application must never attempt to modify this
  'structure or to free any of its components. Furthermore,
  'only one copy of this structure is allocated per thread,
  'so the application should copy any information it needs
  'before issuing any other Windows Sockets function calls.
 
  'gethostbyname function cannot resolve IP address strings
  'passed to it. Such a request is treated exactly as if an
  'unknown host name were passed. Use inet_addr to convert
  'an IP address string the string to an actual IP address,
  'then use another function, gethostbyaddr, to obtain the
  'contents of the HOSTENT structure.
   sHostName = Trim$(sHostName)
   lpHost = gethostbyname(sHostName)
 
   If lpHost = 0 Then
      GetIPAddress = ""
      MsgBox "Windows Sockets are not responding. " & _
              "Unable to successfully get Host Name."
      SocketsCleanup
      Exit Function
   End If
 
  'to extract the returned IP address, we have to copy
  'the HOST structure and its members
   CopyMemory HOST, lpHost, Len(HOST)
   CopyMemory dwIPAddr, HOST.hAddrList, 4
 
  'create an array to hold the result
   ReDim tmpIPAddr(1 To HOST.hLen)
   CopyMemory tmpIPAddr(1), dwIPAddr, HOST.hLen
 
  'and with the array, build the actual address,
  'appending a period between members
   For i = 1 To HOST.hLen
      sIPAddr = sIPAddr & tmpIPAddr(i) & "."
   Next
 
  'the routine adds a period to the end of the
  'string, so remove it here
   GetIPAddress = Mid$(sIPAddr, 1, Len(sIPAddr) - 1)
 
   SocketsCleanup
 
End Function
 
 
Public Function GetIPHostName() As String
 
    Dim sHostName As String * 256
 
    If Not SocketsInitialize() Then
        GetIPHostName = ""
        Exit Function
    End If
 
    If gethostname(sHostName, 256) = SOCKET_ERROR Then
        GetIPHostName = ""
        MsgBox "Windows Sockets error " & Str(WSAGetLastError()) & _
                " has occurred.  Unable to successfully get Host Name."
        SocketsCleanup
        Exit Function
    End If
 
    GetIPHostName = Left$(sHostName, InStr(sHostName, Chr(0)) - 1)
    SocketsCleanup
 
End Function
 
 
Public Function HiByte(ByVal wParam As Integer) As Byte
 
  'note: VB4-32 users should declare this function As Integer
   HiByte = (wParam And &HFF00&) \ (&H100)
 
End Function
 
 
Public Function LoByte(ByVal wParam As Integer) As Byte
 
  'note: VB4-32 users should declare this function As Integer
   LoByte = wParam And &HFF&
 
End Function
 
 
Public Sub SocketsCleanup()
 
    If WSACleanup() <> ERROR_SUCCESS Then
        MsgBox "Socket error occurred in Cleanup."
    End If
 
End Sub
 
Public Function SocketsInitialize() As Boolean
 
   Dim WSAD As WSADATA
   Dim sLoByte As String
   Dim sHiByte As String
 
   If WSAStartup(WS_VERSION_REQD, WSAD) <> ERROR_SUCCESS Then
      MsgBox "The 32-bit Windows Socket is not responding."
      SocketsInitialize = False
      Exit Function
   End If
 
 
   If WSAD.wMaxSockets < MIN_SOCKETS_REQD Then
        MsgBox "This application requires a minimum of " & _
                CStr(MIN_SOCKETS_REQD) & " supported sockets."
 
        SocketsInitialize = False
        Exit Function
    End If
 
 
   If LoByte(WSAD.wVersion) < WS_VERSION_MAJOR Or _
     (LoByte(WSAD.wVersion) = WS_VERSION_MAJOR And _
      HiByte(WSAD.wVersion) < WS_VERSION_MINOR) Then
 
      sHiByte = CStr(HiByte(WSAD.wVersion))
      sLoByte = CStr(LoByte(WSAD.wVersion))
 
      MsgBox "Sockets version " & sLoByte & "." & sHiByte & _
             " is not supported by 32-bit Windows Sockets."
 
      SocketsInitialize = False
      Exit Function
 
   End If
 
 
  'must be OK, so lets do it
   SocketsInitialize = True
 
End Function

Quote:

---

Originally Posted by Darren M.

That being the situation I might suggest the following, knowing the IP could change and it sounds like you want proof that a specific machine clicked ok. (e.g. IP addresses can/will probably change. DHCP and all...)

Assuming the machine name would suffice you could easily use something like this.....

vb Code:

Private Sub Command1_Click()
    Dim strMachineName  As String
    strMachineName = Environ$("COMPUTERNAME")
    ' Send your message here
End Sub

---

This may not suffice because more than one machine may have the same Computername. Anyway thanks for the suggestion. I can use it for some other purpose.:)

Quote:

---

Originally Posted by Darren M.

I knew I had this code some where. I do not recall where I picked this up, I am not the author.

So, just in case you MUST have the IP address.....

vb Code:

Option Explicit
 
Public Const MAX_WSADescription As Long = 256
Public Const MAX_WSASYSStatus As Long = 128
Public Const ERROR_SUCCESS       As Long = 0
Public Const WS_VERSION_REQD     As Long = &H101
Public Const WS_VERSION_MAJOR    As Long = WS_VERSION_REQD \ &H100 And &HFF&
Public Const WS_VERSION_MINOR    As Long = WS_VERSION_REQD And &HFF&
Public Const MIN_SOCKETS_REQD    As Long = 1
Public Const SOCKET_ERROR        As Long = -1
 
Public Type HOSTENT
   hName      As Long
   hAliases   As Long
   hAddrType  As Integer
   hLen       As Integer
   hAddrList  As Long
End Type
 
Public Type WSADATA
   wVersion      As Integer
   wHighVersion  As Integer
   szDescription(0 To MAX_WSADescription)   As Byte
   szSystemStatus(0 To MAX_WSASYSStatus)    As Byte
   wMaxSockets   As Integer
   wMaxUDPDG     As Integer
   dwVendorInfo  As Long
End Type
 
Public Declare Function WSAGetLastError Lib "wsock32" () As Long
 
Public Declare Function WSAStartup Lib "wsock32" _
  (ByVal wVersionRequired As Long, _
   lpWSADATA As WSADATA) As Long
 
Public Declare Function WSACleanup Lib "wsock32" () As Long
 
Public Declare Function gethostname Lib "wsock32" _
  (ByVal szHost As String, _
   ByVal dwHostLen As Long) As Long
 
Public Declare Function gethostbyname Lib "wsock32" _
  (ByVal szHost As String) As Long
 
Public Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (hpvDest As Any, _
   ByVal hpvSource As Long, _
   ByVal cbCopy As Long)
 
 
Public Function GetIPAddress() As String
 
   Dim sHostName    As String * 256
   Dim lpHost    As Long
   Dim HOST      As HOSTENT
   Dim dwIPAddr  As Long
   Dim tmpIPAddr() As Byte
   Dim i         As Integer
   Dim sIPAddr  As String
 
   If Not SocketsInitialize() Then
      GetIPAddress = ""
      Exit Function
   End If
 
  'gethostname returns the name of the local host into
  'the buffer specified by the name parameter. The host
  'name is returned as a null-terminated string. The
  'form of the host name is dependent on the Windows
  'Sockets provider - it can be a simple host name, or
  'it can be a fully qualified domain name. However, it
  'is guaranteed that the name returned will be successfully
  'parsed by gethostbyname and WSAAsyncGetHostByName.
 
  'In actual application, if no local host name has been
  'configured, gethostname must succeed and return a token
  'host name that gethostbyname or WSAAsyncGetHostByName
  'can resolve.
   If gethostname(sHostName, 256) = SOCKET_ERROR Then
      GetIPAddress = ""
      MsgBox "Windows Sockets error " & Str(WSAGetLastError()) & _
              " has occurred. Unable to successfully get Host Name."
      SocketsCleanup
      Exit Function
   End If
 
  'gethostbyname returns a pointer to a HOSTENT structure
  '- a structure allocated by Windows Sockets. The HOSTENT
  'structure contains the results of a successful search
  'for the host specified in the name parameter.
 
  'The application must never attempt to modify this
  'structure or to free any of its components. Furthermore,
  'only one copy of this structure is allocated per thread,
  'so the application should copy any information it needs
  'before issuing any other Windows Sockets function calls.
 
  'gethostbyname function cannot resolve IP address strings
  'passed to it. Such a request is treated exactly as if an
  'unknown host name were passed. Use inet_addr to convert
  'an IP address string the string to an actual IP address,
  'then use another function, gethostbyaddr, to obtain the
  'contents of the HOSTENT structure.
   sHostName = Trim$(sHostName)
   lpHost = gethostbyname(sHostName)
 
   If lpHost = 0 Then
      GetIPAddress = ""
      MsgBox "Windows Sockets are not responding. " & _
              "Unable to successfully get Host Name."
      SocketsCleanup
      Exit Function
   End If
 
  'to extract the returned IP address, we have to copy
  'the HOST structure and its members
   CopyMemory HOST, lpHost, Len(HOST)
   CopyMemory dwIPAddr, HOST.hAddrList, 4
 
  'create an array to hold the result
   ReDim tmpIPAddr(1 To HOST.hLen)
   CopyMemory tmpIPAddr(1), dwIPAddr, HOST.hLen
 
  'and with the array, build the actual address,
  'appending a period between members
   For i = 1 To HOST.hLen
      sIPAddr = sIPAddr & tmpIPAddr(i) & "."
   Next
 
  'the routine adds a period to the end of the
  'string, so remove it here
   GetIPAddress = Mid$(sIPAddr, 1, Len(sIPAddr) - 1)
 
   SocketsCleanup
 
End Function
 
 
Public Function GetIPHostName() As String
 
    Dim sHostName As String * 256
 
    If Not SocketsInitialize() Then
        GetIPHostName = ""
        Exit Function
    End If
 
    If gethostname(sHostName, 256) = SOCKET_ERROR Then
        GetIPHostName = ""
        MsgBox "Windows Sockets error " & Str(WSAGetLastError()) & _
                " has occurred.  Unable to successfully get Host Name."
        SocketsCleanup
        Exit Function
    End If
 
    GetIPHostName = Left$(sHostName, InStr(sHostName, Chr(0)) - 1)
    SocketsCleanup
 
End Function
 
 
Public Function HiByte(ByVal wParam As Integer) As Byte
 
  'note: VB4-32 users should declare this function As Integer
   HiByte = (wParam And &HFF00&) \ (&H100)
 
End Function
 
 
Public Function LoByte(ByVal wParam As Integer) As Byte
 
  'note: VB4-32 users should declare this function As Integer
   LoByte = wParam And &HFF&
 
End Function
 
 
Public Sub SocketsCleanup()
 
    If WSACleanup() <> ERROR_SUCCESS Then
        MsgBox "Socket error occurred in Cleanup."
    End If
 
End Sub
 
Public Function SocketsInitialize() As Boolean
 
   Dim WSAD As WSADATA
   Dim sLoByte As String
   Dim sHiByte As String
 
   If WSAStartup(WS_VERSION_REQD, WSAD) <> ERROR_SUCCESS Then
      MsgBox "The 32-bit Windows Socket is not responding."
      SocketsInitialize = False
      Exit Function
   End If
 
 
   If WSAD.wMaxSockets < MIN_SOCKETS_REQD Then
        MsgBox "This application requires a minimum of " & _
                CStr(MIN_SOCKETS_REQD) & " supported sockets."
 
        SocketsInitialize = False
        Exit Function
    End If
 
 
   If LoByte(WSAD.wVersion) < WS_VERSION_MAJOR Or _
     (LoByte(WSAD.wVersion) = WS_VERSION_MAJOR And _
      HiByte(WSAD.wVersion) < WS_VERSION_MINOR) Then
 
      sHiByte = CStr(HiByte(WSAD.wVersion))
      sLoByte = CStr(LoByte(WSAD.wVersion))
 
      MsgBox "Sockets version " & sLoByte & "." & sHiByte & _
             " is not supported by 32-bit Windows Sockets."
 
      SocketsInitialize = False
      Exit Function
 
   End If
 
 
  'must be OK, so lets do it
   SocketsInitialize = True
 
End Function

---

I will try this out and inform. Thanks a lot.

Quote:

---

Originally Posted by dilettante

Well then did the simple Winsock control approach resolve the question?

If so you can mark this revolved via the Thread Tools menu above.

---

The method works. I have tried it on a Win XP machine.

But since it requires the winsock control, I would like to know whether it will work on a Win 7 machine. If not how can I make it work?

Quote:

---

Originally Posted by svg3414

The method works. I have tried it on a Win XP machine.

But since it requires the winsock control, I would like to know whether it will work on a Win 7 machine. If not how can I make it work?

---

I forgot to mention I was using Windows 7 when I posted the posts above. So, yes, that code does work in Windows 7.

Edit:

That is I tested the code before posting it.