Using the registry

[Neandrake]

I'm trying to delete a value in the registry in my program, but I have a question. The RegDeleteValue key will work but it only has two parameters. The hKey and the Value. If I want to delete a key in say HKEY_CURRENT_USER\Software\MyCompany then how do I put that in hKey? I've tried HKEY_CURRENT_USER & "Software\MyCompany" but that doesn't seem to work. What to do?

[chrisjk]

Try it like this:

Private Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Private Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
 
Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003
Const HKEY_PERFORMANCE_DATA = &H80000004
Const HKEY_CURRENT_CONFIG = &H80000005
Const HKEY_DYN_DATA = &H80000006
 
Private Sub DelSetting(hKey As Long, strPath As String, strValue As String)
 
Dim Ret
 
'Create a new key
RegCreateKey hKey, strPath, Ret
 
'Delete the key's value
RegDeleteValue Ret, strValue
 
'close the key
RegCloseKey Ret
 
End Sub
 
Private Sub Command1_Click()
 
DelSetting HKEY_LOCAL_MACHINE, "MyKey\MySubKey", "MyStringValue"
 
End Sub

[Megatron]

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal HKEY As Long) As Long
Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String) As Long
Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal HKEY As Long, ByVal lpValueName As String) As Long
Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal HKEY As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal HKEY As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Public Const HKEY_PERFORMANCE_DATA = &H80000004
Public Const REG_SZ = 1
 
Function RegQueryStringValue(ByVal HKEY As Long, ByVal strValueName As String)
    Dim lResult As Long
    Dim lValueType As Long
    Dim strBuf As String
    Dim lDataBufSize As Long
    
    On Error GoTo 0
    lResult = RegQueryValueEx(HKEY, strValueName, 0&, lValueType, ByVal 0&, lDataBufSize)
    If lResult = ERROR_SUCCESS Then
        If lValueType = REG_SZ Then
            strBuf = String(lDataBufSize, " ")
            lResult = RegQueryValueEx(HKEY, strValueName, 0&, 0&, ByVal strBuf, lDataBufSize)
            If lResult = ERROR_SUCCESS Then
                RegQueryStringValue = StripTerminator(strBuf)
            End If
        End If
    End If
End Function
 
Public Function GetSettingEx(HKEY As Long, sPath As String, sValue As String)
    Dim KeyHand&
    Dim datatype&
    Call RegOpenKey(HKEY, sPath, KeyHand&)
    GetSettingEx = RegQueryStringValue(KeyHand&, sValue)
    Call RegCloseKey(KeyHand&)
End Function
 
Function StripTerminator(ByVal strString As String) As String
    Dim intZeroPos As Integer
 
    intZeroPos = InStr(strString, Chr$(0))
    If intZeroPos > 0 Then
        StripTerminator = Left$(strString, intZeroPos - 1)
    Else
        StripTerminator = strString
    End If
End Function
 
Public Sub SaveSettingEx(HKEY As Long, sPath As String, sValue As String, sData As String)
    Dim KeyHand As Long
    Call RegCreateKey(HKEY, sPath, KeyHand)
    Call RegSetValueEx(KeyHand&, sValue, 0, REG_SZ, ByVal sData, Len(sData))
    Call RegCloseKey(KeyHand&)
End Sub
 
 
'Save a Value to the Registry
SaveSettingEx HKEY_CURRENT_USER, "Software\Myapp", "Testing", "Hello"
 
 
'Get a value from the Registry
Retval = GetSettingEx(HKEY_CURRENT_USER, "Software\Myapp", "Testing")

[chrisjk]

That's lovely megatron, but he only wanted to delete a value, nothing else

[Neandrake]

Thanks alot, I've managed. I was wondering where to get a list of all the data types acceptable for the registry. Like how REG_SZ = 1 and I think I saw somewhere REG_BINARY = 3. Where's the rest of them? Thanks

[chrisjk]

Here are some...

Public Const REG_SZ = 1                         ' Unicode nul terminated string
Public Const REG_BINARY = 3                     ' Free form binary
Public Const REG_DWORD = 4                      ' 32-bit number
Public Const ERROR_SUCCESS = 0&