[CR .NET 2k5 Edition] Printing Crystal Reports via code.

[Jenner]

One thing that has baffled me in the past was I could not figure out how to print a Crystal Report without first sending it to the CRViewer first. Basically, I want to put a big "Print" button on my forms that would send the things straight to printer, do not pass Go, do not collect $200.

My implementation of Crystal Reports is that I first pull a DataSet from the database with given parameters. Then I declare a new report object and load in the corresponding *.rpt file that was built using the schema.xml from that dataset. I pass the report any additional parameters it might need and send the thing to the CRViewer.

Assuming I can create that Report document object and populate it as I have been, does anyone have a code-example of popping a printer select dialog and upon exit, sending it off to the printer of choice w/o having to go through the CRViewer?

Any help would be most appreciated. I can provide code samples if required.

[GaryMazzone]

Here is the sub I use: (I connect to the db change were required)

Public Sub outputToPrinter(ByVal mRepName As String, ByVal mstrW As String, Optional ByVal strPars As String = "")
        Dim ConInfo As New CrystalDecisions.Shared.TableLogOnInfo
        Dim paraValue As New CrystalDecisions.Shared.ParameterDiscreteValue
        Dim currValue As New CrystalDecisions.Shared.ParameterValues
        'Sub report object of crystal report.
        Dim mySubReportObject As CrystalDecisions.CrystalReports.Engine.SubreportObject
        'Sub report document of crystal report.
        Dim mySubRepDoc As New CrystalDecisions.CrystalReports.Engine.ReportDocument
        Dim i, x, z As Integer 'Some Counters
        Dim mRep As New CrystalDecisions.CrystalReports.Engine.ReportDocument
 
        Try
            ' Load the report
            'Need to add the Report dll yet nothing works
            Dim rep As New RSMReports.clsReports(mRepName)
            mRep = rep.returnRep()
            mRep.RecordSelectionFormula = mstrW
 
            ConInfo.ConnectionInfo.UserID = "UserName"
            ConInfo.ConnectionInfo.Password = "Password"
            ConInfo.ConnectionInfo.ServerName = mdlGeneral.serverName
            ConInfo.ConnectionInfo.DatabaseName = mdlGeneral.dbName
 
            For i = 0 To mRep.Database.Tables.Count() - 1
                mRep.Database.Tables(i).ApplyLogOnInfo(ConInfo)
            Next i
 
            'Check for Subreprots
            For i = 0 To mRep.ReportDefinition.Sections.Count - 1
                For x = 0 To mRep.ReportDefinition.Sections(i).ReportObjects.Count - 1
                    With mRep.ReportDefinition.Sections(i)
                        If .ReportObjects(x).Kind = CrystalDecisions.Shared.ReportObjectKind.SubreportObject Then
                            mySubReportObject = CType(.ReportObjects(x), CrystalDecisions.CrystalReports.Engine.SubreportObject)
                            mySubRepDoc = mySubReportObject.OpenSubreport(mySubReportObject.SubreportName)
                            For z = 0 To mySubRepDoc.Database.Tables.Count - 1
                                mySubRepDoc.Database.Tables(z).ApplyLogOnInfo(ConInfo)
                            Next z
                        End If
                    End With
                Next x
            Next i
            'Parameter Fields
            If strPars.Trim() <> String.Empty Then
                Dim arPars As String() = strPars.Split("~")
                Dim strVal As String()
                For xx As Integer = 0 To arPars.GetUpperBound(0)
                    strVal = arPars(xx).Split("=")
                    paraValue.Value = strVal(1)
                    currValue = mRep.DataDefinition.ParameterFields(strVal(0)).CurrentValues
                    currValue.Add(paraValue)
                    mRep.DataDefinition.ParameterFields(xx).ApplyCurrentValues(currValue)
                Next
            End If
            mRep.PrintToPrinter(1, False, 0, 0)
        Catch crExp As CrystalDecisions.CrystalReports.Engine.LoadSaveReportException
            MessageBox.Show("Error printing Report " & mRepName & System.Environment.NewLine & _
                "The error number is: " & Err.Number.ToString() & System.Environment.NewLine & _
                "The error Message is: " & System.Environment.NewLine & crExp.Message.Trim(), "Print Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ex As Exception
            MessageBox.Show("Error printing Report " & mRepName & System.Environment.NewLine & _
                            "The error number is: " & Err.Number.ToString() & System.Environment.NewLine & _
                            "The error Message is: " & System.Environment.NewLine & ex.Message.Trim(), "Print Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            mRep.Dispose()
        End Try
    End Sub

[Jenner]

Hmm... unfortunately, I just tried PrintToPrinter and it didn't do anything at all. No error, no print...

Here's my code that I tried minus some extra selection / options criteria to make it easier to see the parts that matter.

    Private Sub CostCustomerShow()
        Dim strSQL As String = String.Empty
        Dim ds As New DataSet

        Dim cRpt As New CrystalDecisions.CrystalReports.Engine.ReportDocument
        Dim strRpt As String = String.Format("{0}\Reports\CpCust\{1}", Application.StartupPath, g.SELECTED_CUSTCOST_REPORT)

        cRpt.Load(strRpt, CrystalDecisions.Shared.OpenReportMethod.OpenReportByTempCopy)

        Dim mCon As MySql.Data.MySqlClient.MySqlConnection
        mCon = CType(ReturnGlobalMCon(), MySql.Data.MySqlClient.MySqlConnection)


        strSQL = String.Format("SELECT * FROM FormulaUse WHERE UseDate BETWEEN '{0:yyyy-MM-dd}' AND '{1:yyyy-MM-dd}'; ", dtpCostFrom.Value, dtpCostTo.Value)
        strSQL &= "SELECT * FROM CustomerList; "

        Dim da As New MySql.Data.MySqlClient.MySqlDataAdapter(strSQL, mCon)
        da.Fill(ds)

        cRpt.SetDataSource(ds)
        cRpt.SetParameterValue("From", dtpCostFrom.Value)
        cRpt.SetParameterValue("To", dtpCostTo.Value)
        cRpt.SetParameterValue("Units", g.UNITS & "s")

        cRpt.PrintToPrinter(1, False, 0, 0)

        'crViewer.ReportSource = cRpt
        'crViewer.Zoom(1)

        da.Dispose()
        mCon.Close()
    End Sub

[Jenner]

Shameless bump... still unresolved.

Anybody know this one? I refuse to accept that I can only get the stupid thing to print while being displayed in the viewer. I messed with it for about 4 hours today and got nowhere. I even tried a variation of Mazz1's routine and couldn't get it to happen.

[ducky]

It may be that the printer that the report was designed with is not found in your local printers on your machine. Try setting the printer to a valid printer to print to via code just before the printtoprinter command.

'set the printer name
Dim CrPrintOptions As PrintOptions = CRpt.PrintOptions
CrPrintOptions.PrinterName = "My favorite printer"

'send the report to the printer
CRpt.PrintToPrinter(1, False, 1, -1)