[VB] - Occurrences of a char in a string

[SkiNLaB]

V suprised I couldn't find a general purpose function that returns the number of times a character appears in a string...

so here's one i made

Public Function OccurrenceInstr(searchStr As String, char As String) As Integer
    Dim lastSpot As Integer
    Dim occCount As Integer
    Dim found As Boolean
    
    If searchStr = "" Or char = "" Then Exit Function
    
    found = True
    While found
        lastSpot = InStr(lastSpot + 1, searchStr, char)
        If lastSpot > 0 Then
            occCount = occCount + 1
            found = True
        Else
            found = False
        End If
    Wend
    OccurrenceInstr = occCount
End Function

note: not thoroughly tested

[crptcblade]

Private Sub Command1_Click()
    MsgBox CountChars("Hello there Lenny", "a")
End Sub
 
Private Function CountChars(ByVal SearchString As String, _
                            ByVal StrToFind As String, _
                            Optional ByVal IgnoreCase As Boolean = True) _
                            As Integer
                            
    If Len(SearchString) = 0 Or Len(StrToFind) = 0 Then Exit Function
    
    If IgnoreCase Then
        SearchString = LCase$(SearchString)
        StrToFind = LCase$(StrToFind)
    End If
    
    CountChars = UBound(Split(SearchString, StrToFind))
 
End Function

Probably better not to do a lot of looping.

[SkiNLaB]

haha v nice.

[manavo11]

Another way

Option Explicit
 
Private Function CharCount(S As String, Char As String) As Integer
    If Len(Char) = 0 Then Exit Function
    Dim SR As String
    
    SR = Replace(S, Char, vbNullString)
    
    CharCount = (Len(S) - Len(SR)) / Len(Char)
End Function
 
 
Private Sub Form_Load()
    MsgBox CharCount("manavo", "a")
End Sub