Registry Settings

[Mattyboy2000]

Can anyone let me know how to store values in the system registry?

[HeSaidJoe]

Save or Delete Settings

'
'one option of SaveSetting and GetSetting

Option Explicit
'


'to test this out
'make a std project
'add a textbox with "" value for text
'add command1 and command2
'run the app
'click command1
'click the x to unload the project
'reload the project and text1 will now have the text that
'was in it when you quit

'if you want to delete the save settings click on command2

Private Sub Command2_Click()
'this will delete it from the register if you are finished
'with playing with it

DeleteSetting "project1", "TextboxValue"

End Sub

Private Sub Form_Load()
'this will load it into the register
   Text1.Text = GetSetting("project1", "TextboxValue", "Value", 0)
End Sub


Private Sub Form_Unload(Cancel As Integer)
'this will save it into the register when you quit
    SaveSetting "project1", "TextboxValue", "Value", Text1.Text
End Sub


Private Sub Command1_Click()
'load the text1.text with whatever
    Text1.Text = "Shame on you, you went and dit it!"
End Sub

[chrisfricke]

Use the SaveSetting and GetSetting functions to save data

e.g

SaveSetting "Prog","Set","User","The data you want to save"
String=getsetting("Prog","Set","User","Default Data")

[jbart]

Just FYI.

You can look at the settings you save with the code posted above by running REGEDIT and looking under:

HKEY_CURRENT_USER\Software\VB and VBA Program Settings

[Mattyboy2000]

Top draw guys ! Thanks very much!

[parksie]

If you want to save them elsewhere (like in Software\My Company), then you need the API functions. I've got a load of code here: http://www.parksie.uklinux.net/registry.zip

If you want to store in different sections, use the following code.

Add this to a Module

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal HKEY As Long) As Long
Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String) As Long
Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal HKEY As Long, ByVal lpValueName As String) As Long
Declare Function RegOpenKey Lib "advapi32.dll" Alias "RegOpenKeyA" (ByVal HKEY As Long, ByVal lpSubKey As String, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal HKEY As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal HKEY As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_USERS = &H80000003
Public Const HKEY_PERFORMANCE_DATA = &H80000004
Public Const REG_SZ = 1

Function RegQueryStringValue(ByVal HKEY As Long, ByVal strValueName As String)
    Dim lResult As Long
    Dim lValueType As Long
    Dim strBuf As String
    Dim lDataBufSize As Long
    
    On Error GoTo 0
    lResult = RegQueryValueEx(HKEY, strValueName, 0&, lValueType, ByVal 0&, lDataBufSize)
    If lResult = ERROR_SUCCESS Then
        If lValueType = REG_SZ Then
            strBuf = String(lDataBufSize, " ")
            lResult = RegQueryValueEx(HKEY, strValueName, 0&, 0&, ByVal strBuf, lDataBufSize)
            If lResult = ERROR_SUCCESS Then
                RegQueryStringValue = StripTerminator(strBuf)
            End If
        End If
    End If
End Function

Public Function GetSettingEx(HKEY As Long, sPath As String, sValue As String)
    Dim KeyHand&
    Dim datatype&
    Call RegOpenKey(HKEY, sPath, KeyHand&)
    GetSettingEx = RegQueryStringValue(KeyHand&, sValue)
    Call RegCloseKey(KeyHand&)
End Function

Function StripTerminator(ByVal strString As String) As String
    Dim intZeroPos As Integer

    intZeroPos = InStr(strString, Chr$(0))
    If intZeroPos > 0 Then
        StripTerminator = Left$(strString, intZeroPos - 1)
    Else
        StripTerminator = strString
    End If
End Function

Public Sub SaveSettingEx(HKEY As Long, sPath As String, sValue As String, sData As String)
    Dim KeyHand As Long
    Call RegCreateKey(HKEY, sPath, KeyHand)
    Call RegSetValueEx(KeyHand&, sValue, 0, REG_SZ, ByVal sData, Len(sData))
    Call RegCloseKey(KeyHand&)
End Sub

Usage

'Save a Value to the Registry
SaveSettingEx HKEY_CURRENT_USER, "Software\Myapp", "Testing", "Hello"


'Get a value from the Registry
Retval = GetSettingEx(HKEY_CURRENT_USER, "Software\Myapp", "Testing")
Print Retval

[parksie]

And the parksie vs. Megatron registry code competition continues...