Access 2000 and Common Dialog Control

[JDigits]

I am using Access 2000 to develop a DB application. All has been going very well, until i discover that i cant use the Common Dialog Control. The error i get is OLE Server isnt Registered - To Register re-install it

Now from further investigation, i find that the required file comdlg32.ocx is no where to be found on my machine. This then led me to search for the file on the internet, which i dually found and registered on my machine, where i still got the same message the first time i tried to place the control onto one of my forms, then after that the message changed to one about not having the appropraite license.

What i thought would resolve this little situation would be to install VB on this machine, but that leaves me to wonder will there be issues when it comes to deploying this app onto another machine??

Surely there is another way around this, im really stuck here so any help is going to be very well received.

Thanks

[Ephesians]

This should give you a leg up..

Public Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (lpofn As OPENFILENAME) As Long
 
Public Const OFN_ALLOWMULTISELECT = &H200
Public Const OFN_CREATEPROMPT = &H2000
Public Const OFN_ENABLEHOOK = &H20
Public Const OFN_ENABLESIZING = &H800000
Public Const OFN_ENABLETEMPLATE = &H40
Public Const OFN_ENABLETEMPLATEHANDLE = &H80
Public Const OFN_EXPLORER = &H80000
Public Const OFN_EXTENSIONDIFFERENT = &H400
Public Const OFN_FILEMUSTEXIST = &H1000
Public Const OFN_HIDEREADONLY = &H4
Public Const OFN_LONGNAMES = &H200000
Public Const OFN_NOCHANGEDIR = &H8
Public Const OFN_NODEREFERENCELINKS = &H100000
Public Const OFN_NOLONGNAMES = &H40000
Public Const OFN_NONETWORKBUTTON = &H20000
Public Const OFN_NOREADONLYRETURN = &H8000
Public Const OFN_NOTESTFILECREATE = &H10000
Public Const OFN_NOVALIDATE = &H100
Public Const OFN_OVERWRITEPROMPT = &H2
Public Const OFN_PATHMUSTEXIST = &H800
Public Const OFN_READONLY = &H1
Public Const OFN_SHAREAWARE = &H4000
Public Const OFN_SHOWHELP = &H10
Public Type OPENFILENAME
     lStructSize As Long
     hwndOwner As Long
     hInstance As Long
     lpstrFilter As String
     lpstrCustomFilter As String
     nMaxCustomFilter As Long
     nFilterIndex As Long
     lpstrFile As String
     nMaxFile As Long
     lpstrFileTitle As String
     nMaxFileTitle As Long
     lpstrInitialDir As String
     lpstrTitle As String
     Flags As Long
     nFileOffset As Integer
     nFileExtension As Integer
     lpstrDefExt As String
     lCustData As Long
     lpfnHook As Long
     lpTemplateName As String
End Type
Public Sub GetFileName(strfiletype)
     ' Configure how the dialog box will look
     With strFile
          ' Size of the structure.
          .lStructSize = Len(strFile)
          ' Handle to window opening the dialog.
          .hwndOwner = Application.hWndAccessApp
          ' Handle to calling instance (not needed).
          .hInstance = 0
          ' File filters to make available: Dat Files
          .lpstrFilter = strfiletype & " Files (*." & strfiletype & ")" & vbNullChar & "*." & strfiletype & vbNullChar
          '.lpstrCustomFilter is ignored -- unused string
          .nMaxCustomFilter = 0
          ' Default filter is the first one (Dat Files, in this case).
          .nFilterIndex = 1
          ' No default filename.  Also make room for received
          ' path and filename of the user's selection.
          .lpstrFile = Space(256) & vbNullChar
          .nMaxFile = Len(.lpstrFile)
          ' Make room for filename of the user's selection.
          .lpstrFileTitle = Space(256) & vbNullChar
          .nMaxFileTitle = Len(.lpstrFileTitle)
          ' Initial directory is C:\.
          .lpstrInitialDir = "c:\" & vbNullChar
          ' Title of file dialog.
          .lpstrTitle = "Select a File" & vbNullChar
          ' The path and file must exist; hide the read-only box.
          .Flags = OFN_PATHMUSTEXIST Or OFN_FILEMUSTEXIST Or OFN_HIDEREADONLY
          ' The rest of the options aren't needed.
          .nFileOffset = 0
          .nFileExtension = 0
          '.lpstrDefExt is ignored -- unused string
          .lCustData = 0
          .lpfnHook = 0
          '.lpTemplateName is ignored -- unused string
     End With
 
     ' Display the dialog box.
 
     If GetOpenFileName(strFile) <> 0 Then
          ' Remove null space from the file name.
          strFilename = left(strFile.lpstrFile, InStr(strFile.lpstrFile, vbNullChar) - 1)
     End If
End Sub