[RESOLVED] Minimum height for menu bar to be visible?

I want to start an application with the main form shrunken such that only the title bar and the menu bar are visible. Later on the full form height is to be restored.

How do I figure out the height of the menu bar avoiding manual trial and error at design time?

Quote:

---

Originally Posted by krtxmrtz

I want to start an application with the main form shrunken such that only the title bar and the menu bar are visible. Later on the full form height is to be restored.

How do I figure out the height of the menu bar avoiding manual trial and error at design time?

---

Oh, well, I've just realized that

Me.Height = Me.Height - Screen.TwipsPerPixelY * Me.ScaleHeight

allows the menu bar to be visible (I'd thought only the title bar would)

Resolved!

As long as your form initially has a client area, your solution should work fine. But if form starts out where .ScaleHeight is zero, your form won't resize using that logic. Just FYI

Quote:

---

Originally Posted by LaVolpe

As long as your form initially has a client area, your solution should work fine. But if form starts out where .ScaleHeight is zero, your form won't resize using that logic. Just FYI

---

Thanks, I wasn't aware of that of course.

In order to have a visible menu I have tried

Me.Height = CInt(1.6 * Me.Height)

where Me.Height is the design time form height with SceleHeight=0 and the munus are visible. But it seems to me an ugly way to do it and I'd rather find out the correct menu height in case it's available from some metrics related api function.

GetMenuBarInfo API (Win2K and higher) can do it for you. It should take into consideration the font/size used which can be different from computer to computer.

Quote:

---

Originally Posted by LaVolpe

GetMenuBarInfo API (Win2K and higher) can do it for you. It should take into consideration the font/size used which can be different from computer to computer.

---

Searching around I found some examples from which I tried this code on a form with a menu bar with 2 main menus, one of them with 2 submenus:

VB Code:

Private Type rect
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Type MENUBARINFO
  cbSize As Byte
  rcBar As rect
  hMenu As Long
  hwndMenu As Long
  fBarFocused As Boolean
  fFocused As Boolean
End Type
Private MenuInfo As MENUBARINFO
Private Const OBJID_MENU As Long = &HFFFFFFFD
Private Const OBJID_SYSMENU As Long = &HFFFFFFFF
Private Declare Function GetMenuBarInfo Lib "user32" (ByVal hwnd As Long, _
ByVal idObject As Long, ByVal idItem As Long, ByRef pmbi As MENUBARINFO) As Boolean
Private Declare Function GetMenu Lib "user32" (ByVal hwnd As Long) As Long
 
Private Sub Command1_Click()
 
    MenuInfo.cbSize = Len(MenuInfo)
    If GetMenuBarInfo(GetMenu(Me.hwnd), OBJID_MENU, 0, MenuInfo) Then
    
        With MenuInfo.rcBar
        
            Debug.Print "Left: " & CStr(.Left)
            Debug.Print "Right: " & CStr(.Right)
            Debug.Print "Top: " & CStr(.Top)
            Debug.Print "Bottom: " & CStr(.Bottom)
            
        End With
        
    End If
    
End Sub

But GetMenuBarInfo returns False for some reason :(

1. cbSize As Long, not as Byte

2. The call would look like this to get your form's menubar size
GetMenuBarInfo(Me.hwnd, OBJID_MENU, 0, MenuInfo)

3. Submenus are not a player. Submenus are only shown if the menu is activated. Where submenus may come into play is if you want to get the size of the menu box that the submenu will display in once activated

Quote:

---

Originally Posted by LaVolpe

1. cbSize As Long, not as Byte

2. The call would look like this to get your form's menubar size
GetMenuBarInfo(Me.hwnd, OBJID_MENU, 0, MenuInfo)

3. Submenus are not a player. Submenus are only shown if the menu is activated. Where submenus may come into play is if you want to get the size of the menu box that the submenu will display in once activated

---

Still False. Have you tried if it works?

Quote:

---

Originally Posted by krtxmrtz

Still False. Have you tried if it works?

---

Yes, I've used it before. Though I used Integer instead of Boolean for the structure members and Long as the the API's return value. Ensure you are passing the window Hwnd not a menu handle as the 1st parameter. I cannot give you an example today -- rebuilding my PC & won't have VB up & running until late today or tomorrow

Quote:

---

Originally Posted by LaVolpe

1. cbSize As Long, not as Byte

2. The call would look like this to get your form's menubar size
GetMenuBarInfo(Me.hwnd, OBJID_MENU, 0, MenuInfo)...

---

I can't say I did as you suggested... I used Me.hwnd but then forgot to change long to byte in the cbSize declaration. Sheer absent-mindedness, sorry.

Now it works. I assume the returned values are the rectangle coordinates relative to the screen's upper left corner.

I attach the final typo-free working version for someone's future reference.

VB Code:

Private Type rect
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Type MENUBARINFO
  cbSize As Long
  rcBar As rect
  hMenu As Long
  hwndMenu As Long
  fBarFocused As Boolean
  fFocused As Boolean
End Type
Private MenuInfo As MENUBARINFO
Private Const OBJID_MENU As Long = &HFFFFFFFD
Private Const OBJID_SYSMENU As Long = &HFFFFFFFF
Private Declare Function GetMenuBarInfo Lib "user32" (ByVal hwnd As Long, _
ByVal idObject As Long, ByVal idItem As Long, ByRef pmbi As MENUBARINFO) As Boolean
Private Declare Function GetMenu Lib "user32" (ByVal hwnd As Long) As Long
Private Sub Command1_Click()
 
    MenuInfo.cbSize = Len(MenuInfo)
    
    If GetMenuBarInfo(Me.hwnd, OBJID_MENU, 0, MenuInfo) Then
   
        With MenuInfo.rcBar
       
            Debug.Print "Left: " & CStr(.Left)
            Debug.Print "Right: " & CStr(.Right)
            Debug.Print "Top: " & CStr(.Top)
            Debug.Print "Bottom: " & CStr(.Bottom)
           
        End With
       
    End If
   
End Sub