How do I get exe file version with old versions of the FSO?

[FunkyDexter]

Hi guys

Bit of a problem I'm hoping you can help with. I've got an app that builds a report of all the exe files in a directory and and their version numbers. We're using it to pop up a message at client sites if they have an old version of one of our exe's. I've used the file system objects getFileVersion method to get the version info for the report but when we've come to use the client bit (the bit that checks the version they're using against the report) on a NT system it barfs because that method wasn't implemented until version 5.0.3715 of the scripting engine (which presumably came after NT).

So my question is: is there a way UI can get the file version information on older Windows versions in the same format as that returned by getFileVersion (ie ##.##.##.##)?

[Hack]

Try something like

Option Explicit
 
Private Type VS_FIXEDFILEINFO
   dwSignature As Long
   dwStrucVersionl As Integer
   dwStrucVersionh As Integer
   dwFileVersionMSl As Integer
   dwFileVersionMSh As Integer
   dwFileVersionLSl As Integer
   dwFileVersionLSh As Integer
   dwProductVersionMSl As Integer
   dwProductVersionMSh As Integer
   dwProductVersionLSl As Integer
   dwProductVersionLSh As Integer
   dwFileFlagsMask As Long
   dwFileFlags As Long
   dwFileOS As Long
   dwFileType As Long
   dwFileSubtype As Long
   dwFileDateMS As Long
   dwFileDateLS As Long
End Type
 
Private Declare Function GetFileVersionInfo Lib "Version.dll" Alias "GetFileVersionInfoA" _
(ByVal lptstrFilename As String, ByVal dwhandle As Long, ByVal dwlen As Long, lpData As Any) As Long
Private Declare Function GetFileVersionInfoSize Lib "Version.dll" Alias "GetFileVersionInfoSizeA" _
(ByVal lptstrFilename As String, lpdwHandle As Long) As Long
Private Declare Function VerQueryValue Lib "Version.dll" Alias "VerQueryValueA" _
(pBlock As Any, ByVal lpSubBlock As String, lplpBuffer As Any, puLen As Long) As Long
Private Declare Sub MoveMemory Lib "kernel32" Alias "RtlMoveMemory" (dest As Any, _
ByVal Source As Long, ByVal length As Long)
 
Private sFileVer As String
 
Private Sub DisplayVerInfo(sFullFileName As String)
   'modified slightly from the example in the API Viewer from [url]http://www.allapi.net/[/url]
   Dim rc As Long
   Dim lDummy As Long
   Dim sBuffer() As Byte
   Dim lBufferLen As Long
   Dim lVerPointer As Long
   Dim udtVerBuffer As VS_FIXEDFILEINFO
   Dim lVerbufferLen As Long
 
   '*** Get size ****
   lBufferLen = GetFileVersionInfoSize(sFullFileName, lDummy)
   If lBufferLen < 1 Then
      MsgBox "No Version Info available!"
      Exit Sub
   End If
 
    ReDim sBuffer(lBufferLen)
   rc = GetFileVersionInfo(sFullFileName, 0&, lBufferLen, sBuffer(0))
   rc = VerQueryValue(sBuffer(0), "\", lVerPointer, lVerbufferLen)
   MoveMemory udtVerBuffer, lVerPointer, Len(udtVerBuffer)
 
   sFileVer = Format$(udtVerBuffer.dwFileVersionMSh) & "." & Format$(udtVerBuffer.dwFileVersionMSl) & "." & Format$(udtVerBuffer.dwFileVersionLSh) & "." & Format$(udtVerBuffer.dwFileVersionLSl)
Label1.Caption = sFileVer
End Sub
 
Private Sub Command1_Click()
DisplayVerInfo "C:\My.Exe"
End Sub