Sample - RGB from long, byte retrieval

[jim mcnamara]

Efficient way to get R,G,B out of a color value
Or to whack a long or integer into bytes....
[code]
In a .BAS module--------------

Private Declare Function LoByte Lib "TLBINF32" Alias "lobyte" _
  (ByVal Word As Integer) As Byte
Private Declare Function HiByte Lib "TLBINF32" Alias "hibyte" _
 (ByVal Word As Integer) As Byte
Private Declare Function loword Lib "TLBINF32" (ByVal DWord As Long) _
 As Integer
Private Declare Function hiword Lib "TLBINF32" (ByVal DWord As Long) _ 
 As Integer

Public Sub From_RGB(Color as Long, R as Byte, G as Byte,B as Byte)
    R = LoByte(loword(Color))  ' Byte 1
    G = HiByte(loword(Color))  ' Byte 2
    B = LoByte(hiword(Color))  ' Byte 3
    '   HiByte(hiword(Color))   Byte 4 - no meaning here just a comment
End Sub

You can also use the api calls above to get any byte out of a two or four byte integer or long.

[Janus]

Using LSet is faster:

Public Type LongUDT
    Value as Long
End Type
Public Type BGRAUDT
    Blue as Byte
    Green as Byte
    Red as Byte
    Alpha as Byte
End Type
 
Dim LU as LongUDT, Color as BGRAUDT
' ...
LU.Value = GetPixel(Me.hDC, X, Y)
LSet Color = LU
Color.Blue = Color.Blue \ 2
Color.Green = Color.Green \ 2
Color.Red = Color.Red \ 2
LSet LU = Color
Call SetPixelV(Me.hDC, X, Y, LU.Value)
' ...

In most situations this is the fastest method. (Even faster than copymemory.)

[plenderj]

Here's another approach

Private Type colTriplet
    r As Long: g As Long: b As Long
End Type
 
Private Function longToTriplet(ByVal colLong As Long) As colTriplet
    With longToTriplet
        .r = (colLong And &HFF)
        .g = (colLong \ &H100&) And &HFF&
        .b = (colLong \ &H10000) And &HFF&
    End With
End Function

... which is basically the same as jim's

[Sastraxi]

The best thing about LSet or CopyMemory (btw, LSet wins by about 3ms for every 100 times called, I did a test) is that it isn't done with VB's slow math.