[RESOLVED] Minimize to Sys Tray

[fEtchboi88]

When you click the "Lock" menu item in my program, I want it to minimize to the system tray, then show the Login form when you click the system tray icon. It works fine, except it doesn't detect the "MouseMove" event when you click the icon.

Here's my Code:

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Dim msg As Long
    Dim sFilter As String
    
    msg = X / Screen.TwipsPerPixelX
    
    Select Case msg
        Case WM_LBUTTONDOWN
            frmLogin.Show
            Shell_NotifyIcon NIM_DELETE, nid ' del tray icon
        Case WM_LBUTTONUP
        Case WM_LBUTTONDBLCLK
        Case WM_RBUTTONDOWN
        Case WM_RBUTTONUP
            frmLogin.Show
            Shell_NotifyIcon NIM_DELETE, nid
        Case WM_RBUTTONDBLCLK
    End Select
    
End Sub

Public Type NOTIFYICONDATA
cbSize As Long
hwnd As Long
uId As Long
uFlags As Long
uCallBackMessage As Long
hIcon As Long
szTip As String * 64
End Type

Public nid As NOTIFYICONDATA

Public Const NIM_ADD = &H0
Public Const NIM_MODIFY = &H1
Public Const NIM_DELETE = &H2
Public Const WM_MOUSEMOVE = &H200
Public Const NIF_MESSAGE = &H1
Public Const NIF_ICON = &H2
Public Const NIF_TIP = &H4
Public Const WM_LBUTTONDBLCLK = &H203 'Double-click
Public Const WM_LBUTTONDOWN = &H201 'Button down
Public Const WM_LBUTTONUP = &H202 'Button up
Public Const WM_RBUTTONDBLCLK = &H206 'Double-click
Public Const WM_RBUTTONDOWN = &H204 'Button down
Public Const WM_RBUTTONUP = &H205 'Button up

Public Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean

Sub minimize_to_tray()
    Me.Hide
    nid.cbSize = Len(nid)
    nid.hwnd = Me.hwnd
    nid.uId = vbNull
    nid.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    nid.uCallBackMessage = WM_MOUSEMOVE
    nid.hIcon = Me.Icon ' the icon will be your Form1 project icon
    nid.szTip = "Sun Life Dashboard" & vbNullChar
    Shell_NotifyIcon NIM_ADD, nid
End Sub

[Edgemeal]

Is the Form scale mode in Pixels or Twips?
Most people write the MouseMove part like this,

   If Me.ScaleMode = vbPixels Then    
        Msg = x
    Else
        Msg = x / Screen.TwipsPerPixelX
    End If

I usually add a picture box set to pixel scalemode and just use the X variable, set the tray icon code to point to the pic Hwnd and use the pic box mouse move event, it just works better, especially on borderless forms for some reason.

[fEtchboi88]

Worked like a charm!!! Thanx!!