Enumerating Network Addresses

[amitabh]

How do I determine all the IP addresses present in my network?

[Babbalouie]

I have a solution, maybe not the BEST solution, but it would work. First, you'd have to get all the computers on the network:



Public Function GetComputersInADomain(aryUsers() As String) As Long

'Notes: Requires a global array to be pased in if list of users wanted
'Notes: Very slow if domain name not valid
'Notes: Must set reference to Active DS Type Library for this to work

Dim TheDomain As IADsDomain
Dim Computer As IADsComputer
Dim strDomain As String
Dim x As Long

'Accept the Domain name
strDomain = InputBox("Domain Name: ")

'Use the WinNT Directory Services
strDomain = "WinNT://" & strDomain

'Create the Domain object
Set TheDomain = GetObject(strDomain)

'Search for Computers in the Domain
TheDomain.Filter = Array("Computer")

'Enumerate each computer in the domain
For Each Computer In TheDomain
x = x + 1
ReDim Preserve aryUsers(x)
aryUsers(x) = Computer.Name
Next Computer

'Clean up
GetComputersInADomain = x
Set Computer = Nothing
Set TheDomain = Nothing

End Function



Part 2, getting the IP addresses, I'll send in a few moments...

[Babbalouie]

Once you do part 1, you will have a list of all the names in the domain. Pass each one of them into this bit of code, and it will return the IP address. The way this is written, it will only return one IP address at a time, but you could modify it to loop through all the computer names.


This will return the IP Address of another computer if you give the hostname.




code:--------------------------------------------------------------------------------'Author: Waty Thierry
'Author's email: http://www.geocities.com/ResearchTriangle/6311/
'Date Submitted: 3/30/99
'Compatibility: VB 6,VB 5,VB 4/32

'Task: Find IP address ginving the hostname

'Declarations
' #VBIDEUtils#************************************************************
' * Programmer Name : Waty Thierry
' * Web Site : http://www.geocities.com/ResearchTriangle/6311/
' * E-Mail : waty.thierry@usa.net
' * Date : 13/10/98
' * Time : 10:24
' * Module Name : IP_Module
' * Module Filename : IP.bas
' **********************************************************************
' * Comments :
' * Find IP address ginving the hostname
' **********************************************************************

'Here's sample code for gethostbyname()

'Add a textbox (Text1) And a Command button (Command1) To a New form And use the
following code:

'Usage: Fill in the textbox with the name you want to resolve and click the
command button to resolve the name.

Private Const WS_VERSION_REQD = &H101
Private Const WS_VERSION_MAJOR = WS_VERSION_REQD \ &H100 And &HFF&
Private Const WS_VERSION_MINOR = WS_VERSION_REQD And &HFF&
Private Const MIN_SOCKETS_REQD = 1
Private Const SOCKET_ERROR = -1
Private Const WSADescription_Len = 256
Private Const WSASYS_Status_Len = 128

Private Type HOSTENT
hName As Long
hAliases As Long
hAddrType As Integer
hLength As Integer
hAddrList As Long
End Type

Private Type WSADATA
wversion As Integer
wHighVersion As Integer
szDescription(0 To WSADescription_Len) As Byte
szSystemStatus(0 To WSASYS_Status_Len) As Byte
iMaxSockets As Integer
iMaxUdpDg As Integer
lpszVendorInfo As Long
End Type

Private Declare Function WSAGetLastError Lib "WSOCK32.DLL" () As Long
Private Declare Function WSAStartup Lib "WSOCK32.DLL" (ByVal wVersionRequired&,
lpWSAData As WSADATA) As Long
Private Declare Function WSACleanup Lib "WSOCK32.DLL" () As Long
Private Declare Function gethostbyname Lib "WSOCK32.DLL" (ByVal hostname$) As
Long
Private Declare Sub RtlMoveMemory Lib "KERNEL32" (hpvDest As Any, ByVal
hpvSource&, ByVal cbCopy&)



'Code:
' #VBIDEUtils#************************************************************
' * Programmer Name : Waty Thierry
' * Web Site : http://www.geocities.com/ResearchTriangle/6311/
' * E-Mail : waty.thierry@usa.net
' * Date : 13/10/98
' * Time : 10:24
' * Module Name : IP_Module
' * Module Filename : IP.bas
' **********************************************************************
' * Comments :
' * Find IP address ginving the hostname
' **********************************************************************

Function hibyte(ByVal wParam As Integer)

hibyte = wParam \ &H100 And &HFF&

End Function

Function lobyte(ByVal wParam As Integer)

lobyte = wParam And &HFF&

End Function

Sub SocketsInitialize()

Dim WSAD As WSADATA
Dim iReturn As Integer
Dim sLowByte As String, sHighByte As String, sMsg As String

iReturn = WSAStartup(WS_VERSION_REQD, WSAD)

If iReturn <> 0 Then
MsgBox "Winsock.dll is not responding."
End
End If

If lobyte(WSAD.wversion) < WS_VERSION_MAJOR Or (lobyte(WSAD.wversion) =
WS_VERSION_MAJOR And hibyte(WSAD.wversion) < WS_VERSION_MINOR) Then
sHighByte = Trim$(Str$(hibyte(WSAD.wversion)))
sLowByte = Trim$(Str$(lobyte(WSAD.wversion)))
sMsg = "Windows Sockets version " & sLowByte & "." & sHighByte
sMsg = sMsg & " is not supported by winsock.dll "
MsgBox sMsg
End
End If

If WSAD.iMaxSockets < MIN_SOCKETS_REQD Then
sMsg = "This application requires a minimum of "
sMsg = sMsg & Trim$(Str$(MIN_SOCKETS_REQD)) & " supported sockets."
MsgBox sMsg
End
End If

End Sub

Sub SocketsCleanup()
Dim lReturn As Long

lReturn = WSACleanup()

If lReturn <> 0 Then
MsgBox "Socket error " & Trim$(Str$(lReturn)) & " occurred in Cleanup "
End
End If

End Sub

Sub Form_Load()

SocketsInitialize

End Sub

Private Sub Form_Unload(Cancel As Integer)

SocketsCleanup

End Sub

Private Sub Command1_click()
Dim hostent_addr As Long
Dim host As HOSTENT
Dim hostip_addr As Long
Dim temp_ip_address() As Byte
Dim i As Integer
Dim ip_address As String

hostent_addr = gethostbyname(Text1)

If hostent_addr = 0 Then
MsgBox "Can't resolve name."
Exit Sub
End If

RtlMoveMemory host, hostent_addr, LenB(host)
RtlMoveMemory hostip_addr, host.hAddrList, 4

ReDim temp_ip_address(1 To host.hLength)
RtlMoveMemory temp_ip_address(1), hostip_addr, host.hLength

For i = 1 To host.hLength
ip_address = ip_address & temp_ip_address(i) & "."
Next
ip_address = Mid$(ip_address, 1, Len(ip_address) - 1)

MsgBox ip_address

End Sub