change text colors (Like Zelda on N64)

[Dayo312]

Ever played zelda??

When someone talks to you the more importain
words are in red, places in green. and such.
I want to do this to the game im making but
I believe that impossable with the label COntroll.
IS there one I could do that with, and or
could I do that with the label controll?

You could use a RichTextBox and set the BackColour to whatever you want and have the Locked property set to True so it will act as a label.

Then you can put this code in the General Section

Option Explicit



Private Sub HighlightText(sKeyword As String, iColour As Long)

Dim nStart As Integer, sPrevChar As String, sNextChar As String

                                           
nStart = InStr(1, LCase(RichTextBox1.Text), sKeyword)
                                            
                                            
Do While nStart <> 0

If nStart > 1 Then
    sPrevChar = Mid$(RichTextBox1.Text, nStart - 1, 1)
Else
    sPrevChar = " "
End If
                                                

If Len(RichTextBox1.Text) >= nStart + Len(sKeyword) Then
    sNextChar = Mid$(RichTextBox1.Text, nStart + Len(sKeyword), 1)
Else
    sNextChar = " "
End If
                                                   

If (sPrevChar = Chr(32) Or sPrevChar = Chr(13) Or _
sPrevChar = Chr(10) Or sPrevChar = Chr(9)) And _
(sNextChar = Chr(32) Or sNextChar = Chr(13) Or _
sNextChar = Chr(10) Or sNextChar = Chr(9)) Then

With RichTextBox1

.SelStart = nStart - 1
.SelLength = Len(sKeyword)
.SelColor = iColour
.SelText = UCase(sKeyword)
.SelStart = Len(RichTextBox1.Text)
.SelColor = vbBlack

End With

End If
                                              
nStart = InStr(nStart + Len(sKeyword), LCase(RichTextBox1.Text), sKeyword)

Loop

End Sub

Now put this code in a CommandButton.

Private Sub Command1_Click()

With RichTextBox1
.SelStart = 0
.SelLength = Len(.Text)
.SelColor = vbBlack
.SelStart = Len(.Text)
End With
                            
' Add more custom words here
HighlightText "bowser", vbBlue
HighlightText "danger", vbRed
HighlightText "palace", vbMagenta
HighlightText "mario", vbGreen
 
End Sub

when you type in the words bowser, danger, palace and mario, they will all turn into different colours when you click the Commandbutton.

[kedaman]

No haven't played zelda, but you can change the forecolor of a label. Also if you wan't you can draw diectly on the form, change forms forecolor and use print

But you might have a hard time trying to get the text whewre you want it on the form.

[kedaman]

No Meg, the form have a currentx and currenty property which is the next position to write.