Crystal Reporting and database path

[glug]

Hi Guys

I set up a report using the report wizard and access DB. After i installed the program on another pc it tries to find the DB using the path thats on my pc.
How can i fix this so the path will be at my.application.info.directoryPath. Do i have to create the report all from code.

Thanks

[GaryMazzone]

What version of VB, and CR? You should have access to the Connection Info properties of the report and can set the database path and name there

[glug]

Im using visual studio 2005 pro, and Crystal reports that come with this, 10.2
I created the Reports at design time so the database is already assigned to the Report.rpt. I just need to set the past diffrent from the one already set else every pc i install this software on, it will look for the database on "e:\Development" where i need the software to look for the DB on My.Application.Info.Directory

Im not sure how to set the Path.

[GaryMazzone]

There are post in this section on chaning the database location (path). You need to use a Sub that will modify the ConnectionInfo property of the report for each table in the report and each sub report (and its tables) in that main report.

This is the code I use (this SQL Server):

Imports CrystalDecisions.Shared
 
    Public Sub outputToPrinter(ByVal mRepName As String, ByVal mstrW As String, Optional ByVal strPars As String = "")
        Dim ConInfo As New CrystalDecisions.Shared.TableLogOnInfo
        Dim paraValue As New CrystalDecisions.Shared.ParameterDiscreteValue
        Dim currValue As New CrystalDecisions.Shared.ParameterValues
        'Sub report object of crystal report.
        Dim mySubReportObject As CrystalDecisions.CrystalReports.Engine.SubreportObject
        'Sub report document of crystal report.
        Dim mySubRepDoc As New CrystalDecisions.CrystalReports.Engine.ReportDocument
        Dim i, x, z As Integer 'Some Counters
        Dim mRep As New CrystalDecisions.CrystalReports.Engine.ReportDocument
 
        Try
            ' Load the report
            'Need to add the Report dll yet nothing works
            Dim rep As New RSMReports.clsReports(mRepName)
            mRep = rep.returnRep()
            mRep.RecordSelectionFormula = mstrW
 
            ConInfo.ConnectionInfo.UserID = UserName
            ConInfo.ConnectionInfo.Password = Password
            ConInfo.ConnectionInfo.ServerName = mdlGeneral.serverName
            ConInfo.ConnectionInfo.DatabaseName = mdlGeneral.dbName
 
            For i = 0 To mRep.Database.Tables.Count() - 1
                mRep.Database.Tables(i).ApplyLogOnInfo(ConInfo)
            Next i
 
            'Check for Subreprots
            For i = 0 To mRep.ReportDefinition.Sections.Count - 1
                For x = 0 To mRep.ReportDefinition.Sections(i).ReportObjects.Count - 1
                    With mRep.ReportDefinition.Sections(i)
                        If .ReportObjects(x).Kind = CrystalDecisions.Shared.ReportObjectKind.SubreportObject Then
                            mySubReportObject = CType(.ReportObjects(x), CrystalDecisions.CrystalReports.Engine.SubreportObject)
                            mySubRepDoc = mySubReportObject.OpenSubreport(mySubReportObject.SubreportName)
                            For z = 0 To mySubRepDoc.Database.Tables.Count - 1
                                mySubRepDoc.Database.Tables(z).ApplyLogOnInfo(ConInfo)
                            Next z
                        End If
                    End With
                Next x
            Next i
            'Parameter Fields
            If strPars.Trim() <> String.Empty Then
                Dim arPars As String() = strPars.Split("~")
                Dim strVal As String()
                For xx As Integer = 0 To arPars.GetUpperBound(0)
                    strVal = arPars(xx).Split("=")
                    paraValue.Value = strVal(1)
                    currValue = mRep.DataDefinition.ParameterFields(strVal(0)).CurrentValues
                    currValue.Add(paraValue)
                    mRep.DataDefinition.ParameterFields(xx).ApplyCurrentValues(currValue)
                Next
            End If
            mRep.PrintToPrinter(1, False, 0, 0)
        Catch crExp As CrystalDecisions.CrystalReports.Engine.LoadSaveReportException
            MessageBox.Show("Error printing Report " & mRepName & System.Environment.NewLine & _
                "The error number is: " & Err.Number.ToString() & System.Environment.NewLine & _
                "The error Message is: " & System.Environment.NewLine & crExp.Message.Trim(), "Print Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ex As Exception
            MessageBox.Show("Error printing Report " & mRepName & System.Environment.NewLine & _
                            "The error number is: " & Err.Number.ToString() & System.Environment.NewLine & _
                            "The error Message is: " & System.Environment.NewLine & ex.Message.Trim(), "Print Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            mRep.Dispose()
        End Try
    End Sub