If Not Reverse Mod, Then What???

[pixelcandy]

thanks to those of you that answered my original question... It's good to know that there is no possible answer... but that still leaves me with an unanswered question... My frist question was how do I "unmod" a number that has been moded in the program below.... I now know that it is impossible to write a program that will unmod any random number... perhaps then there is a way to decrypt the originally encrypted message without "un"moding the digits???

Here is the question word for word, let me know what you think!!Maybe I am interpreting it wrong...

"A company wants to trasnmit data over the telephone, but they are concerned that their phones may be tapped. All their data is transmitted as four-digit integers. They have asked you to write a program that encrypts their data so that it may be transmitted more securely. Your program should read a four digit integer entered by the user and encrypt it as follows: Replace each digit by (the sum of that digit plus 7) modulo 10. THen swap the first digit with the third, and swap the second digit with the fourth. Print the encrypted integer. Write a separate program that inputs an encrypted four digit integer and decrypts it to form the original number. "

Here is the code again for the first part of the problem:

Module Module1

Sub Main()

Dim digit As Integer
Dim placeOne, placeTwo, placeThree, placeFour As Integer
Dim oneSwap, twoSwap, threeSwap, fourSwap As Integer

Console.Write("Please enter the four-digit integer: ")
digit = Console.ReadLine()

placeFour = digit \ 1 Mod 10
placeThree = digit \ 10 Mod 10
placeTwo = digit \ 100 Mod 10
placeOne = digit \ 1000 Mod 10

placeOne = (placeOne + placeOne + 7) Mod 10
placeTwo = (placeTwo + placeTwo + 7) Mod 10
placeThree = (placeThree + placeThree + 7) Mod 10
placeFour = (placeFour + placeFour + 7) Mod 10

oneSwap = placeThree
twoSwap = placeFour
threeSwap = placeOne
fourSwap = placeTwo

Console.WriteLine(oneSwap & twoSwap & threeSwap & fourSwap)

End Sub

End Module


Thank you in advance to anyone who helps me with this thing!!!! I'm new at this, and I'm not much of a logical thinker really...

[VictorB212]

You should not have made a new thread for this. There IS no solution. All you can do is guess that the resulting number is one of 16 original numbers.

[Mc Brain]

There's NO way to decrypt this. For example, what if placeOne = 6... what would be the original value?? You have two possible original values that would return 9:. For example:

placeOne = (placeOne + placeOne + 7) Mod 10
(1 + 1 + 7) Mod 10 = 9
(6 + 6 + 7) Mod 10 = 9

See?? Which was the original one? 6 or 1??

Other examples.... all of them has two posible original values:

(2 + 2 + 7) Mod 10 = 1
(7 + 7 + 7) Mod 10 = 1

(3 + 3 + 7) Mod 10 = 3
(8 + 8 + 7) Mod 10 = 3

(4 + 4 + 7) Mod 10 = 5
(9 + 9 + 7) Mod 10 = 5

(5 + 5 + 7) Mod 10 = 7
(0 + 0 + 7) Mod 10 = 7

[nemaroller]

In this exercise, we look at one method of encryption. A message is first broken up into pairs of consecutive characters Each pair is converted to a four digit number by using the ASCII values of the characters; for example, BY is converted to 6689 because the ASCII value for B is 66 and the ASCII value for Y is 89.

Then we add 7 mod 10 to each digit. This is done by adding 7 to the digit and taking the remainder on dividing by 10: e.g., the sum of 6 and 7 is 3. . In our example, the result of adding 7 (mod 10) to each digit of 6689 is 3356.

Finally, we swap the first and fourth digit and the second and third digit. In our example, this will produce 6533, the encrypted form of BY

(a) Show that GO is encrypted as 6484

(b) Encrypt your initials.

(c) Decrypt 2314 2335

(d) Do you think this method provides a secure encryption scheme? Explain.

http://community.middlebury.edu/~mol...gnment_17.html

[Mc Brain]

0+7=7
1+7=8
2+7=9
3+7=0
4+7=1
5+7=2
6+7=3
7+7=4
8+7=5
9+7=6

Ok, then.... that's decryptable!!!

[nemaroller]

Guess that military training paid off... you should of never left the CIA..

[Mc Brain]

Option Explicit
 
Private Sub Form_Load()
    Debug.Print Encrypt("BY")
    
    Debug.Print Decrypt(6533)
End Sub
 
Private Function Encrypt(ByVal Word As String) As Integer
    Dim i As Integer
    
    Word = Asc(Word) & Asc(Mid$(Word, 2))
 
    For i = 1 To 4
        Mid$(Word, i, 1) = (Mid$(Word, i, 1) + 7) Mod 10
    Next i
    
    Word = SwapValues(Word, 1, 4)
    Word = SwapValues(Word, 2, 3)
    
    Encrypt = Word
    
End Function
 
Private Function SwapValues(ByVal Word As String, First As Integer, Second As Integer) As String
    Dim tempstring As String
        
    SwapValues = Mid$(Word, First, 1)
    Mid$(Word, First, 1) = Mid$(Word, Second, 1)
    Mid$(Word, Second, 1) = SwapValues
    
    SwapValues = Word
End Function
 
Private Function Decrypt(ByVal Word As String) As String
    Dim i As Integer
    Dim TempValue As Integer
    
    Word = SwapValues(Word, 1, 4)
    Word = SwapValues(Word, 2, 3)
 
    For i = 1 To 4
        TempValue = (Mid$(Word, i, 1) - 7)
        
        If TempValue < 0 Then TempValue = TempValue + 10
        
        Mid$(Word, i, 1) = TempValue
    Next i
 
    Word = Chr$(Left$(Word, 2)) & Chr$(Mid$(Word, 3))
    
    Decrypt = Word
    
End Function